File CCL.SB (8k SABR macro assembler source file)

Directory of image this file is from
This file as a plain text file

/CCL.SB
/
/	CALL CCL(COMMAND)
/
/	CALL CCL WITH A COMMAND
/
/	'COMMAND' MUST BE A PACKED 6-BIT TEXT STRING,
/	TERMINATED BY A ZERO BYTE.
/	IT IS UNPACKED AND PUT INTO 17600-17643 BEFORE
/	CHAINING TO CCL (CCLX.SV).
/	MAXIMUM COMMAND LENGTH IS 34 CHARACTERS.
/

	ENTRY	CCL

ABSYM	TEM7	7
ABSYM	CDF1	6211

	DUMMY	ARGUMT
	DUMMY	CCLCMD

CCL,	BLOCK	2
	TAD I	CCL
	DCA	ARGUMT
	INC	CCL#
	TAD I	CCL
	DCA	ARGUMT#
	INC	CCL#
	TAD	(7600
	DCA	CCLCMD#
	TAD	(-21
	DCA	CCLCNT
CCL10,	TAD I	ARGUMT	/MOVE COMMAND TEXT IN
	RTR;RTR;RTR
	JMS	CCLCH
	TAD I	ARGUMT
	JMS	CCLCH
	INC	ARGUMT#
	ISZ	CCLCNT
	JMP	CCL10

CCL20,	DCA I	CCLCMD
	CALL	1,CHAIN
	ARG	CCLFIL
	HLT

///	CCLCH - CONVERT AND STORE COMMAND CHAR
/
CCLCH,	0
	AND	(77
	SNA
	JMP	CCL20
	TAD	(40
	AND	(77
	TAD	(240
	DCA I	CCLCMD
	INC	CCLCMD#
	JMP I	CCLCH

CCLCNT,	0
CCLFIL,	TEXT	"CCLX@@"
CCLCMD,	CDF1
	7600
ARGUMT,	BLOCK	2

	END



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search