*20
///JSDATA
/
/DATA COLLECTOR FOR JANET STEVENS
/COLLECTS DATA ACCORDING TO PBLOCK 0
/NORMAL SETTINGS ARE 16 SEC,1024 POINTS
/ENSEMBLE DELAY=244 SEC
/CONTINGENCY CHANNEL WILL CAUSE
/A COLLECTION OF ONE SEGMENT
/AT ANY TIME
/THIS SEGMENT IS FOLLOWED BY A 30 HZ
/SINE WAVE IN ONE BLOCK
/IF CONTINGENCY CHANNEL COMES ON
/DURING NORMAL SEGMENT COLLECTION
/THE SEGMENT WILL BE FOLLOWED BY A
/20 HZ SINE WAVE IN ONE BLOCK
/
/AFTER SAMPLING CALLS JSGLITCH
/FOR DATA CLEANUP
/
/OPERATION:
/SAM--START SAMPLING
/AVG--CALL GLITCH
/OUTPUT IS TO UNIT 2
	SEGMNT 5
	*20
START,	LDF 7
	IOB 12
	7077		/PBLOCK 0
	JMP SETPAR
/
D0,	LIF 4
	INTRAC
	I1
	O1
/
/READY TO SAMPLE
/
FY,	JMP DELWAT	/TAPE STARTUP
DOSAM,	LDA I
	0
	STC CONLOC	/NORMAL FLAG
	JMP SETCLK
	JMP SAMBUF
/COUNT SEGMENT
	LDA I
	1
	ADM I
NSEG,	0
	SAE I
DESSEG,	0
	SKP
	JMP ENDSAM	/FINISHED SAMPLING
/SEGMENT DELAY
	LDA
	ENWDES
	AZE
	JMP ENSWAT
	JMP DOSAM
/
/END OF SAMPLING
/SET UP HEADER BLOCK
/
ENDSAM,	LDF 7
	LDA I
	1
	AXO
	LDA
	CURBLK
	STA
	2004
	WRC
	4000
	LDA I
	10
	AXO
	JMP GLITCH
	EJECT
/
/SUBROUTINES FOR DATA COLLECTION
/
DELWAT,	SET 3
	0
	IOB 
	6002
/
	SET I 6
DEL,	0
/
/.01 SEC WAIT LOOP
/
	NOP
	XSK I 5
	JMP .-2
/
/TIMES DEL
/
	XSK I 6
	JMP .-4
	JMP 3
/
	 
	 
ENSWAT,	LDA
	0
	STC ENX
	STC ENWCNT
	LDA I
	1
	STC CONLOC
ENS1,	IOB 3
	5100
	144
ENS2,	JMP SAMTIM
	LDA I
	-1
	ADM I
ENWCNT,	0
	ADA I
ENWDES,	0
	APO
ENX,	JMP		/FINISHED WAITING
/
	LDA I
CONFLG,	0
	AZE I
	JMP ENS2
/
/COLLECT A SEGMENT
/
	LDA I
SEGW,	0
	ADM
	ENWCNT
	JMP SETCLK
	JMP SAMBUF
	JMP ENS1
	EJECT
/
/SET UP PARAMETERS FOR SAMPLING
/
SETPAR,	SET 3
	0
	LDF 7
	LDA
	P5 	/CONTINGENCY CHANNELS
	JMP CHSET
	STC CONCH
	ADD INVT
	STC CONCH+1
/
	LDA
	P1 	/DATA CHANNELS
	JMP CHSET
	STC DATCH
	ADD INVT
	STC DATCH+1
/
	LOAD
	P77 	/TRUE VOLTS
	FMUL
	SEVN
	FIX
	FAC
	ISTOR1
	TRUE
/
	SFLOAT
	P25		/ENSEMBLE DELAY
	FDIV
	P37		/TAPE SPEED
	FIX
	FAC
	ISTOR1
	ENWDES
/
	LDA
	P20 	/  SEGMENTS
	STC DESSEG
/
	LDA 
	P17 	/  SAMPLES
	STC DESSAM
/
	LDA
	P24		/TAPE DELAY
	COM
	STC DEL
/
/GET CONTINGENCY FUDGE
/
	SFLOAT
	P44		/SEG LNG
	FDIV
	P37		/TAPE SPEED
	FIX
	FAC
	ISTOR1
	.+2
	LDA I
	0
	COM
	STC SEGW
/
/
GRAT,	LDA
	P26
	STC CLRAT
	LDA
	P27
	STC CLTIC
	JMP SETFST
	JMP 3
/
SETFST,	SET I 10
	3777
	SET I 11
	-400
	SET I 5
	4000
	SET I 16
	TAPBUF
	SET I 17
	TAPBUF
	STC TAPFLG
	STC NSEG
	LDA I
	0 	/500 2 TAPE
	STC CURBLK
/
/POSITION DATA TAPE
/
	LDA I
	1021
ONE,	AXO
	LDA I
	4000
	TMA
	RDC
	0
/
	JMP 0
/
/CHANNEL SETUP SUBROUTINE
/
CHSET,	STC CHTST
	ADD 0
	STC CHSETX
	LDA
	P15
	STC INVCH
/
	SET I 14
	10
	SET I 15
	-14
/
/INVERT TEST
/
TS,	LDA I
	NOP
	SRO I
INVCH,	0
	ADD ONE
	STC INVT
/
/TEST FOR CHANNEL
/
	SRO I
CHTST,	0
	JMP GOTCH
	XSK I 14
	XSK I 15
	JMP TS
/
GOTCH,	LDA
	14
	BSE I
	SAM
CHSETX,	JMP
/
/SET CLOCK
/
/
SETCLK,	IOB 3
CLRAT,	0
CLTIC,	0
	JMP 0
INVT,	NOP
/
SEVN,	2
	3777
	7777
	EJECT
/
/THE SAMPLER
/
SAMBUF,	LDA
	0
	STC SAMX
	STC NSAM
/
/
SN,	JMP SAMTIM
/
DATCH,	SAM
	NOP
	SCR 1
	STA I
	0
	JMP BSTUF
	LDA 
	.-3
	SCR 1
	DIS I 5
	LDA I
	177
	DIS 5
	LDA I
	-177
	DIS 5
	NOP
	LDA I
	1
	ADM I
NSAM,	0
	SAE I
DESSAM,	0
	JMP SN
/
/SAMPLING FINISHED
/WAIT FOR TAPE BUFFER
/AND RESET CLOCK
/
SAMDON,	LDA
	CONFLG
	AZE
	JMP CONDMP
	JMP SAMTIM
	LDA
	TAPFLG
	APO
	JMP SAMDON
	STD
	JMP .-1
/
	IOB 3
	5100
	144
/
	LDA I
	10
	AXO
SAMX,	JMP
/
/
/STUFF DATA INTO BUFFER
/
BSTUF,	SET 15
	0
CURBNK,	LDF 6
	STA I 10
	XSK I 11
	JMP 15
/
/BUFFER OVERFLOW
/
	SET I 11
	-400
	LDA
	CURBNK
	ROL 7
	STA 17
	ROL 3
	STA I 17
	LDA
	10
	BCL I
	6000
	BSE 17
	BCL I
	377
	STA 17
	XSK I 17
	CLR
	COM
	STC TAPFLG
	ADD 17
	SAE I
	TEND
	JMP .+3
	SET I 17
	TAPBUF
	XSK 10
	JMP 15
	LDA
	CURBNK
	ADD ONE
	SAE I
ENDBNK,	LDF 10 	/UMB 14 12K12K12K
	JMP .+3
	LDA I
FSTBNK,	LDF 6
	STC CURBNK
	JMP 15
	EJECT
/
/CONTINGENCY TESTER AND DUMPER
/
CONTST,	SET 1
	0
CONCH,	SAM
	NOP
	SCR 7
	AZE I
	CLR
	SAE I
TRUE,	0
	JMP 1
	LDA I
	1
	STC CONFLG
	JMP 1
/
/
CONDMP,	LDA
	0
	STC CONDX
	STC CONFLG
	LDA I
CONLOC,	0
	ROL 10
	ADA I
	777
	STC 1
	SET I 2
	-400
	LDA I 1
	JMP BSTUF
	XSK I 2
	JMP .-3
CONDX,	JMP
	EJECT
/
/THE CLOCK ROUTINE
/USED ALSO TO PRIME
/TAPE BUFFER OUTPUT
/
SAMTIM,	SET 3
	0
	IOB
	6002
SW,	TAPTST
	IOB
	6131
	JMP K
	CLR
	IOB 
	6135
	JMP 3
/
K,	JMP CONTST
	IOB
	6031
	JMP SW
	IOB
	6036
	SAE I 
	377
	JMP SW
	JMP ENDSAM
/
/TAPE BUFFERER
/
	TAPTST=JMP .
/
	LDA
	0
	STC SX
	STD
	JMP SX
/
/CHECK IF MORE TAPE
/
	LDA I
TAPFLG,	0
	APO I
	JMP SX
	ADD 17 	/PUT POINTER
	SAE
	16 	/PROCESS POINTER
	JMP TN
TAPDON,	CLR
	SET I 16
	TAPBUF
	SET 17
	16
	STC TAPFLG
	JMP SX
/
TN,	LDA 16
	BCL I
	777
	BSE I
	31 	/30 2 TAPE
	AXO
	LDA I
CURBLK,	0
	SAE I
	777
	SKP
	JMP TAPDON
	ADD ONE
	STA
	TPBLK
	STC CURBLK
	LDA I 16
	TMA
	XSK I 16
	LDA
	16
	SAE I
	TEND
	JMP .+3
	SET I 16
	TAPBUF
/
	WRI
TPBLK,	0
SX,	JMP
/
/TAPE BLOCK BUFFER AREA
/RING BUFFER WHICH HOLDS
/2 BANKS WORTH OF INFO
/
/FIRST WORD SETS AXO
/SECOND WORD SETS TMA
/
/
TAPBUF,	0
	0
/
	0
	0
/
	0
	0
/
	0
	0
/
	0
	0
/
	0
	0
/
	0
	0
/
	0
	0
/
TEND,	0
	EJECT
/MESSAGES AND DECISION TABLES
/
/
/SAM
/
O1,	2301
	1545
	4372
/
I1,	T1
	J1
T1,	SAMPL
	AVG
	0
/
J1,	JMP D0
	JMP FY		/SAMPLE
	JMP GLITCH	/CALL GLITCH
	EJECT
/
/GLITCH CALL
/
GLITCH,	IOB 3
	5100
	144
/CALL GLITCH
	LIF 4
	JMP 37		/CALL
	TEXT .JSGLITCH.
	0
/RESTART
	JMP START
/
	 
	 
/20 HZ SINE WAVE
	*1000
	0
/30 HZ SINE WAVE
	*1400
	0
	EJECT
/
/
/PARAMETER BLOCK ASSIGNMENTS
/
	P0=3400		/DATA TYPE
	P1=3401		/CURRENT CHAN.
	P2=3402		/CURRENT CHAN.
	P3=3403		/DATA CHAN.
	P4=3404		/DATA CHAN.
	P5=3405		/CONTINGENCY CH
	P6=3406		/CONTINGENCY CH
	P7=3407		/TRUE CONTING.
	P10=3410	/FALSE CONTING.
	P11=3411	/CONTING. WIDTH
	P12=3412	/TRUE CONTING.
	P13=3413	/FALSE CONTING.
	P14=3414	/CONTING. WIDTH
	P15=3415	/CHAN INVERSION
	P16=3416	/CHAN INVERSION
	P17=3417	/NO.SAMP IN SEG
	P20=3420	/NO.SEG IN ENSM
	P21=3421	/NO. ENSEMBLES
	P22=3422	/
	P23=3423	/BASELINE PNTS
	P24=3424	/TAPE DELAY
	P25=3425	/ENSEMBL DELAY
	P26=3426	/CLOCK RATE
	P27=3427	/CLOCK TICS
	P37=3437	/TAPE SPEED UP
/
/FLOATING POINT VARIABLES
/
	P42=3442	/MULT FACTOR
	P43=3445	/UV PER VOLT
	P44=3450	/SEG. LENGTH
	P45=3453	/TEMP
	P46=3456	/BASELINE DELAY
	P47=3461	/CONTING WIDTH
	P76=3566	/TEMP
	P77=3571	/TRUE VOLTS
	P100=3574	/FALSE VOLTS
	P101=3577	/TEMP
	INTRACT=JMP 42
/COMMAND NUMBERS.
	YES=17
	NO=20
	SAMPL=21
	AVG=30
/FLOATING POINT DEFINITIONS.
/
	FAC=0
	FSUB=1701
	FMUL=1702
	FDIV=1703
	LOAD=1704
	STORE=1705
	SETWRD=1706
	INPUT=1707
	OUTPUT=1710
	ISTOR1=1711
	SQRT=1712
	DFLOAT=1713
	SFLOAT=1714
	FIX=1715
	FADD=1716
	ISTOR2=1717
	FCOMP=1721
	FZER=1722
	FAPO=1723
	FAZE=1724
	RECIP=1725
	NEXTIN=1726
	SETIN=1727
	SETOUT=1730
	OUTBUF=1731
	PACFAC=1732
	SACFAC=1733
	FACAC=1734
	UNFIX=1735
/
/
/JSDATA
/JUNE 73