File DEFDAT.PA (PAL assembler source file)

Directory of image this file is from
This file as a plain text file

/50
/
/
/%R	COLLECT INSPECTOR DEFECT AND SPLICE DATA
/
/%TW	COME HERE FROM "MEMORY" FOR EACH MOTION
/	PULSE AND MOVE THE INSPECTOR DEFECT DATA TO CHANNEL
/	STORAGE.
/
/%TD	WHEN THE LASER SHUTTERS ARE CLOSED, AND THE EXERCISER
/	IS OFF, DEFECT DATA IS SET IN MEMORY FOR ALL THREE
/	INSPECTION CHANNELS.  IF THE INSPECTOR IS ACTIVE, OR
/	THE EXERCISER IS ON, THE DEFECT LINES ARE MONITORED
/	AND DEFECT DATA IS SAVED FOR LATER ENTRY INTO THE
/	DEFECT MEMORY TABLE (SEE DEFCH1,2,3).  THE SPLICE
/	SIGNAL FROM CHANNEL 2 IS ALSO MONITORED AND THAT
/	DATA IS SAVED FOR "DEFCH2".
/
/
DEFDAT,	0
	DBRI50		/READ THE DEFECT AND SPLICE BITS
	AND (0017)
	DBCI50		/CLEAR THE DEFECT BITS FROM THE INPUT
	MQL
	TAD SHUTDY	/IS THE SHUTTER OPENING DELAY ACTIVE ?
	SNA CLA
	JMP .+3		/NO, GO ON
	TAD (7)		/YES, FORCE ALL DEFECT BITS SET, BUT 
	MQL		/NOT THE SPLICE BIT
	ACL		/ARE ANY BITS SET ?
	SNA
	JMP I DEFDAT	/NO, RETURN
	AND P4		/YES, PROCESS CHANNEL 1 DATA
	SZA
	DCA DEFCT1
	ACL		/PROCESS CHANNEL 3 DATA 
	AND P1
	SZA
	DCA DEFCT3
	TAD DEFCT2	/"OR" THE NEW DATA WITH THE PREVIOUS
	MQA		/DATA FOR CHANNEL 2
	AND (0012)
	DCA DEFCT2
	JMP I DEFDAT	/RETURN



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search