File BITO.SB (8k SABR macro assembler source file)

Directory of image this file is from
This file as a plain text file

/ 2.A	BITVERARBEITUNG FUER OS/8-FORTRAN II
/
/	SUBROUTINE SETB		BIT SETZEN
/
/	CALL SETB ( ARG1 , ARG2 )
/
/	SUBROUTINE CLRB		BIT LOESCHEN
/
/	CALL CLRB ( ARG1 , ARG2 )
/
/	FUNCTION IGET		BIT PRUEFEN
/
/	K=IGET ( ARG1 , ARG2 )
/
/	ARG1 = VARIABLE
/	ARG2 = BIT-NUMMER (1-12)
/
/	9. APRIL 1973
/	W. HOUBEN
/
/	LETZTE AENDERUNG 26. FEBRUAR 1974
/	W. HOUBEN
/
	ENTRY	SETB
	ENTRY	IGET
	ENTRY	CLRB

	DUMMY	ONE
	DUMMY	TWO

ONE,	BLOCK	2
TWO,	BLOCK	2

ERR1,	4211; 2406		/ BITF - ERROR

SETB,	BLOCK	2
	CLA
	JMS	PARA
	JMS	VERS
	TAD	BIMU
	CMA
	AND I 	ONE
	TAD	BIMU
	DCA I	ONE
	RETRN	SETB

IGET,	BLOCK	2
	CLA
	TAD	IGET
	DCA	SETB
	TAD	IGET#
	DCA	SETB#
	JMS	PARA
	JMS	VERS
	TAD	BIMU
	AND I	ONE
	SNA CLA
	SKP
	IAC
	RETRN	SETB

CLRB,	BLOCK	2
	CLA
	TAD	CLRB
	DCA	SETB
	TAD	CLRB#
	DCA	SETB#
	JMS	PARA
	JMS	VERS
	TAD	BIMU
	CMA
	AND I	ONE
	DCA I	ONE
	RETRN	SETB

IPNT,	ONE
PNTR,	0
CNTR,	0

PARA,	0
	TAD	IPNT
	DCA	PNTR
	TAD	(-4
	DCA	CNTR
A1,	TAD I	SETB
	INC	SETB#
	DCA I	PNTR
	INC	PNTR
	ISZ	CNTR
	JMP	A1
	JMP I	PARA

VERS,	0
	CLA
	TAD I	TWO
	SNA
	JMP	ERR
	SPA
	JMP	ERR
	TAD	(-15
	SMA CLA
	JMP	ERR
	TAD I	TWO
	CIA
	DCA	BIMU
	CLL CML
A2,	RAR
	ISZ	BIMU
	JMP	A2
	DCA	BIMU
	JMP I	VERS

BIMU,	0

ERR,	CLA CLL
	CALL	1,ERROR
	ARG	ERR1
	RETRN	SETB

	END



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search