File HLTS1.PA (PAL assembler source file)

Directory of image this file is from
This file as a plain text file

/HALTS 1 CDN   23/5/72


*200


	CLA
	DCA FIELD0
WHICH,	KSF	/WHICH FIELD ?
	JMP .-1
	KRB
	TLS
	TAD NM260
	DCA FIELDN
	TAD FIELDN
	AND N7770
	SNA
	JMP ACTION

ISITRT,	CLA
	TAD FIELDN
	TAD RET
	SNA
	JMP END
	JMP WHICH

F0,	ISZ FIELD0	/SET FLAG TO DO FIELD 0 LAST
	JMP WHICH

NM260,	-260
FIELDN,	0
FIELD0,	0
N7770,	7770
RET,	-215+260

ACTION,	CLA CLL
	TAD FIELDN
	SNA
	JMP F0
	RTL
	RAL
	TAD NCDF
	DCA INSTR
	TAD N7600
	DCA NUM
	JMS PUT
NUM,	0	/NUMBER OF LOCS TO BE 'HLT'ED
ADDR,	0	/STARTING ADDRESS OF HLTS
	JMP WHICH



PUT,	0
	CLA
	TAD I PUT
	ISZ PUT
	CIA
	DCA COUNT
	CLA CMA
	TAD I PUT
	ISZ PUT
	DCA 10
INSTR,	HLT
LOOP,	TAD NHLT
	DCA I 10
	ISZ COUNT
	JMP LOOP
	CDF 0
	JMP I PUT

NCDF,	CDF
N200,	200
N7600,	7600
NHLT,	HLT
COUNT,	0

END,	CLA
	CDF 0
	TAD FIELD0
	SNA CLA	/HLTS INTO FIELD 0 ?
	JMP I MONIT
	TAD NCDF
	DCA INSTR
	JMS PUT
	6600
	1000	/6600 HLTS LOCS 1000 TO 7577

	JMS I SYSDEV	/WRITE ON SYS SCRATCH AREA
	5000		/TO SIMULATE HLTS IN LOWER CORE
	1000
	33
	HLT
	JMP I MONIT

SYSDEV,	7607
MONIT,	7605

$$$$$$$$$$$$$$$$



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search