File BLKJAK.BA (BASIC source file)

Directory of image this file is from
This file as a plain text file

4 REMARKABLY TRANSLATED TO OS8 BASIC BY KAY R. FISHER ...DEC
5 PRINT "WELCOME TO DIGITAL EDUSYSTEM COMPUTER BLACKJACK!!"
6 PRINT\PRINT "YOUR DEALER TONIGHT IS PETEY P. EIGHT."
7 PRINT "WATCH HIM CLOSELY.... HE HAS A REPUTATION FOR"
8PRINT "DEALING OFF THE BOTTOM OF THE DECK."\PRINT
9 RANDOMIZE
10 DIM A(13)
20 PRINT "QUESTIONS REQUIRING A YES OR NO ANSWER"
25 PRINT "SHOULD BE ANSWERED WITH A 'Y' FOR YES, 'N' FOR NO."\PRINT
30 PRINT "DON'T START PLAYING WITH LESS THAN $100.. HAVE FUN!"\PRINT
40 PRINT "HOW MANY DOLLARS ARE YOU STARTING WITH";
41 INPUT F
42 PRINT
43 F1=F
50 PRINT "WHAT IS YOUR WAGER THIS TIME";
51 INPUT W
52 PRINT
53 IF W>F GOTO 56
54 IF W<10 GOTO 58
55 GOTO 100
56 PRINT "YOUR BET EXCEEDS YOUR REMAINING DOLLARS."
57 GOTO 50
58 PRINT "MINIMUM WAGER IS $10."
59 GOTO 50
100 GOSUB 780
102 P1=I
104 PRINT "YOUR FIRST CARD IS ";CHR$(L)
106 GOSUB 780
110 P2=I
112 PRINT "YOUR SECOND CARD IS ";CHR$(L)
115 GOTO 200
117 PRINT "YOU HAVE ";P3;" SHOWING."
119 GOSUB 760
120 P3=P3+I
122 PRINT "YOU GOT A ";CHR$(L)
123 IF P3>21 GOTO 820
124 GOTO 117
200 GOSUB 780
201 P3=P1+P2
202 D1=I
204 GOSUB 780
206 D2=I
208 PRINT "DEALER SHOWS A ";;CHR$(L)
210 GOTO 117
212 D3=D1+D2
214 PRINT "DEALER HAS ";D3
216 IF D3>16 GOTO 222
217 GOSUB 780
218 PRINT "DEALER GETS A ";;CHR$(L)
219 D3=D3+I
220 GOTO 214
222 IF D3<22 GOTO 800
224 PRINT "DEALER BUSTED."
226 GOTO 802
760 PRINT "DO YOU WANT A HIT?";
762 INPUT K$
764 PRINT
766 IF K$="N" GOTO 212
768 GOSUB 780
770 RETURN
780 I=INT(13*RND(0)+1)
782 A(I)=A(I)+1
784 IF A(I)>4 GOTO 780
786 GOSUB 900
788 RETURN
800 IF D3>=P3 GOTO 820
802 F=F+W
806 PRINT "YOU WIN. YOU NOW HAVE $";F
808 GOTO 980
820 F=F-W
822 PRINT "YOU LOSE. YOU NOW HAVE $";F
824 GOTO 980
900 IF I<>1 GOTO 910
904 I=11
906 L=1
908 GOTO 942
910 IF I<>13 GOTO 920
912 I=10
914 L=11
916 GOTO 942
920 IF I<>12 GOTO 930
922 I=10
924 L=17
926 GOTO 942
930 IF I<>11 GOTO 937
932 I=10
934 L=10
936 GOTO 942
937 IF I<>10 GOTO 940
938 L=20
939 GOTO 942
940 L=I+48
942 RETURN
980 PRINT "DO YOU WISH TO PLAY AGAIN?";
982 INPUT K$
984 PRINT\PRINT
986 IF K$="Y" GOTO 50
987 PRINT\PRINT\PRINT \IF F>F1 THEN 995
988 PRINT "TOO BAD! YOU LOST";F1-F;"DOLLARS AT THE EDUSYSTEM CASINO."
990 GOTO 998
995 PRINT "NOT BAD! YOU WON";F-F1;"DOLLARS AT THE EDUSYSTEM CASINO."
998 PRINT\PRINT "HOPE YOU ENJOYED YOURSELF.  THANKS FOR PLAYING."
999 END



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search