File CHRISM

Directory of image this file is from
This file as a plain text file

[THIS PROG WILL SAMPLE ANALOGUE SIGNALS ON MAG TAPE
[AND STORE AS DIGITAL INFO ON LINC TAPE
[1=HOR DSC POS
[2=PTR FOR WARN, INFO DISPLAY
[2=CTR FOR WARN, INFO DISPLAY
[4=CTR, # OF Q OF DATA, # OF LOST BITS IN DATA AVG
[5=ALPHA REG FOR DATA DISPLAY
[7=PTR FOR AVG AND STORING DATA
[10=CTR FOR MISC
[11=PTR FOR TYP
[12=12
[13=CTR FOR TYP, DATA AVG
[14=PTR FOR MISC
[15=CTR0
[16=CTR1
[17=RETURN ADDRESS OF SUBROUTINE
9A = 1000 [DAY
9B=1001[MONTH
9C=1002[YEAR
9D=1003[EXPNO
9E=1004[BLKNO
9F=1005[RATE
9G=1006[WRDCNT
#1A CLR
SET i 12 [CR
12
SET i 11[TYP PTR
1D-1
SET i 14
777
SET i 10
-5
STA i 14 [CLR TYPE LOC
XSK i 10
JMP p-2
JMP 1E [TYP DAY
#1F KBD i
SAE 12
JMP p+2
JMP 1H-1
STC 1T
ADD 9A
ROL 6
ADD 1T
STC 9A
JMP 1F
JMP 1E [TYP MONTH
#1H KBD i
SAE 12
JMP p+2
JMP 1M-1
STC 1T
ADD 9B
ROL 6
ADD 1T
STC 9B
JMP 1H
JMP 1E [TYP YEAR
#1M KBD i
SAE 12
JMP p+2
JMP 1P-1
STC 1T
ADD 9C
ROL 6
ADD 1T
STC 9C
JMP 1M
JMP 1E [TYP EXPNO
#1P KBD i
SAE 12
JMP p+2
JMP 1S-1
STC 1T
ADD 9D
ROL 6
ADD 1T
STC 9D
JMP 1P
JMP 1E [TYP BLKNO
#1S KBD i
SAE 12
JMP p+2
JMP 2A
STC 1T
ADD 9E
ROL 3
ADD 1T
STC 9E
JMP 1S
#1E SET 17
0
SET i 13
-6
LDA i 11
OPR 14 [TYP
XSK i 13
JMP p-3
JMP 17
#1D 215 
212
304 [DAY
301
331
272
212
315 [MONTH
316
324
310
272
212
331 [YEAR
305
301
322
272
212
305 [EXPNO.
330
320
316
272
212
302 [BLKNO.
314
313
316
272
#1T 0
#1C 0001
#2A CLR
SNS 0 [IS SENSE SW 0 UP
JMP p-1[NO
SET i 10[YES
-773
SET i 14
1004
LDA i
1007
STC 4C [DATA STR-1
STA i 14 [CLEAR LOWER DATA BANK
XSK i 10
JMP p-2
SET i 14
3777
SET i 10
1777
STA i 14 [CLEAR UPPER DATA BANK
XSK i 10
JMP p-2
#3A CLR
STC 3T [SUM1
SET i 16 [CTR1
-10
#3B STC 3S [SUM0
SET i 15 [CTR0
-10
#4A SET i 13
-500 [DELAY FOR SAMPLING
XSK i 13
JMP p-1
SNS 0 [IS SENSE SW 0 UP
JMP 6A [NO , OUT
SAM 11 [YES , WAIT FOR TRIG
APO
JMP p-4
#4B CLR
SAM 10 [SAMPLE DATA 
ADA i
400
ADD 3S
STC 3S [PARTIAL SUM
XSK i 15 [8 SAMPLES
JMP 4A [NO
ADD 3S [YES
ROR i 1
SCR 2 [DIV BY 8
STC 3S
SNS 5 [IS SENSE SW 5 UP
JMP 4D [NO
LDA i [YES
100
STC 9F [SET RATE
ADD 3S
ADD 3T
STC 3T
XSK i 16 [64 SAMPLES
JMP 3B [NO
ADD 3T [YES
SCR 3 [DIVIDE BY 8
STC 3S
JMP 4E
#4D LDA i
10
STC 9F
#4E ADD 1C [INCREMENT PTR
ADD 4C
STC 4C
ADD 3S
STA
#4C 0
CLR
ADD 1C
ADD 9G [INCRMNT WRDCNT
STC 9G
ADD 4C
SAE i
3757 [MEM FILLED
JMP 3A [NO
#5A CLR [YES
SET i 1
200 [HOR POS
SET i 2
5C-1
SET i 3
-40
#5B DSC i 2
SNS 2
JMP 5L
#5T SET i 13 [DELAY FOR SW BOUNCE
-100
SET i 10
1777
NOP
XSK i 10
JMP p-2
XSK i 13
JMP 5T+2
SNS 2
JMP 2A
JMP p-2
#5L XSK i 3
JMP 5B
JMP 5A
#5C 4040 [TOO
4077
4177
7741
4177
7741
0000
0000
3077 [MANY
7730
4477
7744
3077
7706
0770
7007
0000
0000
5121 [SAMPLES
4651
4477
7744
3077
7730
4477
3044
0177
0301
4577
4145
5121
4651
#6A CLR [OUT ROUTINE
STC 4
ADD 9G
ADA i
-770
APO [# OF 770 WORDS IN INITIAL WRDCNT
JMP 6L [NO
XSK i 4
JMP p-5
#6L LDA
4
AZE
JMP 6B
#6D LDA i [STORE DATA ON TAPE
1000
STC 6E
ADD 9E
ADM 
6E
WCG u
#6E 1000
SET i 5 [DISPLAY DATA
1777
LDA
9G
COM
STC 10 [CTR 10 SET = TO  -WRDCNT
SET i 14 [PTR FOR DISPLAY
1007
#6G LDA i 14
ADA i
-400
DIS i 5
XSK i 10 [IS DATA DISPLAY FINISHED
JMP 6G [NO
JMP 6T [YES, DISPLAY INFO
#6B ADD 6M
AZE
JMP 6C [1761 - INIT WRDCNT - 2750
ADD 9F [771 - INIT WRDCNT - 1760
ROL 1 [UPDATE RATE
STC 9F
SET i 14
1007
SET i 10 [SO 14 WONT OVFLO
-374
SET i 7
1007
JMP 6S
SET i 14
3777
SET i 10 [SO 7 WONT OVFLO
-374
JMP 6S
LDA
9G [UPDAT WRDCNT
BCL i
7776
ADD 9G
SCR 1
STC 9G
JMP 6D
#6S SET 17 [AVG AND STORE DATA
0000
LDA i 14
ADA i14
SCR 1
STA i 7
XSK i 10
JMP p-5
JMP 17
#6M -1
#6C LDA [UPDATE RATE
9F
STA 
1T 
ROL 1
ADD 1T [MUL BY 3
STC 9F
SET i 14
1007
SET i 10 [SO 14 WONT OVFLO
-250
SET i 7
1007
JMP 6Q
SET i 14
3777
SET i 10 [SO 7 WONT OVFLO
-520
JMP 6Q
SET i 10
0000
LDA [UPDATE WRDCNT
9G
#6K APO i [SKP IF NEG
XSK i 10
APO [SKP IF POS
JMP 6Z
ADA i
-3
JMP 6K
#6Z LDA
10
STC 9G
JMP 6D
#6Q SET 17 [AVG AND STORE DATA
0000
CLR
STC 1T
SET i 13
-6
LDA i 14
ADA i 14
ADA i 14
SAE i
3
JMP p+2
ADD 1C
#6R SCR 2
STA
6X
ADM
1T
LDA
6X
XSK i 13
JMP 6R
LDA 
1T
STA i 7
XSK i 10
JMP 6Q+2
JMP 17
#3S 0000 [SUM0
#3T 0000 [SUM1
#6X 0000 [TEMP STR
$620
4136 [0
3641
2101 [1
0177
4523 [2
2151
4122 [3
2651
2414 [4
0477
5172 [5
0651
1506 [6
4225
4443 [7
6050
5126 [8
2651
5120 [9
3651
0404 [DASH
0000 [SPACE
#6T SET i 1 [HORIZONTAL POS
100
SET i 2 [PTR FOR INFO DISPLAY
777
SET i 13
-2
#6U CLR
XSK i 2
ADD 2
ADA i
-1003
APO i [BLKNO DISPLAY
JMP 6P-6 [YES
SET i 3 [NO
-2
#6H LDA 2
XSK i 3
ROR 6
BCL i
7700
JMP 6J
XSK 3
JMP 6H
JMP 6N
JMP 6U
SAE i [IS INFO DIS FINISHED
3
JMP p+2 [NO
JMP 6E+1 [YES
SET i 3
-3
#6P LDA 2
XSK i 3
ROR 3
XSK i 3
ROR 3
BCL i
7770
JMP 6J
XSK 3 [END OF WORD
JMP 6W [NO
LDA 2 [YES
BCL i
7770
JMP 6J
XSK i 13 [DONE
JMP 6N [NO
JMP 6U [YES
#6W SET i 3
-2
JMP 6P
#6J SET i 17
645
ROL 1
ADA i
620
STC 5
ADA i
-300
DSC 5
DSC i 5
DSC 17
JMP 0
#6N SET 17
0
SET i 5
643
SET i 3
-2
DSC i 5
XSK i 3
JMP p-2
JMP 17



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search