File LOGIN.PA (PAL assembler source file)

Directory of image this file is from
This file as a plain text file

/LOGIN.SV
/PRINT LOGIN MESSAGE LEFT IN CORE BY SI, THEN
/CHAIN TO DA.SV[0,2].  IF ACCOUNT LOGGING IN IS
/[0,1]-[0,7], OR HE IS ON THE CTY, THE LOGIN
/MESSAGE IS SUPPRESSED.
/BY JOHN YOUNG - 2/18/76
/

*0000
	CLA CLL
	USE
	CON
	SNA CLA		/IF CTY, GO TO DA.SV
	JMP	DA	/OTHERWISE, KEEP ON GOING
	JMP	20

*0010
AUX1,	7377
AUX2,	BLK
AUX3,	7577

*0020
	ACT
	AND	P7770
	SNA CLA		/ACCOUNTS 1-7?
	JMP	DA	/YES, FORGET LOGIN MESSAGE
	JMS	CRLF	/CRLF, NEW LINE
	TAD I	AUX3	/GET A CHAR
	SNA		/END OF MESSAGE?
	JMP	.+4	/YES, GO TO DA.SV
	TLS		/NOPE OUTPUT
	CLA
	JMP	.-5	/GET NEXT CHAR

DA,	JMS	CRLF	/FINISH LINE, AGAIN
	KSF
	JMP	.+3
	KRB
	JMP	.-3	/CLEAR INPUT BUFFER OF GARBAGE
	CLA
	TAD	OPNBLK
	OPEN		/OPEN DA.SV[0,2]
	SZA CLA
	HLT		/HALT ON ANY ERROR
	TAD I	AUX2	/PICK UP WORD
	DCA I	AUX1	/PUT IN HIGH CORE
	ISZ	COUNT	/DONE?
	JMP	.-3	/NO, KEEP GOING
	JMP I	.+1	/YUP, GO CHAIN TO IT
	7400

CRLF,	0
	CLA
	TAD	P15
	TLS
	TAD	N3
	TLS
	CLA
	JMP I	CRLF

P7770,	7770
P15,	15
N3,	-3
COUNT,	-12	/12 WORDS TO MOVE

OPNBLK,	.+1
	0
	2	/[0,2]
	4441	/DA
	0
	0

BLK,	.	/*7400
	1203	/TAD	RFDT
	6603	/RFILE
	5000	/JMP	0
	7404	/RFDT,	.+1
	0	/0
	0	/0
	-1000	/1000 WORDS TO TRANSFER
	-1	/START AT LOCATION 0
	0	/DSK=0
	0	/ERROR RETURNED (THIS IS IGNORED)

$$$



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search