Directory of image this file is from
This file as a plain text file

/10
/
/
/%R	MISCELLANEOUS ROUTINE
/
/%TW	WATCH FOR A SPLICE AND RECALIBRATE THE INSPECTOR
/	AFTER THE SPLICE IS PAST CHANNEL 3. ALSO TURN ON
/	THE SPLICE COMMENT ON THE M.O.P. AND LOCK IN THE
/	SAMPLE TRAY UNTIL SPLICE IS IN THE SAMPLE TRAY
/
/
MISC1,	0
	CLB IAC		/HAS THE MACHINE CHECK MESSAGE DISPLAY
	TAD MCKMCT	/TIMED OUT ?
	SPA SNA
	DCA MCKMCT
	SNL CLA
	JMP .+4		/NO, GO ON.
	CIF 30		/YES, GO REMOVE THE MACHINE CHECK MESSAGE.
	JMS I (CRTCUE)
	CRTH23

	CLB IAC
	TAD SPLMCT	/HAS THE SPLICE MESSAGE DISPLAY TIMED
	SPA SNA		/OUT ?
	DCA SPLMCT
	SNL CLA
	JMP .+4		/NO, GO ON.
	CIF 30
	JMS I (CRTCUE)	/YES, GO REMOVE THE "SPLICE DETECTED"
	CRTH25		/MESSAGE.

	CLB
	TAD SPLFLG	/IS THE SPLICE DETECTED FLAG SET ?
	SNA CLA
	JMP MIS1	/NO, GO ON.
	CIF 30
	JMS I (CRTCUE)	/YES, GO CUE THE "SPLICE DETECTED" MESSAGE
	CRTH24		/FOR DISPLAY.
	TAD (-400)	/SET THE SPLICE MESSAGE DISPLAY DELAY
	DCA SPLMCT	/COUNTER.
	CLB CMA RTL	/SET UP THE INSPECTION RECAL DELAY.
	DCA INSPDY
	ISZ SWPRJF	/SET THE SWAP REJECT TRAY FLAG.
	ISZ RINGAF	/SET THE RING THE ALERT ALARM FLAG.
/11
	ISZ SMTLKF	/LOCK IN THE SAMPLE TRAY.
	TAD (-55)
	DCA SMTLKD	/SET THE SAMPLE TRAY UNLOCK DELAY.
	DBRI51		/IS THE SAMPLE OR A REJECT TRAY OUT ?
	MQL
	DBRO51
	MQA
	AND P7000
	TAD SMGEJC
	TAD RAGEJC
	TAD RBGEJC
	SNA CLA
	JMP .+3		/NO, GO ON.
	TAD P400	/YES, GO OPEN THE "TRAY OUT" INTERLOCK.
	JMS INLOCK
	DCA REJCNT	/SET THE REJECT SHEET COUNTER TO ZERO.
    IFNDEF	EPLTEST	<
	DBRI52		/HAS THE UNWIND SWITCHED OVER ?
	AND P1000
    >
    IFDEF	EPLTEST	<
	DBRI50
	AND P100
    >
	CIA
	TAD UNWDBF
	SNA CLA
	JMP I MISC1	/NO, RETURN.
    IFNDEF	EPLTEST	<
	DBRI52		/YES, RESET THE UNWIND SWITCHOVER FLAG
	AND P1000	/FROM THE INPUT REGISTER.
    >
    IFDEF	EPLTEST	<
	DBRI50
	AND P100
    >
	DCA UNWDBF
	CDF 20
	ISZ I (ESMFLG)	/SET THE END OF ROLL SAMPLE FLAG.
	CDF 0
	DCA SWPRJF	/CLEAR THE SWAP THE REJECT TRAY FLAG.
	TAD SISRLF	/IS THIS A SISTER ROLL ?
	SNA CLA
	JMP .+4		/NO, GO ON.
	DCA SISRLF	/YES, CLEAR THE SISTER ROLL FLAG.
	ISZ SWPRJF	/SET THE SWAP THE REJECT TRAY FLAG.
	JMP I MISC1	/RETURN.
	TAD P200	/NO, STOP WITH THE SPLICE IN THE
	DBSO54		/INSPECTOR.
	CLB
	JMP I MISC1	/RETURN.
/11A
MIS1,	CLB
	TAD I MEMPTR	/IS THERE A SPLICE NOW AT THE CHOPPER ?
	AND P10
	SNA CLA
	JMP MIS2	/NO, GO ON.
	TAD SWPRJF	/YES, IS THE SWAP REJECT TRAY FLAG SET ?
	SZA CLA
	JMS CHNGRJ	/YES, GO CHANGE THE ACTIVE REJECT TRAY AND
			/EJECT THE CURRENT REJECT TRAY.
	DCA SWPRJF	/CLEAR THE SWAP THE REJECT TRAY FLAG.
	JMP I MISC1	/RETURN.

MIS2,	CLB IAC		/INCREMENT THE RECALIBRATE DELAY COUNTER.
	TAD SMTLKD
	SPA SNA
	DCA SMTLKD
	SZL CLA
	DCA SMTLKF
	CLB IAC		/HAS THE RECALIBRATE DELAY TIMED OUT ?
	TAD INSPDY
	SPA SNA
	DCA INSPDY
	SNL CLA
	JMP I MISC1	/NO, RETURN.
	TAD SHUTDY	/YES, HAS THE SHUTTER OPENING DELAY TIMED
	SNA CLA		/OUT ?
	JMP .+4		/YES, GO ON.
	CLB CMA		/NO, RESET THE RECAL DELAY.  THIS WILL 
	DCA INSPDY	/FORCE A RECAL AFTER THE SHUTTER IS OPEN.
	JMP I MISC1	/RETURN.
	TAD P400	/YES, HIT THE END OF SPLICE RECALIBRATE
	DBSO55		/LINE.
	CLB CMA RTL
	DCA WKA		/HOLD THE LINE DOWN FOR 13.2
	ISZ WKA		/MICROSECONDS.
	JMP .-1
	TAD P400	/CLEAR THE RECALIBRATE LINE.
	DBCO55
	CDF 10
	CLB IAC		/SET THE RECALIBRATE FLAG FOR DIGITAL
	DCA I (DIGREC)	/SELF CHECK.
	CDF 0
	JMP I MISC1	/RETURN.
/12
SISRLF,	0		/SISTER ROLL NEXT FLAG.
SMTLKD,	0		/SAMPLE TRAY LOCKED IN DELAY COUNTER.
SWPRJF,	0		/SWAP THE REJECT TRAY ON SPLICE FLAG.

	PAGE