Directory of image this file is from
This file as a plain text file

0 REM I 
1 LET Y1=0 
10 LET M1=0 
20 DIM M(20),Y(20)
30 PRINT"   THIS IS A TWO-PERSON GAME CALLED 'EVEN WINS.'"
40 PRINT"TO PLAY THE GAME, THE PLAYERS NEED 27 MARBLES OR"
50 PRINT "OR OTHER OBJECTS ON A TABLE.  THE RULES ARE:" 
60 PRINT "(1)  YOU MUST ALTERNATE TURNS." 
70 PRINT "(2)  YOU MUST TAKE 1 TO 4 MARBLES AT EACH TURN."
80 PRINT "(3)  THE GAME ENDS WHEN THERE ARE NO MARBLES LEFT," 
90 PRINT
100 PRINT "     NUMBER OF MARBLES AT THE END OF THE GAME." 
170 PRINT "   AS MY UNCLE BILL USED TO SAY: 'HAVING HELPED"
180 PRINT "WRITE THE GAME, I ASSERT IT TAKES MORE THAN A"
181 PRINT "MODICUM OF SKILL AND ALSO, TALENT.  MANYS THE TIME" 
182 PRINT "WILST EXPLORING THE SHORES OF LAKE TITICACA AND"
183 PRINT "THE NETHER REACHES OF THE LESSER ANTILLIES, BEING"
184 PRINT "FORCED TO SURVIVE WITHOUT DRINK FOR HOURS AT A" 
185 PRINT "TIME, MY SKILL AT THIS GAME SAVED ME FROM A FATE" 
186 PRINT "WORSE THAN PHILLY.'"
187 PRINT "A TRULY UNSOLICITED TESTIMONIAL." 
190 PRINT
200 PRINT "DO YOU WANT THE FIRST TURN (1=YES, 0=NO)";
220 INPUT C
230 IF C=0 THEN 250
240 GOTO 1060
250 LET T=27 
260 LET M=2
270 GOSUB 1300 
280 LET M1=M1+M
290 LET T=T-M
300 PRINT "I PICK UP";M;"MARBLE";
301 IF M<2 THEN 303
302 PRINT "S"; 
303 PRINT "."
310 IF T=0 THEN 880
320 GOSUB 1300 
330 PRINT
340 PRINT "MY TOTAL IS";M1;"- HOW MANY WILL YOU PICK UP";
350 INPUT Y
370 IF Y<1 THEN 1160 
380 IF Y>4 THEN 1160 
390 IF Y<=T THEN 430 
400 PRINT "YOU CAN'T CHEAT AN HONEST PDP-8." 
420 GOTO 320 
430 LET Y1=Y1+Y
440 LET T=T-Y
450 IF T=O THEN 880
460 GOSUB 1300 
470 PRINT
480 PRINT "YOUR TOTAL IS";Y1;"- "; 
490 IF T<.5 THEN 880 
500 LET R=T-6*INT(T/6) 
510 IF INT(Y1/2)=Y1/2 THEN 700 
520 IF T<4.2 THEN 580
530 IF R>3.4 THEN 620
540 LET M=R+1
550 LET M1=M1+M
560 LET T=T-M
570 GO TO 300
580 LET M=T
590 LET T=T-M
600 GO TO 830
610 REM 250 IS WHERE I WIN.
620 IF R<4.7 THEN 660
630 IF R>3.5 THEN 660
640 LET M=1
650 GOTO 670 
660 LET M=4
670 LET T=T-M
680 LET M1=M1+M
690 GOTO 300 
700 REM I AM READY TO ENCODE THE STRAT FOR WHEN OPP TOT IS EVEN. 
710 IF R<1.5 THEN 1020 
720 IF R>5.3 THEN 1020 
730 LET M=R-1
740 LET M1=M1+M
750 LET T=T-M
760 IF T<.2 THEN 790 
770 REM IS # ZERO HERE 
780 GOTO 300 
790 REM IS = ZERO HERE 
800 PRINT"I PICK UP";M;" MARBLES." 
810 PRINT
820 GOTO 880 
830 REM THIS IS WHERE I WIN
840 PRINT "I PICK UP";M;" MARBLES."
850 PRINT""
870 LET M1=M1+M
880 PRINT "THAT ENDS THE GAME; LET ME SEE NOW-"
890 PRINT
900 PRINT "I HAVE";M1;"MARBLES, AND YOU HAVE";Y1;"." 
910 PRINT
920 IF INT(M1/2)=M1/2 THEN 950 
925 IF X9>0 THEN 935 
930 PRINT "BEELZEBUB!!  I'VE BEEN HOODWINKED!" 
931 LET X9=1 
932 GOTO 960 
935 PRINT "GODFREY DANIEL!  THE KIDS A HUSTLER." 
940 GOTO 960 
950 PRINT "M'BOY, YOU PUT UP A GOOD FIGHT, BUT"
955 PRINT "NATURALLY YOU CAN COMPETE WITH TRUE GENIUS."
960 PRINT "ANOTHER GO AT IT, PERCHANCE (1=YES, 0=NO)"; 
970 INPUT A1 
980 IF A1=0 THEN 1030
990 LET M1=0 
1000 LET Y1=0 
1010 GOTO 200 
1020 GOTO 640 
1030 PRINT
1040 PRINT "   AS MY UNCLE BILL USED TO SAY, 'THERE"
1050 PRINT "COMES A TIME IN THE AFFAIRS OF MEN WHEN"
1051 PRINT "ONE MUST TAKE THE BULL BY THE TAIL AND" 
1052 PRINT "FACE THE SITUATION.'" 
1053 STOP 
1060 LET T = 27 
1070 PRINT
1100 PRINT"TOTAL =";T 
1130 PRINT "WHAT IS YOUR FIRST MOVE"; 
1150 GOTO 350 
1160 PRINT
1170 PRINT "SUFFERIN' SCIATICA!  A MARBLE SHARK!" 
1180 PRINT "TRY TAKING 1 TO 4 MARBLES, BUNKY."
1190 PRINT
1200 PRINT "NOW WHAT IS YOUR CHOICE"; 
1220 GOTO 350 
1300 PRINT "THERE ";
1310 IF T>1 THEN 1330 
1320 PRINT "IS ONLY 1 MARBLE";
1321 GOTO 1340
1330 PRINT "ARE";T;"MARBLES"; 
1340 PRINT " LEFT." 
1350 RETURN 
1999 END