Directory of image this file is from
This file as a plain text file

/***************** FLD2SR *******************************************
/16.3.76				D.COY  CS/FZNR
/SUBROUTINEN, DIE VON FELD 1 AUS ANGERUFEN WERDEN UND DEN
/FLOATING-POINT INTERPRETER BENUTZEN (EAEFPP.BN)
/DER BENOETIGTE KERNSPEICHERBEREICH GEHT VON 24400-24777.
/BEI BATCH-BETRIEB KANN FLD2SR NICHT VERWENDET
/WERDEN



ENTF=JMS I 7

FIELD 2
*4400

/CIF 20
/JMS SRFIX
/ADR. OF FLOAT. NUMBER IN FIELD 2
/ADR. OF MAX. FLOAT. NUMBER IN FIELD 2
/ADR. OF SCALE-FACTOR IN FIELD 2
/ADR.OF FIXED AND SCALED NUMBER IN FIELD 2


SRFIX,	0
	CLA
	TAD I SRFIX
	DCA SRFP1
	ISZ SRFIX
	TAD I SRFIX
	DCA SRFP2
	ISZ SRFIX
	TAD I SRFIX
	DCA SRFP3
	ISZ SRFIX
	TAD I SRFIX
	DCA SRFP4
	ISZ SRFIX

	CDF 20

	ENTF
	FGET I SRFP1
	FDIV I SRFP2
	FMPY I SRFP3
	FFIX
	FPUT I SRFP4
	FEXT
	
	CDF CIF 10
	JMP I SRFIX

SRFP1,	0
SRFP2,	0
SRFP3,	0
SRFP4,	0


*4511


/CIF 20
/JMS FFOUT      /F-FORMATAUSGABE
/ERG.ADR.       /ERG. IN FELD 20
/ANZ. ALLER STELLEN
/ANZ. DER STELLEN NACH DEM KOMMA

EFZ1,
FFOUT,  0
        CLA IAC
        DCA 56
        DCA 55
        TAD I FFOUT
        DCA FFZ1
        ISZ FFOUT
        TAD I FFOUT
        DCA 57
        ISZ FFOUT
        TAD I FFOUT
        DCA 60
        ISZ FFOUT

        CDF 20

        ENTF
        FGET I FFZ1
        FOUT
        FEXT

        CIF CDF 10
        JMP I FFOUT



/CIF 20
/JMS EFOUT
/ARG.   /ERGEBNISAUSGABE IN EFORMAT

FFZ1,   0
EFOUT,  0
        CLA
        TAD I EFOUT
        DCA EFZ1
        ISZ EFOUT

        CDF 20
        DCA 55
        DCA 56

        ENTF
        FGET I EFZ1
        FOUT
        FEXT

        CDF CIF 10
        JMP I EFOUT

PAGE

/CIF 20
/JMS SRMUY	/MULTIPLIKATION,ALLE ARG. IN FELD 20
/FAKTOR1
/FAKTOR2
/PRODUKT

SUZ1,
SRMUY,	0
	CLA
	TAD I SRMUY
	DCA DIVZ1
	ISZ SRMUY
	TAD I SRMUY
	DCA DIVZ2
	ISZ SRMUY
	TAD I SRMUY
	DCA DIVZ3
	ISZ SRMUY

	CDF 20

	ENTF
	FGET I DIVZ1
	FMPY I DIVZ2
	FPUT I DIVZ3
	FEXT

	CIF CDF 10
	JMP I SRMUY

/CIF 20
/JMS DIVIDR	/DIVISION, ALLE ARGUMENTE IN FELD 20
/DIVIDENT
/DIVISOR
/ERGEBNIS	


SUZ2,
DIVIDR,	0
	CLA
	TAD I DIVIDR
	DCA DIVZ1
	ISZ DIVIDR
	TAD I DIVIDR
	DCA DIVZ2
	ISZ DIVIDR
	TAD I DIVIDR
	DCA DIVZ3
	ISZ DIVIDR

	CDF 20

	ENTF
	FGET I DIVZ1
	FDIV I DIVZ2
	FPUT I DIVZ3
	FEXT

	CIF CDF 10
	JMP I DIVIDR

/CIF 20
/JMS SUMM	ALLE ARG. IN FELD 20
/SUMMAND1
/SUMMAND2
/SUMME

DIVZ2,
SUMM,	0
	CLA
	TAD I SUMM
	DCA SUZ1
	ISZ SUMM
	TAD I SUMM
	DCA SUZ2
	ISZ SUMM
	TAD I SUMM
	DCA SUZ3
	ISZ SUMM

	CDF 20

	ENTF
	FGET I SUZ1
	FADD I SUZ2
	FPUT I SUZ3
	FEXT

	CIF CDF 10
	JMP I SUMM


/CIF 20
/JMS DIFF	/DIFFERENZ
/SUMMAND1
/SUMMAND2
/DIFFERENZ

DIVZ3,
NRMDZ2,
DIFF,	0
	CLA
	TAD I DIFF
	DCA SUZ1
	ISZ DIFF
	TAD I DIFF
	DCA SUZ2
	ISZ DIFF
	TAD I DIFF
	DCA SUZ3
	ISZ DIFF

	CDF 20

	ENTF
	FGET I SUZ1
	FSUB I SUZ2
	FPUT I SUZ3
	FEXT

	CDF CIF 10
	JMP I DIFF


/CIF 20
/JMS NORMD	/UMWANDLUNG: DOUBLE PREC. IN FLOAT. POINT
/ARG1	/DOPPELTGENAU IN FELD 10
/ARG2	/FP.DARST. IN FELD 20

NRP23,	27

DIVZ1,
SUZ3,
NORMD,	0
	SWAB
	CLA
	TAD I NORMD
	DCA NRMDZ1
	ISZ NORMD
	TAD I NORMD
	DCA NRMDZ2
	ISZ NORMD

	CAM DAD
NRMDZ1,	0
	CDF 20
	SWP
	DST
	45
	CLA
	TAD NRP23
	DCA 44

	ENTF
	FNOR
	FPUT I NRMDZ2
	FEXT

	CIF CDF 10
	JMP I NORMD


/CIF 20
/JMS FUNCSR	/X,Y IN FELD 20
/FUNCTION
/X ADR.
/Y ADR.

FUNCSR,	0
	CLA
	TAD I FUNCSR
	DCA FUNC
	ISZ FUNCSR
	TAD I FUNCSR
	DCA NRMDZ1
	ISZ FUNCSR
	TAD I FUNCSR
	DCA NRMDZ2
	ISZ FUNCSR

	CDF 20

	ENTF
	FGET I NRMDZ1
FUNC,	0
	FPUT I NRMDZ2
	FEXT

	CIF CDF 10
	JMP I FUNCSR