File BULEYE.BA (BASIC source file)

Directory of image this file is from
This file as a plain text file

10 REM*** BULLSEYE BY DAVE AHL
11 REMARKABLY TRANSLATED TO OS8 BASIC BY KAY R. FISHER ...DEC
20 PRINT "GAME OF BULLSEYE"\PRINT\RANDOMIZE
30 PRINT "IN THIS GAME, UP TO 20 PLAYERS THROW DARTS AT A TARGET"
40 PRINT "WITH 10, 20, 30, AND 40 POINT ZONES.  THE OBJECTIVE IS"
50 PRINT "TO GET 200 POINTS."\PRINT
60 PRINT "THROW","DESCRIPTION",,"PROBABLE SCORE"
70 PRINT "  1","FAST OVERARM",,"BULLSEYE OR COMPLETE MISS"
80 PRINT "  2","CONTROLLED OVERARM","10, 20, OR 30 POINTS"
90 PRINT "  3","UNDERARM",,"ANYTHING"\PRINT
100 DIM A$(20,20),S(20),W(10)\R=0\M=0
101 FOR I = 1 TO 20\S(I)=0
102 NEXT I
110 PRINT "HOW MANY PLAYERS";\INPUT N\PRINT
120 FOR I=1 TO N
130 PRINT "NAME OF PLAYER";I;\INPUT A$(I)
140 NEXT I
150 R=R+1\PRINT\PRINT "ROUND";R
160 FOR I=1 TO N
170 PRINT\PRINT A$(I);"'S THROW";\INPUT T
180IFT=1GOTO200\IFT=2GOTO210\IFT=3GOTO220\PRINT"INPUT 1, 2, OR 3"\GOTO170
200 P1=.65\P2=.55\P3=.5\P4=.5\GOTO 230
210 P1=.99\P2=.77\P3=.43\P4=.01\GOTO 230
220 P1=.95\P2=.75\P3=.45\P4=.05
230 U=RND(0)
240 IF U<P1 GOTO 250\PRINT "BULLSEYE!!  40 POINTS!"\B=40\GOTO290
250 IF U<P2 GOTO 260\PRINT "30-POINT ZONE!"\B=30\GOTO 290
260 IF U<P3 GOTO 270\PRINT "20-POINT ZONE"\B=20\GOTO 290
270 IF U<P4 GOTO 280\PRINT "WHEW!  10 POINTS."\B=10\GOTO 290
280 PRINT "MISSED THE TARGET.  TOO BAD!"\B=0
290 S(I)=S(I)+B\PRINT "TOTAL SCORE =";S(I)
295 NEXT I
300 FOR I=1 TO N
310 IFS(I)<200 GOTO 320\M=M+1\W(M)=I
320 NEXT I
330 IF M=0 THEN 150
340 PRINT\PRINT "WE HAVE A WINNER!!"\PRINT
345 FOR I=1 TO M
350 PRINT A$(W(M));" SCORED";S(W(M));"POINTS."
355 NEXT I
360 PRINT\PRINT "THANKS FOR THE GAME!"
370 END



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search