Directory of image this file is from
This file as a plain text file

[LISTONG
[TRANSFERS LAP6
[MANUSCRIPTS TO G
[TRANSLATES MS TO
[G 6-BIT BCD CODE
[AND PACKS IN H.W.
[
[TO USE, AM DESIRED
[MS INTO LAP6, CV
[IF BINARY DESIRED,
[LO LISTONG
[
[1:MS POINTER
[2:OUTPUT POINTER
[3:BINARY POINTER
[4:BINARY FLAG
[5:TEXT FLAG
[10:JMP RETURN
[6,7:MISC.
[MS AREA: 1400-1777
[BINARY AREA: UMB 3
[OUTPUT: 1300-1357
[   PDP: 5300-5357
[
[FORMAT: SNS 3
[  DOWN: 86 COLUMNS
[   <UP: 120 COLUMNS>
[
[FORMAT: p, 1-2
[   BINARY, 4-5
[       MS, 7-41 <7-55>
[   LINE #, 42-43 <56-57>
[SNS 5 ON, NO BINARY
[SNS 1 ON, PAGE-EJECT FIRST
[
[
[AUTO-START
$1
JMP 20
$20
[SNS 1 ON, PAGE-EJECT
SNS 1
JMP p+10
[PAGE-EJECT ON G
LDA i
2077
STC 1300
LDA i
5000
NOP
PDP
[INITIALIZE RUN
[READ BINARY IN UMBS
UMB 3
RDC
4|240
RDC
5|241
RDC
6|242
RDC
7|243
UMB 1
RCG
3|244
UMB 3
[SET BINARY POINTER
SET i3
2020
[SET MS LINE COUNTER
CLR
STC 1M
[CLEAR TX FLAG
STC 2F
[SET MS COLUMN
[SNS 3 UP--120 COLUMNS
[SNS 3 DOWN--86 COLUMNS
SNS i 3
JMP 1S
LDA i
5341
STA
2M
STC 3M
[READ FIRST MS BLOCK
#1S RDC
3|250
SET i1
5401
SET i5
1777
#1A SET i2
5310
SET i4
1777
JMP 1I
[TEXT FLAG
XSK 5
#1F JMP 2X
LDH i1
[IGNORE SPACES
SHD i
1400
JMP p-3
[COMMENT
SHD i
6600
JMP 1C
[TAG
SHD i
2200
JMP 1T
[ORIGIN
SHD i
6500
JMP 1B
JMP p+2
#2A LDH i 1
[TEXT
SHD i
7000
JMP 1X+1
[PARAMETER
SHD i
6100
JMP 1E
[EOL
SHD i
1200
JMP 1L
[DONE
SHD i
7700
JMP 1Q
[TO G PRINTER CODE
JMP 1G
[TO OUTPUT AREA
STH i2
[DONE WITH BLOCK
XSK 1
JMP p+2
JMP 1R
[NEXT CHARACTER
JMP 2A
[
[
[TRANSLATE TO G
#1G ADA i
1P
STC p+2
LDA
<G-CODE>
JMP 0
#1P 12 [0
01 [1
02 [2
03 [3
04 [4
05 [5
06 [6
07 [7
10 [8
11 [9
20 [EOL
20 [DEL
20 [SPACE
37 [i, BIT 7
73 [p, CUR. LCN.
40 [-
60 [+
21 [|
36 [#, TAG
20 [CASE
61 [A
62 [B
63 [C
64 [D
65 [E
66 [F
67 [G
70 [H
71 [I
41 [J
42 [K
43 [L
44 [M
45 [N
46 [O
47 [P
50 [Q
51 [R
22 [S
23 [T
24 [U
25 [V
26 [W
27 [X
30 [Y
31 [Z
20 [META
20 [NO CODE
16 [, Q-MARK
13 [=
52 [u, BIT 8
33 [,
73 [.
35 [$, ORIGIN
17 [[
20 [_
55 ["
56 ["
72 [<
57 [>
32 []
54 [*
00 [:
77 [77, NO CODE
[END OF CODING
[
[INITIALIZE OUTPUT
[AREA TO SPACES
#1I SET 10
0
SET i6
1277
SET i7
-60
LDA i
2020
STA i6
XSK i7
JMP p-2
JMP 10
[
[FOUND SOME TEXT
#1X LDH i1
XSK i5
XSK i5
XSK i4
JMP 1G
STH i2
[MORE MS
XSK 1
JMP p+2
JMP 1R
[NEXT CHARACTER
LDH i1
[", END TX
SHD i
7100
JMP 3X
[EOL
SHD i
1200
JMP 3L
[LOOP UNTIL EOL
JMP 1X+4
[
[FORM TEXT COUNT
#2L SET 10
0
SET i6
5310
LDA
2
COM
ADA
6
ADM i
#2F COUNT
JMP 10
[
[OUTPUT TX MS
#3L SET i6
#3M 5355
LDA i
1
ADM
1M
JMP 1D
[DONE WITH TX
LDA
5
APO i
JMP p+6
[YES
LDA i
JMP 2X
STC 1F
STC 2F
JMP 1L
[NO
LDA i
20 [G CODE: EOL
STH i2
LDA i
JMP 1X
STC 1F
JMP 2L
JMP 1L
[
[END OF TX
#3X JMP 2L
ADA i
-1
BSE i
4000
STC 5
LDA i
71
JMP 1X+4
[
[FINISH TX BINARY
#2X XSK i5
JMP 1L
JMP 1A
[
[FOUND A TAG
#1T SET i2
5306
JMP 0
[
[FOUND A PARAMETER
#1E SET 10
0
[CHECK IF COMMENT
SET i6
5310
LDA
2
COM
ADA
6
ROL 1
STC p+2
SET i7
COUNT
LDH i6
SHD i
1700 [G CODE:[
JMP p+4
XSK i7
JMP p-5
XSK i4
LDA i
61
JMP 10
[
[FOUND A COMMENT
#1C SET i2
5306
XSK i4
JMP 0
[
[FOUND AN ORIGIN
#1B SET i7
-4
JMP 1G
STH i2
SET 6
1
CLR
STC 2B
LDH i6
[SHORT NUMBER
SHD i
1200
JMP p+7
ADA i
#2B <ORIGIN>
ROL 3
STC 2B
XSK i7
JMP p-11
LDA
2B
ROR 3
ADA i
2000
STC 3
XSK i4
JMP 2A
[
[READ ANOTHER MS
[BLOCK
#1R SRO i
2525
JMP 0
LDA i
1
ADM
p+2
RDC
3|250
SET i1
5377
JMP 0
[
[FOUND EOL
[OUTPUT TO G AND
[RE-INTITIALIZE
#1L XSK 4
JMP 1N
[SUPRESS BINARY
SNS i5
JMP 1N
LDA
3
ADA i
-4000 [CHECK UMB
APO i [IN UMB
JMP p+2
AZE i
JMP 1U
ADA i
2000
SET i6
5300
JMP 1D
LDA 3
SET i6
5303
JMP 1D
XSK i3
NOP
#1N XSK 5
JMP p+10
LDA i
1
ADM i
#1M LINE
SET i6
#2M 5355
JMP 1D
LDA i
5000
NOP
PDP
[READ MORE MS
XSK 1
JMP p+2
JMP 1R
JMP 1A
[BIN IN UMB
#1U UMB 1
ADA i
2000
STA
2U
SET i6
5300
JMP 1D
LDA
#2U <BIN>
UMB 3
JMP 1N-5
[DECODE BINARY, STORE
#1D SET 10
0
SET i7
-4
STC p+2
LDA i
<BINARY>
ROL 3
STA
p-3
BCL i
7770
JMP 1G
STH i6
XSK i7
JMP p-12
JMP 10
[
[FOUND 77-DONE
#1Q LDA i
5000
NOP
PDP
LDA i
2077
STC 1300
LDA i
5000
NOP
PDP
[RETURN TO LAP6
SET i15
701
SET i16
7200
JMP 15
[
[PDP-TO-G TRANSFER
$1000
#2G 0000 [<5000>
6002 [IOF
7300 [CLA CLJ
1220 [TAD FWA
6414 [ACLC
7300 [CLA CLL
1221 [TAD WC
6424 [ACWC
6404 [DB, INT
6402 [SKIP DB 0
5211 [JMP .-1
7300 [CLA CLL
6422 [SKIP OFL
5214 [JMP .-1
6421 [CLEAR OFL
5600 [JMP I 2G
5300 [FWA
0060 [WC
[
[
[CDC 160G ROUTINE
[FOR PRINTER
[
[00, LCF 5
[01, STF 1
[02, <A-MODE>
[O3, CIL
[O4, JPI 33 <TO O3>
[O5, 7677 <-10100>
[06, JPI 42 <00>
[07, EXF 30 <CLR 30>
[10, EXF 25 [SL PDP>
[11, INA
[12, EXF 24 <DB PDP>
[13, INP 44 <100>
[14, 160 <LWA-1>
[15, EXF 20 <SL PDP>
[16, LDI 57 <100>
[17, SBC
[20, 2020 <SPACES"
[21, ZJF 24 <PRINT>
[22, SBN 57 <2077>
[23, ZJF 20 <EJECT>
[24, JPI 33 <03>
[25, 0
[26, 0
[27, 0
[30, 0 <INTERRUPT>
[31, JPI 34 <07>
[32, 0
[33, 03 <WAIT LOOP>
[34, 07 <ROUTINE>
[35, 2700 <SLOW PDP>
[36, 2701 <DB PDP>
[37, 2702 <CLR 30>
[40, 0 <INTERRUPT>
[41, ERR
[42, 0
[43, EXF 10 <EJECT>
[44, JPI 33
[45, EXF 10 <AUTOEJ>
[46, EXF 10 <12-BIT>
[47, OUT 10 <100>
[50, 160 <LWA-1>
[51, EXF 03 <PRINT>
[52, JMP 33 <03>
[53, 604 <EJECT>
[54, 605 <PRINT>
[55, 627 <AUTOEJECT>
[56, 630 <12-BIT>
[57, 100 <FWA>
[
[ONE-CARD ROUTINE
[STARTS AT 06
[
[B SCHOR   5|15|69