Directory of image this file is from
This file as a plain text file

	DCLA=6751
	DLDR=6733
	DLDC=6732
	DRDS=6741
	DRWC=6752
	DCLS=6742
	DSKC=6745
	DLWC=6753
	DSKE=6747
	DLCA=6755




*4000
NOPUNCH
*7607
ENPUNCH



SHNDLR,	0
	CLA CLL CMA RTL
	DCA SYSCNT	/NO. ERROR TRIES
	TAD I SHNDLR
	DCA SFUN	/FUNCTION WORD
	ISZ SHNDLR
	CLA CMA
	TAD I SHNDLR
	DCA SLOC	/BUFFER ADDRESS-1
	ISZ SHNDLR
STRY,	TAD I SHNDLR
	DCA SREC
	TAD SFUN
	RAL
	AND S7600
	DCA SBLKCT	/WORD COUNT
	RTL
	TAD SDLDR
	DCA SINST	/SINST=6733 (READ) OR 6735 WRITE
SLOOP,	TAD SLOC
	DLCA		/LOAD CURRENT ADDRESS
	TAD SBLKCT
	TAD S7600	/FULL OR HALF RECORD READ?
	SZA CLA
	TAD S7600	/FULL..2 PAGES
	TAD S7600	/HALF..1 PAGE
	DLWC		/WORD COUNT
	DCLS		/CLEAR ALL FLAGS
	TAD SFUN
	AND S70
	DLDC		/LOAD DATA FIELD OF BUFFER
	TAD SREC
SINST,	0		/READ OR WRITE IOT
	DSKC
	JMP .-1
SNEXT,	DSKE		/DONE..IS ERROR FLAG UP?
	JMP NOERR

SERROR,	ISZ SYSCNT
	JMP SLOOP	/TRY AGAIN
	CLA CLL CML RAR	/DON'T BOTHER..YOU LOSE
	JMP SRTRN+1

NOERR,	ISZ SREC	/NO..BUMP RECORD NO.
S70,	70
	DRCA
	DCA SLOC
	TAD S7600
	CLL RAL
	TAD SBLKCT
	SZL SNA		/WORD COUNT EXHAUSTED?
	JMP .+3		/YES
	DCA SBLKCT
	JMP SLOOP
S7600,	7600
SRTRN,	ISZ SHNDLR
	ISZ SHNDLR
	JMS FELDSR
	JMP I SHNDLR





KRBSR,	0
	CLA RAL
	DCA LINK
	RDF
	TAD SCIF
	DCA RETFLD
ROUND,
INS1,	KSF
	JMP .-1
INS5,	KRS
	TAD S7600
	SNA CLA
	JMP NEWMON
	TAD LINK
	CLL RAR
INS2,	KRB
RETFLD,	0
	JMP I KRBSR

C35,	35


NEWMON,	TAD C35
	CIF CDF 10
	JMP 7705




SYSCNT,
FELDSR,	0
	DCA SAVE
	RDF
	TAD SCIF
	DCA RTFLD2
SCIF,	CIF CDF 0
	TAD I FELDSR
	DCA .+3
	TAD SAVE
BACKGO,
SBLKCT,
RTFLD2,	0	/MULTI-OVERLAY AREA	/JMS 7607
SFUN,	0				/1010
SLOC,	0				/0
SAVE,
SREC,	0				/64
MQSAV,	0				/HLT
	HLT				/JMP ROUND




NOPUNCH
*.+3
ENPUNCH

SDLDR,	DLDR

LINK,
EAEMOD,
KSFSR,	0
INS6,	KSF
	SKP
	ISZ KSFSR
	JMS FELDSR
	JMP I KSFSR