File CHAIN.SB (8k SABR macro assembler source file)

Directory of image this file is from
This file as a plain text file

/CHAIN.SB
/
/	05-MAY-82 JVE	CREATED BY EXTRACTION FROM UNITIO.SB
/			SO CHAINING ONLY NEEDS 1 PAGE OF CODE
/			INSTEAD OF THE 4 THAT WERE IN UNITIO.
/
/
/	CALL CHAIN (FNAME)
/
/		CHAIN TO 'SYS:FNAME.SV'.
/
////

ABSYM	CDF0	6201
ABSYM	CIF0	6202
ABSYM	ACPOS1	7301
ABSYM	ACPOS2	7305
ABSYM	ACPOS3	7325
ABSYM	ACPOS4	7307
ABSYM	ACNEG1	7340
ABSYM	ACNEG2	7344
ABSYM	ACNEG3	7346
ABSYM	AC2000	7332
ABSYM	AC4000	7330
ABSYM	AC6000	7333

OPDEF	ANDI	0400
OPDEF	TADI	1400
OPDEF	INCI	2400
OPDEF	DCAI	3400
OPDEF	JMSI	4400
OPDEF	JMPI	5400

/////		FIELD 0 LOCATIONS

ABSYM	TEMP	7

ABSYM	X6	16
ABSYM	X7	17

ABSYM	CDFUS	34

ABSYM	UNITNO	115	/FOLLOWING LOCATIONS DEFINED BY LOADER
ABSYM	UBASE	116

ABSYM	XUSR	74
ABSYM	XREADU	75
ABSYM	XWRITU	76
ABSYM	UTABLE	77

	ENTRY	CHAIN

	LAP

DEVSYS,	TEXT	"SYS"
EXTSV,	TEXT	"SV"

SOFTER,
HARDER,
CHAINE,	CALL	1,ERROR
	ARG	CHAINM
CHAINM,	TEXT	"CHER"

CHAIN,	0		/===> CALL CHAIN(FNAME)
CHAINA,	0
	TAD	CHAIN
	DCA	CHA10
CHA10,	TAD I	CHAINA	/*CDF*
	DCA	ZFILA1
	INC	CHAINA
	STA
	TAD I	CHAINA
	DCA	X6
	INC	CHAINA

	DCA	UNITNO	/UNIT # = 0
	CDF0
	TAD I	UTABLE
	DCA	UBASE	/UNIT #0 UPP BASE
	TAD	(11	/OFFSET TO DEVNAME - 1
	TAD	UBASE
	DCA	X7

	TAD	DEVSYS	/MOVE IN DEVICE NAME
	DCA I	X7
	TAD	DEVSYS#
	DCA I	X7
	JMS	ZFILAS	/MOVE IN ZERO FILLED FILE NAME
	JMS	ZFILAS
	JMS	ZFILAS
	TAD	EXTSV	/MOVE IN "SV" EXTENSION
	DCA I	X7

	TAD	(0002	/USR FILE LOOKUP CODE
	DCA I	UBASE	/  GOES IN FLAG WORD
	CIF0
FOOL2,	JMS I	XUSR	/CALL USR TO LOOK UP FILE
	JMP	SOFTER	/SOFTWARE ERROR
	JMP	HARDER	/HARDWARE ERROR

	CDF0
	TAD	(0006	/USR CHAIN TO SYS FILE CODE
	DCA I	UBASE
	CALL	0,CKIO	/MAKE SURE DEVICE I/O IS FINISHED
FOOL3,	CIF0
	JMS I	XUSR	/CALL USR TO CHAIN TO SYS FILE
	HLT		/SHOULD NOT RETURN
	HLT
	HLT

///	ZFILAS - ZERO FILL AND STORE
/
ZFILAS,	0
ZFILA1,	TAD I	X6	/*CDF*
	DCA	TEMP
	TAD	TEMP
	AND	(3737
	TAD	(3737
	AND	(4040
	TAD	(3737
	AND	TEMP
	CDF0
	DCA I	X7
	JMP I	ZFILAS

	END



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search