File AS2.PA (PAL assembler source file)

Directory of image this file is from
This file as a plain text file





/15.10.71
/AS2
/ANALYSIS SYNTHESIS SYSTEM1  USING TRNASFER OF COEFFICIENTS
/EXCIATION CODEC , NO ADAPT OF SAF DURING PITCH
/PULSES



*PART1

/INITIALISATION SEPARATED FROM MAIN PROGRAMM


        CLA
        TAD NMLOCS
        DCA TEM1
        TAD STORE
        DCA TEM2
NXT,    DCA I TEM2
        ISZ TEM2
        ISZ TEM1
        JMP NXT
        TAD ZABASE
        DCA ZA0
        TAD ZBBASE
        DCA ZB0
        TAD ZCBASE
        DCA ZC0

        JMP I CONT



ZERO,   0
A0APTR, 2440
A0BPTR, 2500
A0CPTR, 2540
ZABASE, 2360
ZBBASE, 2400
ZCBASE, 2420
ZA0,    0
ZB0,    0
ZC0,    0
OFLOWA, 0
OFLOWB, 0
OFLOWC, 0
NA,     12
NB,     12
D,      0
        0
STORE,  X
NMLOCS, -220-NUM
TEM1,   0
TEM2,   0
CONT,   PART2+2



DO4000, 0
        TAD N4000
        SNA
        IAC
        TAD N4000
        JMP I DO4000

N4000,  4000




/---------------------




*PART2


IAS1,   0
        JMP I LINIT
        JMS I LITF
LTF,    0

        JMS I LIEXCG
EXCLOC, 0


        JMS I IAS1


AS1,    0
        JMS I L4000
        DCA X

        TAD UA       /YA:=X-UA
        JMS I L4000
        CIA
        DCA 44
        LADD1
        X
        NOP
        TAD 44
        DCA YA

        TAD UB      /YB:=X-UB
        JMS I L4000
        CIA
        DCA 44
        LADD1
        X
        NOP
        TAD 44
        DCA YB


        TAD YA
        JMS I EXCLOC
        DCA EXC

ESAFA,  JMS I ESAFI
        X
        YA
        UA
        NA
        D
        ZABASE
        ZA0
        A0APTR
        OFLOWA


        JMS I LTF
        NB



/------------------------



ESAFB,  JMS I ESAFI
        X
        YB
        UB
        NB
        D
        ZBBASE
        ZB0
        A0BPTR
        OFLOWB

        TAD EXC        /Z:=YA+UC
        DCA 44
        LADD1
        UC
        NOP
        TAD 44
        DCA Z

AF,     JMS I ESAFI
        Z
        ZERO
        UC
        NB
        D
        ZCBASE
        ZC0
        A0CPTR
        OFLOWC

        TAD Z
        JMP I AS1



LIEXCG, PART5
LINIT,  PART1
L4000,  DO4000
ESAFI,  2141
LITF,   PART3



NUM=10    /NUMBER OF LOCS TO BE CLEARED

*PART2+200-20-NUM


X,      0
YA,     0
YB,     0
UA,     0
UB,     0
UC,     0
EXC,    0
Z,      0



PAUSE

Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with. I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation.

PDP-8 Home Page PDP-8 Site Map PDP-8 Site Search