10 T = 0
  20 P = 4. * ATN (1.)
  40 PRINT "ENTER MAGNITUDE OF FIRST VECTOR";
  50 INPUT M1
  60 PRINT "ENTER ANGLE (IN DEGREES) OF FIRST VECTOR";
  70 INPUT A1
  80 PRINT "ENTER MAGNITUDE OF SECOND VECTOR";
  90 INPUT M2
 100 PRINT "ENTER ANGLE (IN DEGREES) OF SECOND VECTOR";
 110 INPUT A2
 120 R1 = P * A1/180.
 130 R2 = P * A2/180.
 140 X1 = M1 * COS (R1)
 150 Y1 = M1 * SIN (R1)
 160 X2 = M2 * COS (R2)
 170 Y2 = M2 * SIN (R2)
 180 X = X1+X2
 190 Y = Y1 + Y2
 200 IF ABS(X) > .0001 THEN 205
 204 X = 0
 205 IF ABS (Y) > .0001 THEN 208
 206 Y = 0
 208 S = (X*X+Y*Y)^.5
 210 IF X = 0 THEN 221
 215 IF X > 0 THEN 315
 219 T = P
 220 GO TO 315
 221 IF Y = 0 THEN 317
 230 T = P/2
 240 IF Y >= 0 THEN 317
 250 T = (3*P)/2
 260 GO TO 317
 315 T = ATN (Y/X)+T
 317 A = T*180./P
 320 PRINT "ANGLE OF FIRST VECTOR IN RADIANS = ",R1
 330 PRINT "X-COMPONENT OF FIRST VECTOR = ",X1
 340 PRINT "Y-COMPONENT OF FIRST VECTOR = ",Y1
 350 PRINT "ANGLE OF SECOND VECTOR IN RADIANS = ",R2
 360 PRINT "X-COMPONENT OF SECOND VECTOR = ",X2
 370 PRINT "Y-COMPONENT OF SECOND VECTOR = ",Y2
 380 PRINT "X-COMPONENT OF RESULTANT VECTOR = ",X
 390 PRINT "Y-COMPONENT OF RESULTANT VECTOR = ",Y
 410 PRINT "ANGLE OF RESULTANT VECTOR IN DEGREES = ",A
 420 PRINT "ANGLE OF RELSULTANT VECTOR IN RADIANS = ",T
 430 PRINT "ENTER 1 IF YOU WISH TO CONTINUE, ENTER 2 TO STOP";
 440 INPUT Z
 450 ON Z GO TO 10,999
 999 STOP