10 REM ERSTELLUNG EINER LISTE ALLER KURSE ZUR  VERWENDUNG ZU-
20 REM SAMMEN MIT DEN ABITURPROGRAMMEN ZA2***.BA
30 PRINT"ABITURJAHRGANG FUER DEN DIE KURSLISTE ERSTELLT WERDEN"
40 PRINT"SOLL(NUR DIE BEIDEN LETZTEN STELLEN)";
50 INPUT X$
60 X$ = "KURS"&X$&".BA"
70 FILEV#1:X$
80 PRINT"WIEVIELE LEISTUNGSKURSE SIND VORHANDEN";\INPUT L
90PRINT "WIEVIELE GRUNDKURSE SIND VORHANDEN";\INPUT K
100 K = K + L
110 DIM K$(50)
120 PRINT "WELCHE LEISTUNGSKURSE SIND VORHANDEN?"
130  FOR I = 1 TO L
140 PRINT I;". ";\INPUT K$(I)
150 NEXT I
160  PRINT
170 PRINT"WELCHE GRUNDKURSE SIND VORHANDEN?"
180 FOR I = L+1 TO K
190 PRINT I;". ";\INPUT K$(I)
200 NEXT I
210 PRINT"SIND NOCH FEHLER UNTERLAUFEN (J ODER N)";\INPUT A$
220 IF A$="N" THEN 310
230 IF A$="J" THEN 240 \PRINT"JA, WAS DENN NUN???"\ GOTO 210
240 PRINT "FALSCHE BEZEICHNUNG";\INPUT F$
250 PRINT "RICHTIGE BEZEICHNUNG";\INPUT R$
260 FOR I = 1 TO K
270 IF F$<>K$(I)THEN 290
280 K$(I) = R$
290 NEXT I
300 GOTO 210
310 FOR I = 1 TO K
320 PRINT#1:K$(I)
330 NEXT I
340 PRINT#1:"ENDE"
350 CLOSE#1
360 PRINT"DIE LISTE DER KURSE IST UNTER DEM NAMEN ";X$;" ABGESPEI-"
370 PRINT"CHERT."
380 END