$6000
[ CENTRAL DISPATCHER
[ USE UNTILL PROGOFOP
[ IS INTEGRATED
[
[ STATUS IS PASSED TO
[ THE LINC IN THE AC:
[   +0 - NOT READY
[   +1 - COUNT DIFFERENT
[   +2 - SAME AS LAST
#DISP   0
JMS START
NOP
JMPi p-3
[
0
JMS READF
NOP
JMPi p-3
[
0
JMS STOP
6462 
JMPi p-3
[ 
[ 
[ 
#START  0
6454
JMPi START
[
#STOP   0
6452
JMPi STOP
[
#READF  0
CLA
IACA
6461
JMPi READF [NOT READY
JMSi READX
TAD CVXX
JMSi XFURX
NOP
JMPi READF
[
[ FROM OTHER ASSEMBLIES
#CVXX   6254 [ IN READ
#READX  6200 [ READ
#XFURX  6400 [ XFUR
#DEBUGX 6600 [ DEBUG
[ 
[ 
[ 
[ 
[ 
$6100
[ THIS DEBUG ROUTINE
[ FOR NON PROGOFOP USE
[ ASSEMBLE WITH DISP
[ START HERE TO USE
[
[ TTY KEY TO ALTERNATE :
[  DISABLE COUNTER
[  ENABLE SAME
HLT
#RDDB JMS START
CLA CLL
IACA [ CLEAR LINC AC
JMS READF
IAAC
SNA
JMP p-3 [ WAIT
ISSP [ TO SEE IT IN LINC
CLA CLL
TADi BE2
DCA TAB
ISZ TAB
[ PRINT LOOP
#RDBM   TADi TAB
ISZ TAB
TLS
TSF
JMP p-1
SZA CLA
JMP RDBM
[ DONE
KSF
JMP RDDB+1
KRB [STOP COUNTER ON KEY
JMS STOP
KSF
JMP p-1
KRB [ AWAY WE GO AGAIN
JMP RDDB
[ CONSTANTS
#BE2    2002
#TAB    0
[ MAKE SURE 2002=2777 uu
$3000
253
261
262
263
264
265
266
267
215
212
0
0
$6200
[ THIS PROGRAM READS THE VALUES
[ FROM THE BECKMAN COUNTER
#READ   DEB
CLA
6462
6451
NOP [ JUST TO BE SAFE
TAD CV
DCA CVX
TAD LS
DCA LSX
[ PUT OLD VALUE IN LS
[ NEW VALUE IN CV
TAD CN
DCA CNX [NUM OF REGISTERS
[
#REAX   TAD i CVX
DCA i LSX
NOP [ TIMEING
6464
NOP [ FOR TIMEING
DCA i CVX
ISZ CVX
ISZ LSX
ISZ CNX
JMP REAX
JMS BLAC [ BUMP LINC AC
[ COMPARE LAST WITH
[ CURRENT COUNT
TAD CV
DCA CVX
TAD LS
DCA LSX
TAD CN
DCA CNX
[ LOOP
#CMPL   TADi CVX
CIA
TADi LSX
ISZ CVX
ISZ LSX
SZA CLA
JMPi READ [ DIFFERENT
ISZ CNX
JMP CMPL
[ THE SAME
JMS BLAC [ ONCE MORE TO SHOW IT
JMPi READ
[
[ CONSTANTS
#CVX 0
#LSX 0
#CNX 0
#CN -3
#CV p+1
0
0
0
0
#LS p+1
0
0
0
0
[END
[
[ INCREASE LINC AC BY 1
#BLAC   0
CLA
IAAC
IAC
IACA
CLA CLL
JMPi BLAC
[ DEBUG FOLLOWS
#DEB HLT
JMP READ+1
$6400
[ THIS ROUTINE CONVERTS
[ THE COUNT TO ASCII
[ AND PUTS IT IN LINC
[ AT LOC IN BETA TWO REGISTER
#XFUR   0
DCA VAL [ INPUT LOC
TAD i BETA2
AND L1777
TAD L2000 [ LINC FIELD ONE
DCA PUTS
ISZ PUTS [ LOC OF SIGN
TAD PUTS
DCA PUT
ISZ PUT [ LOC OF DIGIT ONE
TAD M5
DCA CA [ NUM CHARACTERS
#XFB    TAD M3
DCA CB
TAD i VAL
CMA
RAL
DCA VALL
[ LOOP
#XFA    TAD VALL
RTL
RTL
DCA VALL
TAD VALL
[ CONVERT TO ASCII
AND L17
TAD L260
DCA i PUT
ISZ PUT
[ TEST FOR NEXT WORD
ISZ CB
JMP p+3
[ GET NEXT WORD
ISZ VAL
JMP XFB
[TEST FOR LAST CHAR
ISZ CA
JMP XFA
[ TEST LAST SIGN CHAR
SZL CLA
JMP p+4
[ PLUS
TAD L255
DCA i PUTS
JMP i XFUR
[ MINUS
TAD L253
DCA i PUTS
JMP i XFUR
#PUTS    0 [ LOC OF OUT SIGN
#VAL     0 [ INPUT POINT
#VALL    0 [ WORKING WORD
#PUT     0 [ OUTPUT POINT
#BETA2   2002 [ ASSUME BANK 1
#M3      -3
#M5      -5
#CA      0 [ CHAR COUNT
#CB      0 [ WORD COUNT
#L17     17 [ BCD MASK
#L1777   1777
#L2000   2000
#L260    260 [ ASCII NUMERIC
#L253    253 [ ASCII PLUS
#L255    255 [ ASCII MINUS
[
[
[ DEBUG FOLLOWS
CLA
TAD WW
JMS XFUR
HLT
JMP p-4
#WW     p+1 [ TABLE LOC
7755
6272
4400 [ +0123456
$2002
2777