File LPTEST.PA (PAL assembler source file)

Directory of image this file is from
This file as a plain text file

/TEST PROGRAM FOR LINE PRINTERS ON THE PDP-8 "FAMILY" COMPUTERS
/AS AN LP08
/AC00=0,80 COL; =1,132 COL
/AC01=0,FULL CARRAGE WIDTH; =1, SHORT 1 CHARACTER
/AC02=0,NO CR; =1, WITH CR
/AC03=0,PROGRAM MODE; =1, INTERRUPT MODE
/AC04=0,OUTPUT A VT PER AC05-AC11; =1, SELECT PER ABOVE

AUTO=10
LSF=6661
LCF=6662
LSR=6663
LPC=6664
LIN=6665
LLS=6666
LIF=6667

*0001
	JMP I .+1
	INT1

*0200
START,	DCA FSTCAR
	DCA TYPE
	LLS
NEWLIN,	LIF
	LSR
	JMP .+2
	HLT
	JMP FILL
	TAD BUFBEG
	DCA AUTO
	TAD BUFSIZ
	CMA IAC
	DCA COUNT
	LAS
	RTL
	RTL
	SPA CLA
	JMP INT
PRO,	TAD I AUTO
	LSF
	JMP .-1
	LLS
	CLA
	ISZ COUNT
	JMP PRO
	JMP NEWLIN
INT,	LIN
	TAD I AUTO
	ION
	JMP .
INT1,	LSF
	HLT
	LLS
	CLA
	ISZ COUNT
	JMP INT+1
	JMP NEWLIN
M2,	-0002
BUFBEG,	0377
BUFSIZ,	0000
B80,	0177
B132,	0064
COUNT,	0000
MASK1,	0077
FSTCAR,	0000
TYPE,	0000
LF,	0012
CR,	0015
FF,	0014
VT,	0013
TEMP,	0000
C40,	0040
FILL,	0000
	TAD BUFBEG
	DCA AUTO
	DCA BUFSIZ
	LAS
	SPA CLA
	TAD B132
	TAD B80
	DCA TEMP
	LAS
	RAL
	SMA CLA
	ISZ TEMP
	TAD TEMP
	CIA
	DCA COUNT
	TAD FSTCAR
	AND MASK1
	DCA FSTCAR
	TAD FSTCAR
	SZA CLA
	JMP LINGEN
	TAD TYPE
	CMA
	DCA TYPE
	TAD FF
	LSF
	JMP .-1
	LLS
	CLA
LINGEN,	TAD FSTCAR
	DCA TEMP
FILL1,	TAD TEMP
	AND MASK1
	TAD C40
	DCA I AUTO
	TAD TYPE
	SZA CLA
	ISZ TEMP
	ISZ BUFSIZ
	ISZ COUNT
	JMP FILL1
	ISZ FSTCAR
	LAS
	RTL
	RTL
	SPA CLA
	JMP CRLF
	TAD VT
	DCA I AUTO
	ISZ BUFSIZ
	LAS
	DCA I AUTO
	ISZ BUFSIZ
	JMP I FILL
CRLF,	LAS
	RTL
	SPA SZL
	JMP .+3
	CLA
	JMP I FILL
	SMA CLA
	JMP CRLF1
	TAD CR
	DCA I AUTO
	ISZ BUFSIZ
CRLF1,	TAD LF
	DCA I AUTO
	ISZ BUFSIZ
	JMP I FILL
$



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search