Directory of image this file is from
This file as a plain text file

*20
/     FIREFLY FLASH DIGITIZING 5/12/82
	SEGMNT 0
	*20
	LDF 1
	JMP AAFTBK-1
WIMIN1,	21		/17(10)SAMS
WIMIN2,	6		/6      "
WIMIN3,	6
WIMAX1,	62		/50  "  "
WIMAX2,	24		/20  "  "
WIMAX3,	24		/ "  "  "
FILTR1,	62		/50  "  "
FILTR2,	33		/27  "  "
FILTR3,	33		/"   "  "
	LDA I
AAFTBK, 0		/FIRST TAPEBLOCK
	STC MTBLK
	LDA I
AAROT8,	0		/REEL ROTATION CTR.
	STC ROTCTR
	LDA I
	-3
	STC PLSCTR	/PRESET PULSECOUNTER
	LDA I
AASAM,	1		/SAMPLING RATE...
	COM		/...IN MSEC.
	STA
	TIME+3
	STC .+3
	STC K310	/CLR CLOCK PRESET
	SET I 3
	-8		/REPLACED
	LDA I
	144
	ADM
	K310		/SET CLOCK PRESET B.
	XSK I 3		/...FOR SAM RATE
	JMP .-5
	LDA I		/SAM INVL MULTIP.CH.1
SIMUL1,	2		/(REPLACEABLE)
	STC SIMFL1
	LDA I		/CH.2
SIMUL2,	2		/(REPLACEABLE)
	STA I
	SIMFL2+2000
	LDA I		/CH.3
SIMUL3,	2		/(REPLACEABLE)
	STA I
	SIMFL3+2000
	LDF 2
	SET I 2
	2000
	CLR		/CLR DATA STORAGE
	STA 2
	XSK I 2
	JMP .-3
	LDF 1
	SET I 2
	T1-1     /CLEAR TABLES...
        CLR
	STA I 2
	LDA
	2
	SAE I
	350		/...TO LOC 350
	JMP .-6
	SET I 2		/CLEAR T2 & 3
	T2+2000
	CLR
	STA I 2
	LDA
	2
	SAE I
	2200
	JMP .-6
	CLR
	STC MSEC
	STC SEC
	MSEC=15
	SEC=16
	SET I DATSTO	/DATA STORAGE POINTER
	2000
	DATSTO=17
	JMP 400
	T1=140		/TABLE 1
	DISPT=160	/DISPLAY TABLE
	D1=160		/CH.1 "   "
	D2=220		/CH.2 "   "
	D3=260		/CH.3 "   "
	FLUTRC=346	/FLUTTER COMP STORE
	CFLAG=347	/CHAR.DISP. FLAG
	BCDROT=350	/REEL ROTNS IN DECIML
	MONON=6420	/MONO PULSE 0 ON
	MONOF=6430	/MONO PULS 0 OFF
	*360
PCRIT,	-20
LASTDF,	37
MTBLK,	000
LASTBK,	777
TEMRY,	0		
SIMFL1,	1
SAVEDF,	2
CORE,	37		/MEMORY (OCTAL)
FOOT8,	3720		/2000 (10) MAX
	*400
	LDA		/NUM OF FIRST...
	MTBLK		/TBLK TYPED
	JMP OCTPRT
	HLT
	LDA I		/INITIALIZE DF
	2
	STC SAVEDF
	LDA I
	0060
	ATR		/RELAY 0,1 ON
	LDF 1
CLOCK,	LDA I
	0200		/FULL-SIZED CHARS. 
	ESF
	PDP
	PMODE
	CLA
	CLLR
	CLEN
	TAD K310	/2 MSEC INTERVALS
	CIA
	CLAB
	CLA
	TAD K0100	/AC BIT 5 SET
	CLLR
	CLSA
	CLA 
	TAD K0300	/AC BITS 4,5 SET
	CLEN
	CLA
	TAD K2100	/100 KHZ RATE
	CLLR
	LINC
	LMODE
CURINL, SET I 11	/HOR
	10
	SET I 12	/VERT
	DISPT-1
LOOP,	IOB
	6131		/SKIP ON CLOCK FLAG
	SKP
	JMP TIME
DISP,	LDA I 12	/SAM
	SCR 2		/   /4
	ADA I
	-50		/POSITION CONTROL
	DIS I 11
	DIS I 11
	DIS I 11
	XSK I 11
	LDA I
	D1+37		/END OF CH.1?
	SAE
	12
	JMP.+6		/NO.
	LDA I		/YES. SPACE...
	70
	ADM
	11
	JMP LOOP	/ AND RETURN.
	LDA I
	D2+37		/END OF CH.2?
	SAE
	12
	JMP .+6		/NO
	LDA I		/YES. SPACE
	80
	ADM
	11
	JMP LOOP	/AND RETURN
	LDA I
	D3+37		/END OF CH 3?
	SAE
	12
	JMP LOOP	/NO. RETURN.
	SNS 0		/YES. ROTN.CT.?
	JMP CURINL	/NO.INITIALIZE.
	JMP CDISP	/YES.DIS.ROT.CTR.
K310,	310		/2 MSEC INVL(REPL.)
K0100,	100
K0300,	300
K2100,	2100
TIME,	IOB
	6135		/CLEAR CLOK FLAG
	SET I 3		/SAM INTERVAL(MSEC)
	-2		/REPLACED
	XSK I MSEC	/INCR.MSEC CTR.
	LDA
	MSEC
	SAE I
	1750		/ =1000(10)MSEC?
	SKP
	JMP .+4
	XSK I 3
	JMP .-10
	JMP CHOICE	/NO
	SET I MSEC	/YES.RESET MSEC CTR
	0
	LDA I
	1		/INCR. SEC CTR.
	ADM
	SEC
	SNS 0
	JMP CHOICE
	SAM 0		/ROT CTR SPEED CTRL.
	ROL 1		/MULT.X 2
	STC REELCT+2
CHOICE,	SAM 14
	COM
	STC FLUTRC	/FLUTTER COMP.
	SNS I 0
	JMP REELCT	/ROTATION COUNTER
RETRN0,	SNS I 1
	JMP ONE		/TO CH.1
RETRN1, SNS 2
	JMP RETRN2
	LIF 1
	JMP TWO		/TO CH.2
RETRN2,	SNS 3
	JMP RETRN3
	LIF 1
	JMP THREE	/TO CH 3
RETRN3,	SNS I 4
	JMP HALTCP    /HALT COMPUTER
	SNS I 5
	JMP STOPDA	/STOP DATA INTAKE
	JMP LOOP
HALTCP,	LDA I
	40
	ATR		/RELAY 0 OFF
	LDA
	SEC		/SEC.CTR. TO AC
	HLT
	BSE I
	0040		/RELAY 0 ON
	ATR
	JMP LOOP	/RESTART
ONE,	LDF 1
        LIF 0          /LOAD SF REGISTER
        LDA I
	-1
	ADM
	SIMFL1		/ARE SAM INVL FLAGS
	AZE		/...STILL SET?
	JMP RETRN1	/YES.DONT SAM CH.1
	LDA		/NO. RESET...
	SIMUL1
	STC SIMFL1
	LDA		/AND SAM CH.1
	T1+4		/OLDEST...
	
	COM
	ADM		/...SUBT. FR.SUM
	T1+5
	SET I 2		/B2=SHUFFLE CTR
	-3
	SET I 3
	T1+3		/B3=SHUF. INDEXR
SHUFL1,	LDA 3		
	STA I 3		
	LDA I
	-2
	ADM
	3
	XSK I 2
	JMP SHUFL1
	SAM 11
	ADD FLUTRC     / FLUTTER COMP
	STA
	T1+1
	ADM
	T1+5		/SAM+SUM
	LDA
	T1+7
	AZE		/PD CTR > 0 ?
	JMP PEAK1	/YES
	SAM 1		/THRESHOLD A-D 1
	STA
	D1+3		/ " TO DISPT.
	COM
	ADD T1+1
	APO		/ > THRESHOLD ?
	JMP TIMCK1-3	/NO
SLOPE1,	LDA		/YES
	T1+5            /        SUM
	SCR 1		/  SUM/2
	ADD T1+4	/  +X4
	COM		/  -""
	ADD T1+2	/  +X2
	ADD T1+1
	ADD T1+1	/  +2X1
	SCR 1		/ALL /2
	STC T1		/        SLOPE
	RSW		/CRITN
	COM
	ADD T1
	APO I		/REACH CRITN?
	JMP PKSET1
	LDA		/NO
	T1+1
	STC D1+4	/SAM TO DIS.T.
TIMCK1,	LDA
	T1+13		/TIME OF LAST PEAK
	COM
	ADA
	SEC		/CURRENT TIME
	ADA I
	-4
	APO		/4 SEC. ELAPSED?
	JMP RETRN1	/NO
	CLR		/YES.CLR STORE PLS.
	STC D1+2
	LDA		/DISPT.CLEARED?
	D1+6
	AZE I
	JMP RETRN1	/YES.
	SET I 3		/NO. CLR DISPT.
	D1+4
	CLR 
	STA I 3
	LDA I
	D1+37
	SAE
	3
	JMP .-6
	JMP RETRN1
PKSET1,	CLR
	STC D1+2	/CLR STORE DISP.PLS.
	SET I 3
	D1+4		/DISP TBL PTR
	LDA 
	T1+4
	STA I 3
	LDA 
	T1+3
	STA I 3
	LDA 
	T1+2
	STA I 3
	LDA 
	T1+1
	STA I 3
	LDA		/SAVE TIME AT SLOPE
	SEC
	STC T1+16	/SEC
	LDA
	MSEC
	STC T1+17	/MSEC
	JMP POVER1-3
PEAK1,  LDA
	T1+6
	SAE I		/FILL CH1 DISPT?
	D1+37
	SKP		/NO
	JMP POVER1	/YES
	SET 3
	T1+6		/DIS.T.PTR
	LDA
	T1+1		/SAM...
	STA I 3		/...TO DIS.T.
	LDA
	3
	STC T1+6	/SAVE PTR
POVER1,	LDA
	T1+10		/STORE FLAG SET?
	AZE
	JMP INCLR1	/YES
	LDA		/NO
	T1+11		/POVER CTR>0?
	AZE
	JMP WIDTH1	/YES
	LDA		/NO
	T1+1
	COM		/ -SAM...
	ADA
	T1+2		/FROM PREV.SAM
	ADA
	PCRIT		/CRITN PEAKOVER
	APO		/REACH CRITN?
	JMP INCLR1	/NO
	LDA		/YES. SAVE...
	SEC		/  TIME & SAM
	STC T1+13	/ SEC.
	LDA
	MSEC
	STC T1+14	/ MSEC.
	LDA
	T1+2		/PEAK SAM...
	STC T1+15	/ SAVED.
	LDA		/POVER CURSOR
	3
	ADA I
	-1
	STC .+4
	LDA
	PCRIT
	STA
	0000		/REPLACED
WIDTH1,	LDA I
	1
	ADM
	T1+11		/+1 TO POVER CTR
	LDA
	T1+15		/PEAK SAM
	SCR 1		/DIV. BY 2...
	COM
	ADA		/>SAM? (I.E.,BELOW
	T1+1		/HALF-DECAY POINT?)
	APO I
	JMP INCLR1	/NO
	LDA		/YES.CHECK WIDTH
	T1+7		/PD CTR>WIMIN1?
	COM
	ADA		/(N SAMS >PK DET?)
	WIMIN1
	APO I
	JMP INCLR1-3	/NO.NARROW.SET FLAG
	LDA
	WIMAX1   	/MODIFIED WIMAX...
	COM
	ADA
	T1+7		/>PD.CTR?
	APO I		/(MAX.WIDTH OK?)
	JMP INCLR1-3	/NO.WIDE.SET FLAG
	IOB		/YES
	MONON+1		/MONO PULSE 1 ON
	LDA		/STORE PEAK TIME
	T1+16		/SEC
	STC STOS
	LDA
	T1+17		/MSEC
	STC STOM
	LDA
	T1+15		/AMPLITUDE OF PK
	STC STOBR
	LDA I		/CHAN. I.D.
	1
	JMP STORE
	IOB
	MONOF+1		/MONO PULS 1 OFF
	LDA I
	2000
	STC D1+2	/DISP.STORE FLAG
	LDA I
	1
	STC T1+10	/SET STORE FLAG
INCLR1, LDA I
	1	
	ADM
	T1+7		/+1 TO PD.CTR
	SAE
	FILTR1		/FILTER
	JMP RETRN1
	CLR
	STC T1+10	/CLR STORE FLAG
	STC T1+7	/CLR PD.CTR.
        STC T1+11	/CLR POVER CTR
	JMP RETRN1
STORE,	COM
        ADA I
	1
	STC .+10		/- CH.NO.+1
	LDA		/DF CONTROL
	SAVEDF
	ADA I
	640
	STC .+1
	LDF 2		/REPLACED
	LDA I
	0000		/REPLACED
	STA DATSTO	/STORE -CH.NO.+1
	LDA
	ROTCTR
	STA  I DATSTO	/STORE ROTATION CTR.
        LDA I
STOS,	0000		/REPLACED
	STA I DATSTO 	/STORES SECONDS
	LDA I
STOM,	0000		/REPLACED
	STA I DATSTO	/ STORES MSECS
	LDA I
STOBR,	0000		/REPLACED
	STA I DATSTO	/STORES AMPLITUDE
	XSK I DATSTO
	LDA
	DATSTO
	COM
	ADA I
	3760		/IS DF POINTR> 1760?
	DJR
	APO I
	JMP STOPDA-3	/NO
	CLR		/YES.ZERO REST OF DF
	STA DATSTO
	DJR
	XSK I DATSTO	/END OF DF?
	JMP .-3		/NO
	STA DATSTO      /YES
	XSK I DATSTO
	IOB
	6214
	ROR 1
	SAE 
        LASTDF	        /LAST DF?
	SKP		/NO
	JMP WRITE	/YES.WRITE ON TAPE.
	ADA I
	1		/INCR. DF
	STC SAVEDF
	IOB
	6214		/RELAY LIGHTS...
	ROR 3		/...AS 8K MF MONITR
	BSE I
	0040		/KEEP RELAY 0
	ATR
	IOB
	6244		/RESTORE MEM.FLD
	JMP 0		/RETURN TO CALL
STOPDA,	RTA
	BCL I
	0040
	ATR		/RELAY 0 OFF
	LDA		/DF CONTROL
	SAVEDF
	ADA I
	640
	STC .+1
	LDF		/REPLACED
        HLT		/SAFETY STOP
	CLR
	STA DATSTO
	XSK I DATSTO
	JMP .-3 	/ZEROS REST OF DF.
	STA DATSTO
	IOB
	6214
	ROR 1
	STC LASTDF	/DF TO LASTDF
WRITE,	LDF 2		/BEGIN WRITE,DF2
	CLR
	ATR		/RELAYS OFF
	LDA I
	207		/RING TTY BELL
	PDP
	PMODE
	TLS
	TSF
	JMP .-1
	LINC
	LMODE
WRITMO,	SET I 2		/COUNTER OF DFS
	-4
	LDA
	MTBLK
	BCL I		/CUT M OFF MTBLK
	7000
	ADA I
	4000		/M=4
	STA
	MTBLK		/SAVE NEW MTBLK
INCR,	STC .+2
	WRI 10		/WRITE ON UNIT 1
	4000		/REPLACED
	LDA I
	1001		/INCR M AND T BLKS
	ADM
	MTBLK
	XSK I 2		/4 MBLKS WRITN?
	JMP INCR	/NO
	LDA I		/YES
	-1
	ADM		/COUNTERACT 1S COMPL.
	MTBLK
	BCL I
	7000		/TBLK ONLY
	COM
	ADA
	LASTBK		/LAST TBLK ALLOWED
	APO		/PAST LAST TBLK?
	JMP .+10	/YES. PRINT TBLK
	CLR		/READ DF.
	IOB
	6214
	ROR 1
	SAE		/LAST DF WRITN?
	LASTDF
	JMP INCR04	/NO
	LDA		/YES. PRINT LAST
	MTBLK		/...TBLK NUM,
	ADA I
	-1
	JMP OCTPRT
	JMP SPACE	/SPACE
	JMP SPACE	/"
	LDA 
	CORE
	STC LASTDF	/RESET LASTDF
	JMP 400		/..& START AGAIN
INCR04, ADA I
	641		/INCR. DF
	STC .+1
	LDF		/REPLACED
	JMP WRITMO
/
	*1400
OCTPRT,	BCL I
	7000
	STA
	TEMRY
	SET I 6
	-4
NASCII,	LDA
	TEMRY
	ROL 3		/SHUFFLE DIGITS
	STA
	TEMRY
	BCL I
	7770
	ADA I
	260		/DIGIT TO ASCII
	PDP
	PMODE
	TLS
	TSF
	JMP .-1
	LINC
	LMODE
	DJR
	XSK I 6		/LAST DIGIT?
	JMP NASCII
SPACE,	LDA I
	240		/TYPE A SPACE
	PDP
	PMODE
	TLS
	TSF
	JMP .-1
	LINC
	LMODE
	JMP 0
REELCT, SAM 10		/TAKE SAM FROM CH 10
	ADA I
	-377		/  -1/2 VOLT
	APO I		/POS. PULSE?
	JMP .+4
	CLR		/NO. CLEAR FLAG...
	STC CFLAG
	JMP RETRN0	/AND RETURN.
	LDA I		/YES.
	-377
	STC REELCT+2	/RE-FORM THRESH.
	CLR		/YES. PULSE DET.
	SAE		/FLAG SET?
	CFLAG
	JMP RETRN0	/YES. RETURN.
	LDA I		/NO...
	1
	ADM 
        CFLAG	       / ...SET FLAG...
	ADM 
        PLSCTR	        /AND INCR. PULSECTR.
	AZE		/PULSCTR OVERFLOW?
	JMP RETRN0	/NO. RETURN.
	LDA I		/YES. RESET PULSCTR
	-3
	STC PLSCTR
	LDA I
	1
	ADM
	FUDGE		/INCR.FUDGE CTR.
	SAE I		/FUDGE OVERFLO?
	14
	JMP .+5		/NO. RESET NORMALLY.
	LDA I		/YES. FUDGE RESET.
	-4
	STC PLSCTR
	STC FUDGE	/AND CLEAR FUDGE CTR.
	LDA I		/ AND INCREMENT
	1               / ROTATION CTR.
	ADM 
        ROTCTR          
	SAE		/COUNTER OVRFLO?
	FOOT8
	JMP RETRN0	/NO. RETURN.
	CLR		/YES. RESET.
	STC ROTCTR
	JMP RETRN0	/RETURN
CDISP,	LDA
	ROTCTR		/ROTATION COUNTS...
	ADA I
	-3720		/>2000 ?
	APO
	JMP .+4		/NO
	SET I 10
	DSCTAB+3
	JMP CDISP2
	LDA
	ROTCTR
	ADA I
	-1750		/>1000 ?
	APO
	JMP .+4
	SET I 10
	DSCTAB+1
	JMP CDISP2
	SET I 10
	DSCTAB-1	/<1000
	LDA
	ROTCTR
	JMP CDISP2
/
	PAGE
CDISP2,	PDP		/...CONV. TO DECIMAL
	PMODE
          DCA INPUT             /STORE BINARY
          TAD CONTRL            /SET UP TABLE
          DCA POINTR            /POINTERS
          CLL
          TAD COUNT             /SET BIT 7=1; 8RALS
          DCA NUMBER            /WILL PUT IT IN LINK
          TAD INPUT
POINTR,   TAD TABLE             /OR TABLE+1, TABLE+2, ETC.
          SZL                   /IF C(L)=1, INPUT>-TABLE
          DCA INPUT             /IF SO: INPUT=INPUT+TABLE
          CLA
          TAD NUMBER
          RAL                   /PUT THIS BIT IN ANSWER
          ISZ POINTR            /UPDATE TABLE POINTER
          SNL                   /IF LINK=1, ALL DONE
          JMP POINTR-2
          CLL RTL               /CONVERTED 2 BCD
          RTL                   /CHARACTERS
          TAD INPUT             /SHIFT LEFT AND ADD
	LINC
	LMODE
          JMP DECDIS             /THE THIRD
	PMODE
CONTRL,   TAD TABLE
INPUT,    0
NUMBER,   0
COUNT,    0020
TABLE,    -1440                 /-800(10)
          -0620                 /-400
          -0310                 /-200
          -0144                 /-100
          -0120                 /-80
          -0050                 /-40
          -0024                 /-20
	-0012		/-10
	LMODE
DECDIS,	STA		/STORE DECIMAL
	BCDROT		/...ROTATION CTR
	SCR 7           / 100 (DOUBLED)
	BCL I
	7741
	ADA I
	DSCTAB-1       /GENERATE ADDRESS
	STC 5          /...OF CHARACTER
	LDA 		/GET DECIMAL ROT CTR
	BCDROT
	SCR 3		/10 (DOUBLED)
	BCL I		/CLEAR HIGH ORDER
	7741
	ADA I
	DSCTAB-1
	STC 6
	LDA 		/ LOW ORDER
	BCDROT
	ROL 1		/ DOUBLE
	BCL I
	7741
	ADA I 
        DSCTAB-1
        STC 7
	LDA I          /VERT.
	340
	SET I 1       /HOR.
	210
	DSC I 10
	DSC I 10
	XSK I 1
	XSK I 1
	DSC I 5
	DSC I 5
	XSK I 1
	XSK I 1
	DSC I 6
	DSC I 6
	XSK I 1
	XSK I 1
	DSC I 7
	DSC I 7
	JMP CURINL
PLSCTR,	0
FUDGE,	0
ROTCTR,	0
DSCTAB,	4136		/0
	3641		
	2101            /1
	0177		
	4523		/2
	2151
	4122		/3
	2651
	2414		/4
	0477
	5172		/5
	0651
	1506		/6
	4225
	4443		/7
	6050
	5126		/8
	2651
	5122		/9
AAAEND, 3651
/
	SEGMNT 1
	T2=130
	T3=150
	*360
SIMFL2,	1
SIMFL3,	1
	*400
TWO,	LDF 0
	LDA I
	-1
	ADM
	SIMFL2		/ARE SAM INVL FLAGS
	AZE		/...STILL SET?
	JMP END2-1	/YES.DONT SAM CH.2
	LDA		/NO. RESET...
	SIMUL2+2000
	STC SIMFL2
	LDA		/...AND SAM CH.2
	T2+4		/OLDEST...
	
	COM
	ADM		/...SUBT. FR.SUM
	T2+5
	SET I 2		/B2=SHUFFLE CTR
	-3
	SET I 3
	T2+3		/B3=SHUF. INDEXR
SHUFL2,	LDA 3		
	STA I 3		
	LDA I
	-2
	ADM
	3
	XSK I 2
	JMP SHUFL2
	SAM 12
	ADA 
	FLUTRC+2000	/FLUTTER COMP.
	STA
	T2+1
	ADM
	T2+5		/SAM+SUM
	LDA
	T2+7
	AZE		/PD CTR >0?
	JMP PEAK2	/YES
	SAM 2		/THRESHOLD A-D 2
	STA		/TO DISP. TABLE
	D2+2003
	COM
	ADD T2+1	/SAM...
	APO		/> THRESH.?
	JMP TIMCK2-4	/ NO
SLOPE2,	LDA		/YES
	T2+5            /        SUM
	SCR 1		/  SUM/2
	ADD T2+4	/  +X4
	COM		/  -""
	ADD T2+2	/  +X2
	ADD T2+1
	ADD T2+1	/  +2X1
	SCR 1		/ALL /2
	STC T2		/        SLOPE
	RSW		/CRITN
	COM
	ADD T2
	APO I		/REACH CRITN?
	JMP PKSET2	/YES
	LDA		/NO
	T2+1
	STA
	D2+2004		/SAM TO DISPT.
TIMCK2,	LDA
	T2+13		/TIME OF LAST PEAK
	COM
	ADA
	SEC+2000	/CURRENT TIME
	ADA I
	-4
	APO		/4 SEC. ELAPSED?
	JMP END2-1	/NO
	CLR		/YES.CLR STORE PLS
	STA
	D2+2002
	LDA		/DISPT CLEARED?
	D2+2006		/(THIS LOC CLR?)
	AZE I
	JMP END2-1	/YES.
	SET I 3		/NO. CLR DISPT.
	D2+2004
	CLR
	STA I 3
	LDA I
	D2+2037
	SAE
	3
	JMP .-6
	JMP END2-1
PKSET2,	CLR
	STA	/CLR STORE DISP.PLS
	D2+2002
	SET I 3
	D2+2004		/DISP TBL PTR
	LDA 
	T2+4
	STA I 3
	LDA 
	T2+3
	STA I 3
	LDA 
	T2+2
	STA I 3
	LDA 
	T2+1
	STA I 3
	LDA		/SAVE TIME OF SLOPE
	SEC+2000
	STC T2+16	/SEC
	LDA
	MSEC+2000
	STC T2+17	/MSEC
	JMP POVER2-3
PEAK2,	LDA
	T2+6
	SAE I		/FILL CH2 DISPT?
	D2+2037
	SKP		/NO
	JMP POVER2	/YES
	SET 3
	T2+6		/DIS.T.PTR
	LDA
	T2+1		/SAM...
	STA I 3		/...TO DIS.T.
	LDA
	3
	STC T2+6	/SAVE PTR
POVER2,	LDA
	T2+10		/STORE FLAG SET?
	AZE
	JMP INCLR2	/YES
	LDA		/NO
	T2+11		/POVER CTR>0?
	AZE
	JMP WIDTH2	/YES
	LDA		/NO
	T2+1
	COM		/ -SAM...
	ADA
	T2+2		/FROM PREV.SAM
	ADA
	PCRIT+2000	/CRITN PEAKOVER
	APO		/REACH CRITN?
	JMP INCLR2	/NO
	LDA		/YES. SAVE...
	SEC+2000	/  TIME & SAM
	STC T2+13	/ SEC.
	LDA
	MSEC+2000
	STC T2+14	/ MSEC.
	LDA
	T2+2		/PEAK SAM...
	STC T2+15	/ SAVED.
	LDA		/POVER CURSOR
	3
	ADA I
	-1
	STC .+4
	LDA
	PCRIT+2000
	STA
	0000		/REPLACED
WIDTH2,	LDA I
	1
	ADM
	T2+11		/+1 TO POVER CTR
	LDA
	T2+15		/PEAK SAM
	SCR 1		/DIV. BY 2...
	COM
	ADA		/>SAM? (I.E.,BELOW
	T2+1		/HALF-DECAY POINT?)
	APO I
	JMP INCLR2	/NO
	LDA		/YES.CHECK WIDTH
	T2+7		/PD CTR>WIMIN2?
	COM
	ADA		/(N SAMS >PK DET?)
	WIMIN2+2000
	APO I
	JMP INCLR2-3	/NO.NARROW.SET FLAG
	LSW
	SCR 9
	BCL I		/LEFT SW.1ST DIGIT=
	7770		/NO.SAMS TO
	STC .+7		/AUGMENT WIMAX2
	LSW
	SCR 6
	BCL I
	7770		/2ND DIGIT=NO.SAMS
	COM		/TO DIMINISH WIMAX2
	ADA I
	0000		/REPLACED
	ADA
	WIMAX2+2000	/MODIFIED WIMAX...
	COM
	ADA
	T2+7		/>PD.CTR?
	APO I		/(MAX.WIDTH OK?)
	JMP INCLR2-3	/NO.WIDE.SET FLAG
	IOB		/YES
	MONON+2		/MONO PULSE 2 ON
	LDA		/STORE PEAK TIME
	T2+16		/SEC
	STA
	STOS+2000
	LDA
	T2+17		/MSEC
	STA
	STOM+2000
	LDA
	T2+15		/AMPLITUDE OF PK
	STA
	STOBR+2000
	LDA I		/CHAN. I.D.
	2
	LIF 0
	JMP STORE
	IOB
	MONOF+2		/MONO PULS 2 OFF
	LDA I
	2000
	STA     	/DISP.STORE FLAG
	D2+2002
	LDA I
	1
	STC T2+10	/SET STORE FLAG
INCLR2, LDA I
	1	
	ADM
	T2+7		/+1 TO PD.CTR
	SAE
	FILTR2+2000	/FILTER
	JMP END2-1
	CLR
	STC T2+10	/CLR STORE FLAG
	STC T2+7	/CLR PD.CTR.
        STC T2+11	/CLR POVER CTR
	LIF 0
END2,	JMP RETRN2
THREE,	LDF 0
	LDA I
	-1
	ADM
	SIMFL3		/ARE SAM INVL FLAGS
	AZE		/...STILL SET?
	JMP END3-1	/YES.DONT SAM CH3
	LDA		/NO. RESET...
	SIMUL3+2000
	STC SIMFL3
	LDA		/...AND SAM CH.3
	T3+4		/OLDEST...
	
	COM
	ADM		/...SUBT. FR.SUM
	T3+5
	SET I 2		/B2=SHUFFLE CTR
	-3
	SET I 3
	T3+3		/B3=SHUF. INDEXR
SHUFL3,	LDA 3		
	STA I 3		
	LDA I
	-2
	ADM
	3
	XSK I 2
	JMP SHUFL3
	SAM 13
	ADA 
	FLUTRC+2000	/FLUTTER COMP.
	STA
	T3+1
	ADM
	T3+5		/SAM+SUM
	LDA
	T3+7
	AZE		/PD CTR >0?
	JMP PEAK3	/YES
	SAM 3		/THRESHOLD A-D 3
	STA		/TO DISP. TABLE
	D3+2003
	COM
	ADD T3+1	/SAM...
	APO		/> THRESH.?
	JMP TIMCK3-4	/ NO
SLOPE3,	LDA		/YES
	T3+5            /        SUM
	SCR 1		/  SUM/2
	ADD T3+4	/  +X4
	COM		/  -""
	ADD T3+2	/  +X2
	ADD T3+1
	ADD T3+1	/  +2X1
	SCR 1		/ALL /2
	STC T3		/        SLOPE
	RSW		/CRITN
	COM
	ADD T3
	APO I		/REACH CRITN?
	JMP PKSET3	/YES
	LDA		/NO
	T3+1
	STA
	D3+2004		/SAM TO DISPT.
TIMCK3,	LDA
	T3+13		/TIME OF LAST PEAK
	COM
	ADA
	SEC+2000	/CURRENT TIME
	ADA I
	-4
	APO		/4 SEC. ELAPSED?
	JMP END3-1	/NO
	CLR		/YES.CLR STORE PLS
	STA
	D3+2002
	LDA		/DISPT CLEARED?
	D3+2006		/(THIS LOC CLR?)
	AZE I
	JMP END3-1	/YES.
	SET I 3		/NO. CLR DISPT.
	D3+2004
	CLR
	STA I 3
	LDA I
	D3+2037
	SAE
	3
	JMP .-6
	JMP END3-1
PKSET3,	CLR
	STA	/CLR STORE DISP.PLS
	D3+2002
	SET I 3
	D3+2004		/DISP TBL PTR
	LDA 
	T3+4
	STA I 3
	LDA 
	T3+3
	STA I 3
	LDA 
	T3+2
	STA I 3
	LDA 
	T3+1
	STA I 3
	LDA		/SAVE TIME AT SLOPE
	SEC+2000
	STC T3+16	/SEC
	LDA
	MSEC+2000
	STC T3+17	/MSEC
	JMP POVER3-3
PEAK3,	LDA
	T3+6
	SAE I		/FILL CH3 DISPT?
	D3+2037
	SKP		/NO
	JMP POVER3	/YES
	SET 3
	T3+6		/DIS.T.PTR
	LDA
	T3+1		/SAM...
	STA I 3		/...TO DIS.T.
	LDA
	3
	STC T3+6	/SAVE PTR
POVER3,	LDA
	T3+10		/STORE FLAG SET?
	AZE
	JMP INCLR3	/YES
	LDA		/NO
	T3+11		/POVER CTR>0?
	AZE
	JMP WIDTH3	/YES
	LDA		/NO
	T3+1
	COM		/ -SAM...
	ADA
	T3+2		/FROM PREV.SAM
	ADA
	PCRIT+2000	/CRITN PEAKOVER
	APO		/REACH CRITN?
	JMP INCLR3	/NO
	LDA		/YES. SAVE...
	SEC+2000	/  TIME & SAM
	STC T3+13	/ SEC.
	LDA
	MSEC+2000
	STC T3+14	/ MSEC.
	LDA
	T3+2		/PEAK SAM...
	STC T3+15	/ SAVED.
	LDA		/POVER CURSOR
	3
	ADA I
	-1
	STC .+4
	LDA
	PCRIT+2000
	STA
	0000		/REPLACED
WIDTH3,	LDA I
	1
	ADM
	T3+11		/+1 TO POVER CTR
	LDA
	T3+15		/PEAK SAM
	SCR 1		/DIV. BY 2...
	COM
	ADA		/>SAM? (I.E.,BELOW
	T3+1		/HALF-DECAY POINT?)
	APO I
	JMP INCLR3	/NO
	LDA		/YES.CHECK WIDTH
	T3+7		/PD CTR>WIMIN3?
	COM
	ADA		/(N SAMS >PK DET?)
	WIMIN3+2000
	APO I
	JMP INCLR3-3	/NO.NARROW.SET FLAG
	LSW
	SCR 9
	BCL I		/LEFT SW.1ST DIGIT=
	7770		/NO.SAMS TO
	STC .+7		/AUGMENT WIMAX3
	LSW
	SCR 6
	BCL I
	7770		/2ND DIGIT=NO.SAMS
	COM		/TO DIMINISH WIMAX3
	ADA I
	0000		/REPLACED
	ADA
	WIMAX3+2000	/MODIFIED WIMAX...
	COM
	ADA
	T3+7		/>PD.CTR?
	APO I		/(MAX.WIDTH OK?)
	JMP INCLR3-3	/NO.WIDE.SET FLAG
	IOB		/YES
	MONON+3		/MONO PULSE 3 ON
	LDA		/STORE PEAK TIME
	T3+16		/SEC
	STA
	STOS+2000
	LDA
	T3+17		/MSEC
	STA
	STOM+2000
	LDA
	T3+15		/AMPLITUDE OF PK
	STA
	STOBR+2000
	LDA I		/CHAN. I.D.
	3
	LIF 0
	JMP STORE
	IOB
	MONOF+3		/MONO PULS 3 OFF
	LDA I
	2000
	STA     	/DISP.STORE FLAG
	D3+2002
	LDA I
	1
	STC T3+10	/SET STORE FLAG
INCLR3, LDA I
	1	
	ADM
	T3+7		/+1 TO PD.CTR
	SAE
	FILTR3+2000	/FILTER
	JMP END3-1
	CLR
	STC T3+10	/CLR STORE FLAG
	STC T3+7	/CLR PD.CTR.
        STC T3+11	/CLR POVER CTR
	LIF 0
END3,	JMP RETRN3
/
	SEGMNT 2
	*20
	LIF 0
	JMP 20		/ALLOWS START 20