File ERROR.SB (8k SABR macro assembler source file)

Directory of image this file is from
This file as a plain text file

/ 1	OS/8 FORTRAN II ERROR MESSAGE PRINTER
/
	OPDEF	BSW	7002
	OPDEF	TADI	1400
ERROR,	BLOCK 2		/ ERROR ROUTINE
U7600,	7600		/ MONITOR EXIT
	DCA FATAL	/ FATAL ERROR FLAG LOESCHEN
	TAD	ERROR
	DCA	TEM1
TEM1,	HLT		/ DATA FIELD OF "CALL ERROR"
	TADI	ERROR#
	DCA	TEM3
	INC	ERROR#
	CLA CMA
	TADI	ERROR#
	DCA	10
	INC	ERROR#
TEM3,	HLT		/ DATA FIELD OF "MESSAGE"
	TADI	10
	RAL
	SZL
	ISZ	FATAL	/ SET FATAL ERROR FLAG
	CLL RAR
	DCA	M1	/ CHAR 1&2
	TADI	10
	DCA	M1#	/ CHAR 3&4
	TADI	10
	AND	(70
	CLL RAR
	RTR
	TAD	(4060
	BSW
	DCA	TEM1	/ CDF CALLER (ASCII)
	TADI	10
	JMS	OCTA
	CALLER		/ ADDR CALLER
	CALL 2,WRITE
	ARG (1
	ARG F
	CALL 1,IOH;ARG M1	/ 2A2
	CALL 1,IOH;ARG TEM1	/ 1A1
	CALL 1,IOH;ARG CALLER	/ 4A1
	CALL 1,IOH;ARG SEQUEN	/ I5
	CALL 1,IOH;ARG 0
	TAD FATAL
	SNA CLA
	JMP U7600	/ FATAL ERROR
	INC ERROR#
	INC ERROR#
	RETRN ERROR
M1,	BLOCK	1
M2,	BLOCK	1
TRACE,	BLOCK 2
	TAD I TRACE
	DCA	ERROR
	INC TRACE#
	TAD I TRACE
	DCA	ERROR#
	INC TRACE#
	CALL 1,IFAD
	ARG	ERROR
	CALL 1,STO
	ARG WORD7
	RETRN TRACE
ISNUM,	BLOCK	2	/ INTERNAL STATEMENT NUMBER HANDLING
	SNA
	JMP	IS1
	DCA	SEQUEN
IS2,	RETRN	ISNUM
IS1,	INC	SEQUEN
	JMP	IS2
SEQUEN,	0
	CPAGE	40
F, TEXT \(A6,A3,1X,A6,A2,1X,2A2,' ERROR AT LOC ',5A1,4H IN ,A6,3H AT,I5)\
FATAL,	0
OCTA,	0
	DCA	TEM
	TAD	(-4
	DCA	CNTR
	TADI	OCTA	/ STRINGADDRESS
	DCA	ADDR
	TAD	TEM
	CLL RAL
LP,	RTL
	RAL
	DCA	TEM
	TAD	TEM
	AND	(7
	TAD	(4060
	BSW
	DCAI	ADDR
	INC	ADDR
	ISZ	CNTR
	JMP	LP
	INC	OCTA
	JMP I	OCTA
TEM,	0
ADDR,	0
CNTR,	0
	END



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search