*20
	PMODE
	*20
TIMER,	0
EXPOSE,	40		/EXPOSURE MSECS
AFTER,	2000		/POSTMASK CYCLES
BEFORE,	1000		/PREMASK CYCLES
SH1,	0
SH2,	0
SH3,	0
SHUFEL,	SHUFL
RNX,	RN
IRX,	IR
K7,	7
TEMP,	0
R1,	0
R2,	0
R3,	0
INDEX6,	0
RNDM3,	0
RNDM2,	0
RNDM1,	RNDM
RMNDR,	RMNDRX
NTRIAL,	0
ITRIAL,	TRIAL
IBLOCK,	BLOCK
M26,	-26
C40,	40
C300,	300
C212,	212
C215,	215
C240,	240
TT,	0
ADSET1,	CHARS
ADSET2,	CHARS+2
ADSET3,	CHARS+4
RFRESH,	-144		/-REFRESH RATE
ADTRLS,	TRIALS-1
C2100,	2100
/SUBR DISPLAYS 3 MASKS ONCE EACH
MASK,	0
	LINC
	LMODE
	SET I 1
IHORCO,	363
	LDA I
VERCO,	340
	DSC I
MASKPW,	7777
	DSC
	MASKPW
	SRO I
	4444
	JMP DONE
	LDA I
DX,	2
	ADM
	1
	JMP VERCO-1
DONE,	PDP
	PMODE
	CLA
	JMP I MASK
/3 BINARY CHARACTER SETS FOLLOW
CHARS,	2		/B OR F
	6
	1		/A OR I
	11
	16		/N OR T
	24
TYPE,	0
	TLS
	TSF
	JMP .-1
	CLA
	JMP I TYPE
/PROGRAM STARTS HERE: INITIALIZE R.N.S
/BY CLEARING L SWS
START,	ISZ 1
	NOP
	LAS
	SZA
	JMP START
	JMS I IRX
	JMS I RNX
	ISZ 1
	JMP .-2
/EACH BLOCK BEGINS HERE
/SHUFFLE 4 REPLICAS OF TRIAL TYPES
BLOCK,	CLA
	TAD M26
	DCA 1		/SHUFFLE 22 TIME
	LINC
	LMODE
	SNS I 0		/SW 0: CHAR SIZE
	ADD C300
	ESF
	PDP
	PMODE
	CLA
	TAD ADTRLS
	DCA SH1
	TAD C40
	DCA SH2
	STA
	DCA SH3
	JMS I SHUFEL
	ISZ 1
	JMP BLOCK+2
	TAD C40
	CIA
	DCA NTRIAL
	TAD ADTRLS
	DCA 10		/AD-1 TRIALS
	HLT		/HALT WHEN READY
/EACH TRIAL BEGINS HERE
TRIAL,	TAD I 10
	DCA TT
	IAC
	AND TT		/BIT 11:CHAR 3
	TAD ADSET3
	DCA 5
	STL RTL
	AND TT		/BIT 10:CHAR 2
	CLL RAR
	TAD ADSET2
	DCA 4
	CLL IAC RTL
	AND TT		/BIT 9:CHAR 1
	CLL RTR
	TAD ADSET1
	DCA 3
/DISPLAY BRIGHT PREMASK UNTIL S STARTS
/AND THEN FOR "BEFORE" NO TIMES
	6304
	JMS MASK
	6302
	SNA CLA
	JMP .-3
	TAD BEFORE
	CIA
	DCA TIMER
	JMS MASK
	ISZ TIMER
	JMP .-2
/NOW DISPLAY 3-LETTER STRING ONCE PER
/MSEC FOR "EXPOSE" MSECS
	TAD EXPOSE
	CIA
	DCA TIMER
SHOW,	CLLR		/SETUP CLOCK
	TAD C2100
	CLLR
	LINC
	LMODE
	SET 1
	IHORCO
	LDA 3
	JMP STRING	/SUBR:CHAR 1
	LDA 4
	JMP STRING	/CHAR 2
	LDA 5
	JMP STRING	/CHAR 3
	PDP
	PMODE
	CLCA		/WAIT FOR MSEC
	TAD RFRESH	/TO ELAPSE
	SPA CLA
	JMP .-3
	ISZ TIMER	/DO EXPOSE TIMES
	JMP SHOW
/NOW DISPLAY BRIGHT POSTMASK "AFTER" X"S
	CLLR		/STOP CLOCK
	TAD AFTER
	CIA
	DCA TIMER
	JMS MASK
	ISZ TIMER
	JMP .-2
/DISPLAY OVER: TYPES OUT CORRECT STRING
/AND E ENTERS VERBALLY REPORTED STRING
	TAD C212
	JMS TYPE
	TAD C215
	JMS TYPE
	TAD I 3
	TAD C300
	JMS TYPE
	TAD I 4
	TAD C300
	JMS TYPE
	TAD I 5
	TAD C300
	JMS TYPE
	TAD C240
	JMS TYPE
	KCC
	KSF
	JMP .-1
	KRB
	JMS TYPE
	KSF
	JMP .-1
	KRB
	JMS TYPE
	KSF
	JMP .-1
	KRB
	JMS TYPE
	ISZ NTRIAL	/ANOTHER TRIAL?
	JMP I ITRIAL
	TAD C212
	JMS TYPE
	TAD C215
	JMS TYPE
	JMP I IBLOCK
	LMODE
STRING,	ROL 1
	ADA I
	PATRN-2
	STC 2
	ADD VERCO
	DSC 2
	DSC I 2
	LDA
	DX
	ADM
	1
	JMP
	PMODE
/BLOCK OF 32 TRIAL TYPES 0-7 BELOW
TRIALS,	2
	4
	6
	7
	5
	3
	0
	1		/FIRST REPLICA
	1
	3
	5
	7
	6
	4
	2
	0		/SECOND REPLICA
	0
	4
	1
	5
	2
	6
	3
	7		/THIRD REPLICA
	3
	6
	2
	7
	1
	0
	4
	5		/FOURTH REPLICA
/RANDOM PACKAGE BEGINS HERE
	PAGE
RNDM,	0		/RN IN 0,RNDM3
	JMS I RNX	/36 BIT RN
	JMS I RMNDR	/REMAINDR RNDM3
	CLA
	JMP I RNDM	/DONE
M36,	-44		/
IDX1,	0		/
R1X,	0		/
R2X,	0		/
R3X,	0		/
RMNDRX,	0		/GET RMNDR
	CLA		/
	DCA RNDM2	/
	TAD R1		/
	DCA R1X		/
	TAD R2		/
	DCA R2X		/
	TAD R3		/
	DCA R3X		/
	TAD M36		/
	DCA IDX1	/FOR 36 BITS
RMN1,	CLA		/
	TAD RNDM2	/
	CLL		/
	RAL		/
	DCA RNDM2	/SHIFT LEFT 1
	TAD R1X		/
	CLL		/
	RAL		/
	DCA R1X		/SHIFT LEFT 1
	RAL		/GET LINK
	TAD RNDM2	/
	DCA RNDM2	/
	TAD R2X		/
	CLL		/
	RAL		/
	DCA R2X		/
	RAL		/GET LINK
	TAD R1X		/
	DCA R1X		/
	TAD R3X		/
	CLL		/
	RAL		/
	DCA R3X		/
	RAL		/GET LINK
	TAD R2X		/
	DCA R2X		/SHIFTS DONE
	TAD RNDM3	/NUMBER MOD
	CIA		/
	TAD RNDM2	/
	SPA		/
	JMP .+2		/
	DCA RNDM2	/SUB,REPLACE
	ISZ IDX1	/CHECK INDEX
	JMP RMN1	/CONTINUE
	JMP I RMNDRX	/RMNDR IN RNDM2
SHUFL,	0		/SHUFFLES
SHUFL1,	CLA		/
	TAD SH2		/LENGTH
	DCA RNDM3	/
	JMS I RNDM1	/GET RN
	CLA		/
	TAD SH3		/BLOCK SIZE
	DCA INDEX6	/
	TAD SH1		/ARRY-1
SHUF1,	TAD RNDM2	/ADD TO ARRY
	ISZ INDEX6	/N X M DONE?
	JMP SHUF1	/CONTINUE
	DCA TEMP	/DONE,IN TEMP
	TAD TEMP	/
	DCA 14		/
	TAD TEMP	/
	DCA 15		/
	TAD SH1		/
	DCA 16		/
	TAD SH1		/
	DCA 17		/
	TAD SH3		/
	DCA INDEX6	/-BLOCK SIZE
SHUF2,	TAD I 14	/
	DCA TEMP	/
	TAD I 16	/
	DCA I 15	/
	TAD TEMP	/
	DCA I 17	/
	ISZ INDEX6	/
	JMP SHUF2	/
	CLA CMA		/AC=-1
	TAD SH2		/LENGTH-1
	SZA		/
	JMP .+2		/
	JMP I SHUFL	/DONE
	DCA SH2		/NEW LENGTH
	TAD SH3		/BLOCK SIZE,-
	CIA		/+BLOCK SIZE
	TAD SH1		/ADD ARRAY
	DCA SH1		/NEW START
	JMP SHUFL1	/CONTINUE
	PAGE
IR,	0		/
	JMP IR1		/
RN,	0		/
	CLA		/
	TAD R3		/
	RAL		/
	AND K7400	/
	DCA T3		/
	TAD R2		/
	AND K177	/
	TAD T3		/
	RTL		/
	RTL		/
	RAL		/
	DCA T1		/
	TAD R3		/
	AND K177	/
	RTL		/
	RTL		/
	RAL		/
	TAD R2		/
	DCA T2		/
	SZL		/
	ISZ T1		/
	NOP		/
	TAD R3		/
	CLL RAL		/
	SZL		/
	ISZ T2		/
	SKP		/
	ISZ T1		/
	NOP		/
	CLL		/
	TAD R3		/
	DCA R3		/
	TAD R2		/
	RAL		/
	SZL		/
	ISZ T1		/
	NOP		/
	CLL		/
	TAD T2		/
	DCA R2		/
	TAD R1		/
	RAL		/
	TAD R1		/
	TAD T1		/
	DCA R1		/
	TAD R1		/
	JMP I RN	/
	HLT		/NOT USED
IR1,	CLA IAC		/
	DCA R3		/
	DCA R2		/
	DCA R1		/
	JMP I IR	/
K177,	177		/
K7400,	7400		/
T1,	0		/
T2,	0		/
T3,	0		/
/PATTERN WORDS FOR CHAR DISPLAY
PATRN,	4477		/A
	7744
	5177		/B
	2651
	4136		/C
	2241
	4177		/D
	3641
	4577		/E
	4145
	4477		/F
	4044
	4136		/G
	2645
	1077		/H
	7710
	7741		/I
	0041
	4142		/J
	4076
	1077		/K
	4324
	177		/L
	301
	3077		/M
	7730
	3077		/N
	7706
	4177		/O
	7741
	4477		/P
	3044
	4276		/Q
	376
	4477		/R
	3146
	5121		/S
	4651
	4040		/T
	4077
	177		/U
	7701
	176		/V
	7402
	677		/W
	7701
	1463		/X
	6314
	770		/Y
	7007
	4543		/Z
	6151
	4177		/[
	0000
	2040		/\
	0410
	0		/]
	7741
	2000		/^
	2077
	3410		/BACK ARROW
	1010
	0		/SPACE
	0
	7500		/!
	0
	6006		/"
	60
	3614		/NUMBER SIGN
	1436
	7721		/DOLLAR SIGN
	4677
	1446		/%
	6130
	5166		/&
	0523
	500		/APOSTROPHY
	
	6
	4163		/(
	0
	0		/)
	6341
	2050		/*
	50
	404		/+
	437
	605		/,
	0
	404		/-
	404
	1		/.
	0
	601		//
	4030
	4136		/0
	3641
	2101		/1
	177
	4523		/2
	2151
	4122		/3
	2651
	2414		/4
	477
	5172		/5
	651
	1506		/6
	4225
	4443		/7
	6050
	5126		/8
	2651
	5120		/9
	3651
	4200		/:
	0
	2601		/;
	0
	2410		/<
	0042
	1212		/=
	1212
	4200		/>
	1024
	4020		/?