File HANG.BA (BASIC source file)

Directory of image this file is from
This file as a plain text file

10 REM *** GAME OF HANGMAN BY DAVE AHL, DIGITAL
15 REM *** BASED ON A PROGRAM WRITTEN BY KEN AUPPERLE, CLASS OF '75,
20 REM *** HALF HOLLOW HILLS H.S., DIX HILLS, NY
21 REMARKABLY TRANSLATED TO OS8 BASIC BY KAY R. FISHER ...DEC
25 PRINT "GAME OF HANGMAN"\PRINT \PRINT 
30 DIM P$(144,1),L$(20,1),D$(20,1),N$(20,1),U(50)
35 DIM A$(20)
36 DIM B$(20)
40 C=1\RANDOMIZE\N=50\M=0
50 FOR I=1 TO 20\D$(I)="-"\NEXT I
60 FOR I=1 TO 20\N$(I)=""\NEXT I
70 FOR I=1 TO 144\P$(I)=" "\NEXT I
80 FOR I=1 TO 133 STEP 12\P$(I)="X"\NEXT I
90 FOR I=1 TO 7\P$(I)="X"\NEXT I
91 P$(19)="X"
95 IF C<N THEN 100 \ PRINT "YOU DID ALL THE WORDS!!"\STOP
100 Q=INT(N*RND(0)+1)
110 IF U(Q)=1 THEN 100 \ U(Q)=1\C=C+1\RESTORE\T1=0
150 FOR I=1 TO Q\READ A$\NEXT I
160 L=LEN(A$)
165 FOR I=1 TO L\L$(I)=SEG$(A$,I,I)\NEXT I
170 PRINT "HERE ARE THE LETTERS YOU USED:"
180 FOR I=1 TO 26\PRINT  N$(I);\IF N$(I+1)="" THEN 200
190 PRINT ",";\NEXT I
200 PRINT \PRINT \FOR I=1 TO L\PRINT  D$(I);\NEXT I\PRINT \PRINT 
210 PRINT "WHAT IS YOUR GUESS"\INPUT G$\R=0
220 FOR I=1 TO 26\IF N$(I)="" THEN 250
230 IF G$<>N$(I) GOTO240\ PRINT  "YOU GUESSED THAT LETTER BEFORE"\GOTO 170
240 NEXT I\PRINT  "PROGRAM ERROR.  RUN AGAIN."\STOP
250 N$(I)=G$\T1=T1+1
260 FOR I=1 TO L\IF L$(I)=G$ THEN 280
265 NEXT I
270 IF R=0 THEN 290 \ GOTO 300
280 D$(I)=G$\R=R+1\GOTO 265
290 M=M+1\GOTO 400
300 FOR I=1 TO L\IF D$(I)="-" THEN 320
310 NEXT I
315 GOTO 390
320 PRINT \FOR I=1 TO L\PRINT  D$(I);\NEXT I\PRINT \PRINT 
330 PRINT "WHAT IS YOUR GUESS FOR THE WORD";\INPUTB$
340 IF B$=A$ THEN 360
350 PRINT "WRONG.  TRY ANOTHER LETTER."\PRINT \GOTO 170
360 PRINT "RIGHT!!  IT TOOK YOU";T1;"GUESSES!"
370 PRINT "WANT ANOTHER WORD";\INPUTW$\IF W$="YES" THEN 50
380 PRINT \PRINT "IT'S BEEN FUN!  BYE FOR NOW."\STOP
390 PRINT "YOU FOUND THE WORD!"\GOTO 370
400 PRINT \PRINT \PRINT "SORRY, THAT LETTER ISN'T IN THE WORD."
410 IFM=2GOTO420\IFM=3GOTO425\IFM=4GOTO430\IFM=5GOTO435\IFM=6GOTO440
411 IFM=7GOTO445\IFM=8GOTO450\IFM=9GOTO455\IFM=10GOTO460
415 PRINT "FIRST, WE DRAW A HEAD"\GOTO 470
420 PRINT "NOW WE DRAW A BODY"\GOTO 470
425 PRINT "NEXT WE DRAW AN ARM"\GOTO 470
430 PRINT "THIS TIME IT'S THE OTHER ARM"\GOTO 470
435 PRINT "NOW, LET'S DRAW THE RIGHT LEG"\GOTO 470
440 PRINT "THIS TIME WE DRAW THE LEFT LEG"\GOTO 470
445 PRINT "NOW WE PUT UP A HAND"\GOTO 470
450 PRINT "NEXT THE OTHER HAND"\GOTO 470
455 PRINT "NOW WE DRAW ONE FOOT"\GOTO 470
460 PRINT "HERE'S THE OTHER FOOT -- YOU'RE HUNG!!"
470 IFM=2GOTO490\IFM=3GOTO500\IFM=4GOTO510\IFM=5GOTO520\IFM=6GOTO530
475 IFM=7GOTO540\IFM=8GOTO550\IFM=9GOTO560\IFM=10GOTO570
480 P$(30)="-"\P$(31)="-"\P$(32)="-"\P$(41)="("\P$(42)="."
481 P$(44)="."\P$(45)=")"\P$(54)="-"\P$(55)="-"\P$(56)="-"\GOTO 580
490 P$(67)="X"\P$(79)="X"\P$(91)="X"\P$(103)="X"
495 GOTO 580
500 P$(39)=CHR$(28)\P$(52)=CHR$(28)\P$(65)=CHR$(28)\P$(78)=CHR$(28)
505 GOTO 580
510 P$(47)="/"\P$(58)="/"\P$(69)="/"\P$(80)="/"\GOTO 580
520 P$(114)="/"\P$(125)="/"\GOTO 580
530 P$(116)=CHR$(28)\P$(129)=CHR$(28)\GOTO 580
540 P$(35)=CHR$(28)\GOTO 580
550 P$(27)="/"\GOTO 580
560 P$(142)=CHR$(28)\P$(143)="-"\GOTO 580
570 P$(135)="-"\P$(136)="/"
580 FOR I=1 TO 133 STEP 12
581 FOR J=0 TO 11
582 PRINT P$(I+J);\NEXT J
583 PRINT
584 NEXT I
590 PRINT\PRINT\PRINT\IF M=10 THEN 600\GOTO 170
600 PRINT "SORRY, YOU LOSE.  THE WORD WAS ";A$
610 PRINT "YOU MISSED THAT ONE.  DO YOU"\GOTO 370
700 DATA "GUM","SIN","FOR","CRY","LUG","BYE","FLY"
710 DATA "UGLY","EACH","FROM","WORK","TALK","WITH","SELF"
720 DATA "PIZZA","THING","FEIGN","FIEND","ELBOW","FAULT","DIRTY"
730 DATA "BUDGET","SPIRIT","QUAINT","MAIDEN","ESCORT","PICKAX"
740 DATA "EXAMPLE","TENSION","QUININE","KIDNEY","REPLICA","SLEEPER"
750 DATA "TRIANGLE","KANGAROO","MAHOGANY","SERGEANT","SEQUENCE"
760 DATA "MOUSTACHE","DANGEROUS","SCIENTIST","DIFFERENT","QUIESCENT"
770 DATA "MAGISTRATE","ERRONEOUSLY","LOUDSPEAKER","PHYTOTOXIC"
780 DATA "MATRIMONIAL","PARASYMPATHOMIMETIC","THIGMOTROPISM"
999 END



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search