*20
//MOD3
	 
/DECODE MODULE 3
/BLOCK 25
	 
/CONTENTS
/   ONE TAPE GETNAM
/   LEVEL 1 GET
/   LEVEL 1 STORE
/   LEVEL 1 DELETE
	 
	LODSYM
	 
	SEGMNT 4
	*1400
	3
	 
	CLR
	ADD COMAND
	ADA I
	JMP .+4
	STC .+2
	STC COMAND
	JMP 
/
	JMP GETFL
	JMP GETNM
	JMP STRIT
	JMP GETM
	JMP STORXM
	JMP DEL
/
GETFL,	JMP SRCH
	AZE
	JMP GOUSER
	JMP GETIT
	JMP EX1
	 
STRIT,	JMP SRCH
	AZE
	JMP .+3		/NOT PRESENT
	JMP REPLAX	/FILE PRESENT
	WIPE
	JMP DOSTR1
	 JMP FULL	/TAPE FULL
	JMP EX1
	 
GETNM,	ADD TPTR
	STC FILPTR
	ADD TCTR
	STC BETA1
NXTLUP,	XSK I BETA1
	SKP
	JMP GOUSER
	LDA I FILPTR
	SAE I
	3232
	SKP
	JMP NG
	SAE I
	5757
	JMP GOTNXT
NG,	SKPFIL
	JMP NXTLUP
/
GOTNXT,	STC FILNAM
	LDA I FILPTR
	STC FILNAM+1
	LDA I FILPTR
	STC FILNAM+2
	ADD FILPTR
	STC TPTR
	ADD BETA1
	STC TCTR
	JMP EX1
/
GETM,	JMP FINDIT
	AZE
	JMP BADCOM 	/FILE NOT PRESENT
	JMP GETIT
	LDA
	FILPTR
	STC TPTR
	ADD BETA1
	STC TCTR
	JMP GOUSER
/
/
GETIT,	SET 14
	0
	SKPFIL
	LDA I FILPTR
	STC FILNAM+2
	JMP BLDWRD
	JMP SETRDE
	ADD ASSFLG
	JMP SETU
	JMP XFER
	JMP 14
	 
	 
STORXM,	JMP FINDIT
	AZE
	JMP XX+1	/NOT PRESENT
	JMP REPLAC	/FILE PRESENT
/
XX,	WIPE
	JMP DOSTR1
	JMP FULL 	/FULL
	JMP GOUSER
/
DOSTR1,	SET 17
	0
	LDA I
	NULL-1
	JMP IDXSCN
	AZE
	JMP 17		/NO SLOT
	LDA		/SLOT AVAILABLE
	FILNAM
	STA I FILPTR
	LDA
	FILNAM+1
	STA I FILPTR
	LDA
	BETA1
	ADA I
	125
	MUL I
	5
	ADD ONE
	BSE I
	5000
	STA I FILPTR
	STC FILNAM+2
/
	JMP BLDWRD
	JMP SETWRI
	ADD ASSFLG
	JMP SETU
	JMP XFER
	XSK I 17
	JMP 17
	 
	 
DEL,	ADD FILNAM
	STC FSV
	ADD FILNAM+1
	STC FSV1
	JMP FINDIT
	STC FSV2
	ADD FSV
	STC FILNAM
	ADD FSV1
	STC FILNAM+1
	ADD FSV2
	AZE
	JMP BADCOM
	WIPE
	JMP GOUSER
	 
	 
FINDIT,	INPUT
	INBUF
	FIX
	0
	ISTOR2
	FILNAM+1
	LDH I CURPTR
	STH
	FILNAM
	LDH I CURPTR
	STH
	4\FILNAM
SRCH,	SET 17
	0
	LDA I
	FILNAM-1
	JMP IDXSCN
	JMP 17
/
IDXSCN,	SET BETA3
	0
	STC IDXLUP+1
	SETFIL
	SET I BETA1
	-125
IDXLUP,	SET I BETA2
	FILNAM-1	/OR NULL-1
	LDA I FILPTR
	SAE I BETA2
	JMP NOTIDX
	LDA I FILPTR
	SAE I BETA2
	JMP NOTIDX+1
	LDA I 	/GOT IT
	-2
	ADD FILPTR
	STC FILPTR
	STC FILNAM+2
	JMP BETA3
NOTIDX,	LDA I FILPTR
	LDA I FILPTR
	XSK I BETA1
	JMP IDXLUP
	ADD .-1
	JMP BETA3 	/NOT FOUND
	EJECT
SETRDE,	LDA I
	RDC
	STC RW
	LDA I
	IOB 12
	STC OI
	JMP 0
/
SETWRI,	LDA I
	WRC
	STC RW
	LDA I
	IOB I 12
	STC OI
	JMP 0
	EJECT
SETU,	SCR 1
	STC XT
	ADD ASSFLG
	BCL I
	7776
	ROL 3
	BSE I
RW,	RDC 	/OR WRC
	STC XU
	JMP 0
/
XFER,	SET BETA4
	0
	ADD TUMB1
	STC TU1
	ADD TUMB2
	STC TU2
	ADD CNT1 	/CNTR, WORD1
	AZE I
	JMP WRD2
	STC BETA3
TU1,	0 	/UMB, WORD1
	ADD TAPWRD 	/QN-BN, WORD1
	JMP RWBLK
	ADA I
	1001
	STC TAPWRD
	XSK I BETA3
	JMP TU1+1
WRD2,	SRO I
	5252
	JMP BETA4
	ADD CNT2 	/CNTR, WORD2
	STC BETA3
	ADD TAPWR2 	/QN-BN, WORD2
	STC TAPWRD
TU2,	0 	/UMB, WORD2
	JMP TU1+1
	EJECT
RWBLK,	STC RB
	ADD 0
	STC RBX
	ADD ASSFLG
	ADA I
	-7
	APO I
	JMP RDSK
	LDA I
XT,	0
	AXO
XU,	RDC 	/OR WRC
RB,	0
	SETAXO
	ADD RB
RBX,	JMP
/DISK
RDSK,	ADD M1
	APO
	CLR
	STC .+2
/SET DISK PARTITION
	IOB 13
	0
/OPERATE DISK
	ADD RB
	STC .+2
OI,	IOB 12 	/OR OPR I 12
	0
	IOB 13
	0
AA3,	JMP RBX-1
	 
/
/MOD3
/FEB 74