Directory of image this file is from
This file as a plain text file

C
C     ..................................................................
C
C        SUBROUTINE DQHFG
C
C        PURPOSE
C           TO COMPUTE THE VECTOR OF INTEGRAL VALUES FOR A GIVEN
C           GENERAL TABLE OF ARGUMENT, FUNCTION, AND DERIVATIVE VALUES.
C
C        USAGE
C           CALL DQHFG (X,Y,DERY,Z,NDIM)
C
C        DESCRIPTION OF PARAMETERS
C           X      - DOUBLE PRECISION INPUT VECTOR OF ARGUMENT VALUES.
C           Y      - DOUBLE PRECISION INPUT VECTOR OF FUNCTION VALUES.
C           DERY   - DOUBLE PRECISION INPUT VECTOR OF DERIVATIVE VALUES.
C           Z      - RESULTING DOUBLE PRECISION VECTOR OF INTEGRAL
C                    VALUES. Z MAY BE IDENTICAL WITH X, Y OR DERY.
C           NDIM   - THE DIMENSION OF VECTORS X,Y,DERY,Z.
C
C        REMARKS
C           NO ACTION IN CASE NDIM LESS THAN 1.
C
C        SUBROUTINES AND FUNCTION SUBPROGRAMS REQUIRED
C           NONE
C
C        METHOD
C           BEGINNING WITH Z(1)=0, EVALUATION OF VECTOR Z IS DONE BY
C           MEANS OF HERMITEAN FOURTH ORDER INTEGRATION FORMULA.
C           FOR REFERENCE, SEE
C           (1) F.B.HILDEBRAND, INTRODUCTION TO NUMERICAL ANALYSIS,
C               MCGRAW-HILL, NEW YORK/TORONTO/LONDON, 1956, PP.314-319.
C           (2) R.ZURMUEHL, PRAKTISCHE MATHEMATIK FUER INGENIEURE UND
C               PHYSIKER, SPRINGER, BERLIN/GOETTINGEN/HEIDELBERG, 1963,
C               PP.227-230.
C
C     ..................................................................
C
      SUBROUTINE DQHFG(X,Y,DERY,Z,NDIM)
C
C
      DIMENSION X(1),Y(1),DERY(1),Z(1)
      DOUBLE PRECISION X,Y,DERY,Z,SUM1,SUM2
C
      SUM2=0.D0
      IF(NDIM-1)4,3,1
C
C     INTEGRATION LOOP
    1 DO 2 I=2,NDIM
      SUM1=SUM2
      SUM2=.5D0*(X(I)-X(I-1))
      SUM2=SUM1+SUM2*((Y(I)+Y(I-1))+.33333333333333333D0*SUM2*
     1(DERY(I-1)-DERY(I)))
    2 Z(I-1)=SUM1
    3 Z(NDIM)=SUM2
    4 RETURN
      END