/CREDIT - CRT EDIT OVERLAY/

/ CODE TO STEAL EDITOR CORE : 05600-07577 /

OURECS=2
INBUF=3600
INCTL=0400
INRECS=2
INDEVH=2600
OUBUF=4600
OUCTL=4400
OUDEVH=3200

 FIELD 0
DIFDIF=3600
MORECS=2160
K5000=6765-DIFDIF
C1=7157-DIFDIF
C2=7160-DIFDIF
OUCT=7166-DIFDIF
OUCTLW=7265-DIFDIF
O7=7374-DIFDIF
I2=7566-DIFDIF
I3=7567-DIFDIF

*MORECS
 -OURECS+1
*K5000
 OUCTL
*C1
 OUCTL&3700
*C2
 OUBUF
*OUCT
 OUCTL
*OUCTLW+1
 OUBUF
*O7
 OUCTL&3700
*I2
 INRECS
*I3
 INCTL+1

/ * * * END OF CORE STEALING CODE * * * /


 FIELD 0
I33=1213
OUTL=1225
MONIT=1717
BUFRD=2026
BUFWT=2076
CIDF=2620
START1=6602
ICHAR=7412
ERRD=2041
OCHAR=7015
ERWT=2105

*I33+1
 KSF 100
*I33+3
 KRS 100
*I33+7
 KRB 100

LIST1=1370
*LIST1+13
 233  /ESCAPE INSTEAD OF ALTMODE/

*OUTL
 0
 JMS I .+2
 SKP
 ZOUTL
 JMP I OUTL
 NOP

*MONIT+1
 JMS I .+1
 ZMONIT

*BUFRD+1
 JMS I .+2
 SKP
 ZBUFRD

*BUFWT+1
 JMS I .+2
 SKP
 ZBUFWT

*CIDF-1
 JMP ZINIT
*CIDF+3
ZINIT, DCA 177
 CDF 10
 TAD I Z7760
 CDF 0
 AND Z0770
 TAD ZM0210
 SZA CLA
 JMP ZNOGO
 CIF 10
 JMS I Z7700
 10
 CLA IAC
 CIF 10
 JMS I Z0200
 2
 ZNAME
 0
 JMP ZNOGO
 CDF 10
 TAD I Z1404
 SNA
 JMP ZNOGO
 TAD I Z0017
 DCA ZINIT
 TAD I ZINIT
 TAD ZM4642
 SZA CLA
 JMP ZNOGO
 CIF CDF 10
 JMP I ZSTAR1
ZNOGO, CDF 10
 DCA 20
 DCA I 20
 ISZ 20
 JMP .-2
 CDF 0
 TAD Z0077
 DCA 10
 TAD ZZZERO
 DCA 11
ZMOVE, TAD I 11
 DCA I 10
 ISZ ZKNT
 JMP ZMOVE
 JMP 100
ZZERO, ISZ 103
 DCA I 103
 JMP 100
 103
ZNAME, FILENAME ABSLDR.SV
Z7760, 7760
Z0770, 0770
ZM0210, -0210
Z7700, 7700
Z0200, 0200
Z1404, 1404
Z0017, 0017
ZM4642, -4642
ZSTAR1, START1
Z0077, 0077
ZZZERO, ZZERO-1
ZKNT, -4

*5600
CRTFLG, 0

ZSTOP, 0
 CLA CLL
 TAD CRTFLG
 SZA CLA
 6152    /STOP SCOPE/
 DCA CRTFLG
 JMP I ZSTOP

ZMONIT, 0
 ISZ ZMONIT
 JMS ZSTOP
 KCC 100
 JMP I ZMONIT

ZBUFRD, 0
 JMS ZSTOP
 CIF 10
 JMS I (ICHAR)
 JMP I (ERRD)
 JMP I ZBUFRD

ZBUFWT, 0
 DCA ZCHAR
 JMS ZSTOP
 TAD ZCHAR
 CIF 10
 JMS I (OCHAR)
 JMP I (ERWT)
 JMP I ZBUFWT

ZOUTL, 0
 DCA ZCHAR
 JMS ZSTART
 TAD ZCHAR
 TAD (-212) /LF/
 SNA
 JMP ZLF
 TAD (212-207) /BELL/
 SNA
 6157
 TAD (207-233)
 SPA SNA CLA
 JMP I ZOUTL /NO ECHO CONTROL CHARS/
 JMP ZNOTLF
ZLF, ISZ ZLINNO
 CLA CLL CMA  /-1/
 DCA ZCOLNO
 TAD ZLINNO
 TAD (-24)
 SMA SZA CLA
 JMS ZROLUP /ROLL-UP AT END OF PAGE/
ZNOTLF, ISZ ZCOLNO
 TAD ZCOLNO
 TAD (-100)
 SMA CLA
 JMP ZFLASH
 SKP
ZROOM, JMS ZROLUP /ROLL-UP AT END OF BUFFER/
 TAD ZBUFPT
 TAD (-ZBUFFE)
 SMA CLA
 JMP ZROOM
 TAD ZBUFPT
 DCA ZTMP
 ISZ ZBUFPT
 TAD (ZEOS)
 DCA I ZBUFPT
 TAD ZCHAR
 AND (177)
 DCA I ZTMP
 JMP I ZOUTL
ZFLASH, CLA CLL CMA  /-1/
 TAD ZBUFPT
 DCA ZTMP
 TAD I ZTMP
 AND (7177)
 TAD (0600) /CURSOR-STYLE/
 DCA I ZTMP
 JMP I ZOUTL

ZROLUP, 0
 TAD (ZBUFF-1)
 DCA ZTMP
ZROL1, ISZ ZTMP
 TAD I ZTMP
 AND (177)
 TAD (-012) /LF/
 SZA CLA
 JMP ZROL1
 TAD (ZBUFF-1)
 DCA ZTMP2
 JMP ZROL2A
ZROL2, ISZ ZTMP
 ISZ ZTMP2
 TAD I ZTMP
 DCA I ZTMP2
ZROL2A, TAD ZBUFPT
 CIA
 TAD ZTMP
 SPA CLA
 JMP ZROL2
 TAD ZTMP2
 DCA ZBUFPT
 CLA CLL CMA  /-1/
 TAD ZLINNO
 DCA ZLINNO
 JMP I ZROLUP

ZEOS=3212  /END OF SCREEN CHAR/
ZCHAR, 0
ZLINNO, 1
ZCOLNO, 0
ZBUFPT, ZBUFF
ZTMP, 0
ZTMP2, 0

 PAGE
ZSTART, 0
 CLA CLL
 TAD CRTFLG
 SZA CLA
 JMP I ZSTART
 6156
 JMP .-1
 TAD (ZBUFF)
 6150
 NOP
 NOP
 6151
 ISZ CRTFLG
 JMP I ZSTART

 PAGE
ZBUFF=.
 ZEOS
ZBUFFE=7570

$