/DB8E HANDLER FOR BUILD
DBRF=6521
DBRD=6522
DBTF=6523
DBTD=6524
DBCD=6527
	*0
	-1
DEVICE DB8E;DEVICE PDP8;0;DB8E&177;0;0

	*200
DB8E,	"A&77		/ENTRY POINT AND VERSION NUMBER
DB7600,	7600
	RDF
	TAD DB8CIF
	DCA DB8XIT	/SAVE RETURN FIELD
	TAD I DB8E
	AND DB70
	TAD DBCDF
	DCA DB8CDF	/DATA FIELD OF BUFFER
	TAD I DB8E
	AND DB3700
	RAL
	CMA
	DCA DB8EWC
	CLA CLL CML RAR
	TAD I DB8E
	CLA
	ISZ DB8E
	TAD I DB8E
	DCA DB8ECA	/SAVE BUFFER ADDRESS
	ISZ DB8E
	ISZ DB8E
	JMP DB8KLG
DB8ELP,	SNL CLA
	JMP DB8GLP	/ZER LINK MEANS READ
	JMS TTYTST	/TEST FOR ^C
	TAD I DB8ECA	/CHARACTER 1 IS LOW ORDER 8 BITS OF WORD 1
	JMS DBPRNT
DBLOOP,	ISZ DB8ECA
DB70,	70
DB8KLG,	ISZ DB8EWC
	JMP DB8ELP
	ISZ DB8E	/SKIP PAST ERROR RETURN
DB8XIT,	HLT	/RESTORE CALLING FIELDS
	JMP I DB8E
TTYTST,	0
DB8CDF,	0
	TAD DB8200
	KRS		/TEST FOR ^C WITH FLAG UP
	TAD DBM203
	KSF
	CLA IAC
	SZA CLA		/YES..BACK TO MONITOR
	JMP I TTYTST
DB8CIF,	CDF CIF 0
	JMP I DB7600
DBPRNT,	0
	DBCD
	DBTD
	JMS TTYTST
	CLA CLL CML
	DBTF
	JMP .-3
	JMP I DBPRNT
DB8ECA,	0
DB8EWC,	0
DBCDF,	CDF 0

/FOLLOWING CODE READS DB8E AND PACKS IN BUFFER.
DB8GLP,	JMS DB8GCH
	DCA I DB8ECA
	CLL CLA
	JMP DBLOOP
DB8GCH,	0
	JMS TTYTST
	DBRF
	JMP .-2
	DBRD
	JMP I DB8GCH
DB8200,	200
DBM203,	-203		/FOR CONTROL/C
DB3700,	3700
$