Directory of image this file is from
This file as a plain text file

/JSB 27 8 70    JG 15 10 71     EXC CODEC1.6

/EXCODEC     SAVOCODE EXITATION CODEC


*PART5

EXCDIN, 0       /INITIALISATION
        CLA
        DCA HIGHT
        CMA
        DCA DELCNT
        JMS I EXEXII
EXEXA,  0
        JMS I TMCDII
TIMCDA, 0
        JMS I SBCKI
SBCKA,  0
        JMS I APHNII
AMPHNA, 0
        JMS I OPHNII
OTPTHA, 0
        JMS I EXCDIN



EXCDRN, 0       /MAIN RETURN ADDRESS
        JMS I EXEXA     /EXITATION EXTRACTION
        JMP NOEVNT        /NO EVENT DETECTED
        DCA HIGHT

        DCA I YAI     / NO ADAPT
        DCA I YBI

        JMS I TIMCDA    /TIME HANDLING SR

        TAD HIGHT
        SKP
NOEVNT, CLA
        DCA PULS       / FOR SCOPE!

        JMS I SBCKA

        TAD HIGHT
        JMS I AMPHNA    /AMPLITUDE HANDLING SR
        JMS I OTPTHA    /OUTPUT CONSTRUCTION
        JMP I EXCDRN
PULS,   0
HIGHT,  0
DELCNT, 0

YAI,    YA
YBI,    YB
EXEXII, EXEXIN
TMCDII, TMCDIN
SBCKI,  SUBCLK
APHNII, APHNIN
OPHNII, OPHNIN


SUBCLK, 0       /SUB-CLOCK
        TAD DIVNUM
        CIA
        DCA DIVCNT
        JMS I SUBCLK
SBCKM,  0
        ISZ DIVCNT
        JMP I SBCKM
        TAD DIVNUM
        CIA
        DCA DIVCNT

        TAD DELCNT
        SZA CLA
        JMP I SBCKM     /IF DELCNT IS WAITING,
        IAC             /TRIGGER IT
        DCA DELCNT
        JMP I SBCKM

DIVCNT, 0
DIVNUM, 10      /SUB CLOCK RATIO

TMCDIN, 0
        JMS I TMCDIN
TIMCOD, 0
        TAD DELCNT
        CLL CIA
        TAD DEDNUM      /IS THE CODER FREE?
        SNL CLA
        DCA DELCNT      /YES,PRIME DELCNT
        JMP I TIMCOD
DEDNUM, 40      /NUM. OF SAMS BEFORE ANOTHER EVENT IS ACC.






OPHNIN, 0
        JMS I OPHNIN
OTPTHN, 0
        DCA SIZE

        CLL
        TAD DELCNT
        SZA             /IF DELCNT IS NON-ZERO,
        IAC             /THEN INCREMENT IT
        SZL
        CMA             /LIMIT AT 7777
        DCA DELCNT

        TAD OPDLNM
        CMA
        TAD DELCNT
        SNA CLA
        TAD SIZE

        JMP I OTPTHN

OPDLNM, 1
SIZE,   0


*EXCDIN+200

APHNIN, 0
        CLA
        DCA SIZELO
        TAD SMIN
        DCA SIZEHI
        DCA OVCNT
        TAD SZCTNM
        CIA
        DCA SZCNT
        JMS I APHNIN
AMPHAN, 0       /EXITATION SIZE CODEC

        CIA
        TAD SIZEHI
        SPA CLA
        ISZ OVCNT       /HIGHT>SIZE

        ISZ SZCNT
        JMP AHIN1

        TAD SZCTNM
        CIA
        DCA SZCNT
        TAD OVTH
        CIA
        TAD OVCNT
        SMA CLA
        JMP GRO
        JMP DEC

OUT,    DCA OVCNT
AHIN1,  TAD SIZEHI
        JMP I AMPHAN

SMIN,   40
SZCTNM, 40
OVTH,   10

SZCNT,  0
SIZEHI, 40
SIZELO, 0
OVCNT,  0


/STATE CHANGE ROUTINES

DEC,    TAD SIZELO
        MQL
        TAD SIZEHI
        LSR
        1               /DECAY PARAMETER
        CMA CLL
        TAD SIZEHI
        DCA SIZEHI

        MQA             /DEC SIZELO
        CIA STL
        TAD SIZELO
        SNL
        ISZ SIZEHI      /CARRY
        DCA SIZELO

        TAD SMIN        /LIMIT SMALL
        CIA CLL
        TAD SIZEHI
        CLA
        TAD SMIN
        SNL             /MIN INTO SIZEHI
        DCA SIZEHI      /IF SIZEHI<MIN
        CLA

        JMP OUT


GRO,    TAD SIZELO
        MQL
        TAD SIZEHI
        LSR
        1               /GROW
        SHL
        0
        TAD SIZEHI
        DCA SIZEHI
        MQA             /GROW SIZELO
        TAD SIZELO
        DCA SIZELO
        SZL
        IAC             /CARRY
        TAD SIZEHI
        SPA
        CLA CLL CMA RAR /SET AC TO 3777
        DCA SIZEHI

        JMP OUT


$$$$$$$$$$$$$$$$$$$$$$$$