Directory of image this file is from
This file as a plain text file

*20
/DELAY/
/FOR THE PDP-12 WITH 8K OF CORE.
/STARTS 00020 IN PMODE
/ENDLESS LOOP RECORD-PLAYBACK USING
/MEM. LOCS. 10000-17777 FOR STORAGE.
/A-D(10) IS THE INPUT,THE HORIZ.(A) AND
/VERT.(B) SCOPE CHANNELS ARE THE OUTPUTS.
/TYPE THE DESIRED DELAY IN MILLISECONDS
/(0-204 IN .1 MILLISEC. STEPS) AND THEN 
/A OR B, TO DELAY CHANNEL A OR B RELATIVE 
/TO THE INPUT ON A-D(10).
/KEYBOARD ECHO WITH RSW=4000.
/CTRL-D RETURNS TO DIAL.
/    WRITTEN BY
/    DAVID TALKIN
/    JAN.19,1972
	*16
	RCG		/BACK TO DIAL
	7300
	400
	PMODE
	FIELD 0
	*20
	6211		/DATA FIELD 1
	CLA CLL
	DCA 12		/STORAGE POINTER
	DCA 13		/OUTPUT POINTER A.
	DCA 14		/OUTPUT POINTER B.
	TLS
	LINC
	LMODE
	LDA I
C100,	100		/FAST SAMPLE
	ESF
DELAY,	SCR 11		/DUMMY INSTRUCTION
	SAM 10		/TO SET SAMPLE RATE=20KHZ.
	PDP
	PMODE
	DCA I 12
	TAD I 13
	TAD C400	/HORIZ. CENTERING
	DCA 7		/FOR SCOPE OUTPUT
	TAD I 14
	LINC
	LMODE
	NOP		/TWO DUMMYS FOR TIMING
	NOP
	DIS 7
	KST
	JMP DELAY
	PDP
	PMODE
	KRB
	JMS PRINT
	LINC
	LMODE
	SAE I
	204
	JMP .+4
	LDF 3		/BACK TO DIAL
	LIF 2
	JMP 16
	SAE I
	215
	SKP
	JMP CRLF	/CARRIAGE RET.
	SAE I
	301
	SKP
	JMP ATERM	/CHANGE "A" DELAY
	SAE I
	302
	JMP NMRLK	/SEE IF ITS A NUMBER
/OR A DECIMAL POINT.
BTERM,	LDA I		/CHANGE "B" DELAY
	14
	STC 1
	JMP TERM
ATERM,	LDA I
	13
	STC 1
TERM,	SET I 11	/THIS ROUTINE
	D100-1		/TAKES THE NUMBER
	SET I 10	/TYPED IN ON THE
	7774		/KEYBOARD AND MULTIPLIES
	CLR		/IT BY 20 AND SUBTRACTS
	ADA I 11	/IT FROM THE STORAGE
	MUL I		/POINTER TO ESTABLISH
	12		/THE DELAY
	XSK I 10
	JMP .-4
	ADD D0
	ROL 1
	COM
	ADD 12
	STA 1
	LDA I
	D1
	STC WHERE
	STC D100
	STC D10
	STC D1
	STC D0
	LDA I
	NOP
	STC SWIT
	JMP DELAY
D100,	0
D10,	0
D1,	0
D0,	0
C400,	400
CRLF,	PDP
	PMODE
	CLA
	TAD LF
	JMS PRINT
	LINC
	LMODE
	JMP DELAY
LF,	212
TEMP,	0
	PMODE
PRINT,	0
	TSF
	JMP .-1
	DCA TEMP
	LAS
	SMA
	JMP .+4
	CLA
	TAD TEMP
	TLS
	CLA
	TAD TEMP
	JMP I PRINT
	LMODE
NMRLK,	BCL I
	17
	SAE I
	260
	JMP DECCK
SWIT,	NOP
	LDA
	D10
	STC D100
	ADD D1
	STC D10
	LDA
	TEMP
	BCL I
	7760
	STA
WHERE,	D1
	JMP DELAY
DECCK,	LDA
	TEMP
	SAE I
	256
	JMP DELAY
	LDA I
	D0
	STC WHERE
	LDA I
	JMP SWIT+6
	STC SWIT
	JMP DELAY