Directory of image this file is from
This file as a plain text file

*20
/NEXTCH ROUTINE: READS IN NEXT CHAR
/FROM SOURCE TAPE, ENTERING NEW TBLK
/AS NEEDED; SKIPS CONT MARK (47)
/SOURCE FILE BUFFERED IN 17000-17377
/B-REG. 17=HALF-WORD POINTER TO TEXT
/RETURNS WITH CHAR IN AC; CHAR CAN ALSO
/BE HAD AFTER RETURN VIA LDH 17
	PMODE
	*1000
	LMODE
NEXTCH,	LDF 7
	LDA
	0
	STC RTRN1	/SET RETURN JUMP
/CHECK FOR CTRL/A: INTERRUPT IF FOUND
	KST
	JMP .+7
	IOB
	6036		/KRB
	SAE I
	201
	SKP
	JMP SYSTEM	/SYSTEM MONITOR
/CHECK FOR END OF SOURCE BUFFER - IF
/FOUND, READ IN NEXT TAPE BLOCK
	LDA
	17
	SAE I
	7377
	JMP TBLK+1
	LDA I		/NEW TBLK NEEDED
	6000
	ADD TBLK
	STC .+2		/2ND LTAPE INSTR
	RDC		/RDC OR RDC U
	0
	SET I 17	/RESET POINTER
	6777
	LDA I
	1
	ADM I		/INCR TBLK
TBLK,	0
	LDH I 17	/NEXT CHAR
	AZE I		/0=FILE END
	JMP EOFILE
	SAE I
	47		/CON"T MARK?
	JMP RTRN1-1	/CHAR O.K.
	LDA I
	1
	ADM I
SGMNT,	0		/INCR SEGMENT
	SNS 5		/PRINT IF SW 5
	JMP NEXTCH+4
	PDP
	PMODE
	JMS I CRLF
	JMS I TAB
	LINC
	LMODE
	JMP NEXTCH+4	/IGNORE CON"T
	SNS 5		/PRINT CHAR?
RTRN1,	HLT		/RETURN JUMP
	PDP
	PMODE
	TAD M40
	SPA
	TAD C100
	TAD C240
	JMS I TIPE
	LINC
	LMODE
	LDH 17		/RESTORE CHAR
	JMP RTRN1
/INITIALIZATION REQUIRED:
/SET TBLK=STARTING TAPE BLOCK OF SOURCE
/SET 17=6001 AND READ IN FIRST TBLK
/SET RDC OR RDC U AT TBLK-7
/
/TEMPORARY CHECKOUT SECTION BELOW
SYSTEM,	HLT
EOFILE,	HLT
	PMODE
	*100
M40,	-40
C100,	100
C240,	240
TIPE,	TYPE
TYPE,	0
	TLS
	TSF
	JMP .-1
	CLA
	JMP I TYPE
CRLF,	CARRET
CARRET,	0
	CLA
	TAD C212
	JMS I TIPE
	TAD C215
	JMS I TIPE
	JMP I CARRET
C212,	212
C215,	215
TAB,	TABOUT
TABOUT,	0
	CLA
	TAD C311
	JMS I TIPE
	JMP I TABOUT
C311,	311
/TEMPORARY CALLING PROGRAM
	*400
START,	LAS
	LINC
	LMODE
	STC TBLK
	SET I 17
	7377
	JMP NEXTCH
	JMP .-1
	HLT