Directory of image this file is from
This file as a plain text file

/FOCAL-8 INIT
/DEC-8E-LFOCA-A-LA2

/OCTOBER 1971			SM

/COPYRIGHT 1971 DIGITAL EQUIPMENT CORPORATION
/	MAYNARD,MASSACHUSETTS   01754

/INITIAL DIALOG FOR FOCAL-8
/INIT IS A FOCAL-8 PROGRAM STORED IN THE TEXT BUFFER
/AND EXECUTED.  THE VARIABLES SET ARE USED LATER BY
/ONCE-ONLY CODE WHICH IS ALSO STORED IN THE TEXT BUFFER


/ASSEMBLY INSTRUCTIONS:
/.R PAL8 OR .R PAL10
/*INIT,INIT_INIT



/THE FOCAL-8 PROGRAM FOR INIT IS:

/1.10 T !"FOCAL-8"
/1.20 T !!"MONITOR IN USE ?";DO 10;S PD=RE
/1.25 DO 2;T !!;R

/2.15 SET XF=1
/2.20 T !"RETAIN"
/2.25 T "LOG,EXP,ATN ?"
/2.30 DO 10;IF (RE) 2.9,2.4,2.4
/2.40 DO 2.2;T "SINE,COSINE ?";DO 10;IF (RE) 2.5;R
/2.5  S XF=-1;R
/2.9  S XF=0

/10.40 A RE;I (RE-0YES) 10.5,10.45,10.5
/10.45 SET RE=-1;R
/10.50 IF (RE-0NO) 10.6,10.8
/10.60 T !"PLEASE ANSWER 'YES' OR 'NO' ";G 10.4
/10.80 SET RE=1;R



OCTAL

CR=7715

*31	/(LASTV)
	ENDL

*60	/(BUFR)
	ENDL

*3206	/(FRST)
	LN1P1

*3217

DECIMAL

/01.10
LN1P1,	LN1P2
02^64!10
TEXT @T !"FOCAL-8"@;*.-1;CR

/01.20
LN1P2,	LN1P25
2^64!20
TEXT @T !!"MONITOR IN USE @;*.-1
OCTAL
4037
DECIMAL
TEXT @";  DO 10;S PD=RE @;*.-1;CR


/01.25
LN1P25,	LN2P15
2^64!25
TEXT @DO 2; T !!;R@;*.-1;CR











/02.15
LN2P15,	LN2P2
4^64!15
TEXT @SET XF=1@;*.-1;CR

/02.20
LN2P2,	LN2P25
4^64!20
TEXT @T !"RETAIN "@;*.-1;CR

/02.25
LN2P25,	LN2P3
4^64!25
TEXT @T "LOG, EXP, ATN@
*.-1
OCTAL
	4037	/QUESTION MARK
	7715	/CARRIAGE RETURN

DECIMAL

/02.30
LN2P3,	LN2P4
4^64!30
TEXT @DO 10;IF (RE)2.9,2.4,2.4@;*.-1;CR

/02.40
LN2P4,	LN2P5
4^64!40
TEXT @DO 2.2;T "SINE, COSINE@
*.-1
OCTAL
	4037	/QUESTION MARK
DECIMAL
TEXT @";DO 10;IF (RE)2.5;R@;*.-1;CR

/02.50
LN2P5,	LN2P9
4^64!50
TEXT @S XF=-1; R@;*.-1;CR

/02.90
LN2P9,	LN10P4
4^64!90
TEXT @S XF=0@;*.-1;CR

/10.40
LN10P4,	LN1045
20^64!40
TEXT @A RE;I (RE-0YES) 10.5,10.45,10.5@;*.-1;CR
/10.45
LN1045,	LN10P5
20^64!45
TEXT @ SET RE=-1;R@;*.-1;CR

/10.50
LN10P5,	LN10P6
20^64!50
TEXT @IF (RE-0NO)10.6,10.8@;*.-1;CR

/10.60
LN10P6,	LN10P8
20^64!60
TEXT @T !"PLEASE ANSWER 'YES' OR 'NO' ";G 10.4@;*.-1;CR

/10.80
LN10P8,	0000
20^64!80
TEXT @SET RE=1;R@;*.-1;CR

ENDL=.

$