Directory of image this file is from
This file as a plain text file

PAGE

/*********** DIGITAL SCOPE ******************************************
/13.10.75
/15.3.76  				D.COY  CS/FZNR
/CALL:	JMS DIGSCP
/	ADR. OF NUMBER TO BE PRINTED (0-7777)
/	FIELD OF NUMBER TO BE PRINTED (1-7)
/	MARK OF NUMBER TO BE PRINTED (-1;0;1-3777)
/
/MERKE:	MARK=0 BEDEUTET INTEGER;=-1 MIT VORZEICHEN
/	MARK=N BEDEUTET STRAHL UNTERDRUECKT MIT N-1 SPACES

DIGSCP,	0
	CLA
	TAD I DIGSCP
	DCA DIGPO1
	ISZ DIGSCP
	TAD I DIGSCP
	DCA DIGTEM
	TAD DIGTEM
	CLL RAL
	RTL
	DCA DIGFLD
	ISZ DIGSCP
	TAD I DIGSCP
	DCA DIGMRK
	ISZ DIGSCP

	TAD DIGMRK
	SPA SNA
	JMP DIGLK0
	CIA
	IAC
	SMA
	JMP I DIGSCP

	DCA DIGCNT
	TDC
	240
	ISZ DIGCNT
	JMP .-3
	JMP I DIGSCP

DIGLK0,	TAD DIGFLD
	TAD (CDF 0
	DCA DIGDF
	RIF
	TAD (CDF 0
	DCA DIGRF
	SWAB

DIGDF,	HLT
	TAD I DIGPO1
DIGRF,	HLT
	DCA DIGSIG

	TAD DIGSIG

DIGLC0,	SPA CLA
	CLL IAC RAL
	TAD (253
	DCA DIGSGN
	TAD DIGSIG
	SPA
	CIA
	DCA DIGSIG
	CLA CLL IAC RTL
	CIA
	DCA DMIN4


	TAD DIGSIG
	SNA
	JMP DIGLC1

	MQL
DIGLP1,	SHL
	3
	SZA
	JMP DIGLC4

	TDC
	240
	CLA
	ISZ DMIN4
	JMP DIGLP1

	JMP DIGLC3

DIGLC1,	TDC
	4240
	4240
	240
	ISZ DIGMRK
	JMP DIGLC2

	TAD DIGSGN
	TCHAR
	TDC
	260
	CLA
	JMP DIGLC3


DIGLC2,	TDC
	4240
	".

DIGLC3,	CLA
	INBLIP
	BLOTNT
	DIGLC7

	TDC
	240
	JMP I DIGSCP

DIGLC4,	DCA DIGTEM
	ISZ DIGMRK
	JMP DIGLC8
	TAD DIGSGN
	TCHAR
	CLA
	TAD DIGTEM
	JMP DIGLC6

DIGLP2,	SHL
	3

DIGLC6,	TAD (260
	TCHAR
	CLA
	ISZ DMIN4
	JMP DIGLP2

	JMP DIGLC3

DIGLC7,	TDC
	"*
	JMP I DIGSCP

DIGLC8,	TDC
	240
	CLA
	TAD DIGTEM
	JMP DIGLC6


DMIN4,	0
DIGPO1,	0
DIGTEM,	0
DIGFLD,	0
DIGMRK,	0
DIGCNT,	0
DIGSGN,	0
DIGSIG,	0
LSTDIG,	".