10 PRINT "BODENKONTROLLE RUFT LUNAR MODULE ....."
20 PRINT "BORD- UND BODENCOMPUTER SIND GLEICHZEITIG AUSGEFALLEN"
30 PRINT "(ES SIND KEINE DEC-COMPUTER)."
40 PRINT "MANUELLE STEUERUNG IST ERFORDERLICH"
50 PRINT
60 PRINT "DIE KAPSEL WIEGT 32.500 LBS. VERFUEGBARE TANKFUELLUNG"
70 PRINT "16.500 LBS. DIE UNGEFAEHRE FALLZEIT (FREIER FALL) BETRAEGT"
80 PRINT "120 SEKUNDEN."
90 PRINT
100 PRINT "DIE BREMSRAKETEN KOENNEN ALLE 10 SEKUNDEN AUF IRGENDEINEN"
110 PRINT "WERT ZWISCHEN 0 LBS/SEC (FREIER FALL) UND "
120 PRINT "200 LBS/SEC (HARTE BREMSUNG) EINGESTELLT WERDEN."
130 PRINT 
140 PRINT "VIEL GLUECK !!!"
150 PRINT
160 PRINT "SEC","MI + FT","MPH","LB FUEL","BURN RATE"
170 PRINT
180 LET A=120
190 LET L=0
195 LET V=1
200 LET M=33000
210 LET N=16500
220 LET G=.001
230 LET Z=1.8
240 PRINT L,INT(A);INT(5280*(A-INT(A))),3600*V,M-N,
250 INPUT K
260 LET T=10
270 IF M-N<.001 THEN 380
280 IF T<.001 THEN 240
290 LET S=T
300 IF M>=N+S*K THEN 320
310 LET S=(M-N)/K
320 GOSUB 790
330 IF I<=0 THEN 650
340 IF V<=0 THEN 360
350 IF J<0 THEN 710
360 GOSUB 590
370 GOTO 270
380 PRINT "TREIBSTOFFVORRAT NACH";L;"SEC ERSCHOEPFT."
390 LET S=(-V+SQR(V*V+2*A*G))/G
400 LET V=V+G*S
410 LET L=L+S
420 LET W=3600*V
430 PRINT "MONDLANDUNG NACH ";L;"SEC-AUFTREFFGESCHWINDIGKEIT";W;"MPH"
440 IF W>1.2 THEN 470
450 PRINT "PERFEKTE LANDUNG!"
460 GOTO 840
470 IF W>10 THEN 500
480 PRINT "ANNEHMBARE LANDUNG (KOENNTE BESSER SEIN)."
490 GOTO 840
500 IF W>60 THEN 550
510 PRINT "MASCHINENSCHADEN! SIE MUESSEN LEIDER AUF EINE RETTUNGS-"
520 PRINT "MISSION WARTEN. WIR HOFFEN, DASS IHR SAUERSTOFFVORRAT"
530 PRINT "AUSREICHT."
540 GOTO 840
550 PRINT "BEDAUERLICHERWEISE GIBT ES KEINE UEBERLEBENDEN! --"
560 PRINT "SIE HABEN JEDOCH EINEN NEUEN MONDKRATER VON"
570 PRINT W*.2777;"FT TIEFE ERZEUGT"
580 GOTO 840
590 LET L=L+S
600 LET T=T-S
610 LET M=M-S*K
620 LET A=I
630 LET V=J
640 RETURN
650 IF S<.005 THEN 420
660 LET D=V+SQR(V*V+2*A*(G-Z*K/M))
670 S=2*A/D
680 GOSUB 790
690 GOSUB 590
700 GOTO 650
710 LET W=(1-M*G/(Z*K))/2
720 LET S=M*V/(Z*K*(W+SQR(W*W+V/Z)))+.05
730 GOSUB 790
740 IF I<=0 THEN 650
750 GOSUB 590
760 IF J>0 THEN 270
770 IF V>0 THEN 710
780 GOTO 270
790 LET Q=S*K/M
800 LET J=V+G*S-Z*Q*(1+Q*(.5+Q*(1/3+Q*(.25+Q/5))))
810LET I=A-G*S*S/2-V*S+Z*S*Q*(.5+Q*(1/6+Q*(1/12+Q/20)))
820 RETURN
830 STOP
840 PRINT "WOLLEN SIE NOCHEINMAL VERSUCHEN (JA ODER NEIN)   ";
850 INPUT Z$
860 IF Z$="JA" THEN 140
870 IF Z$="NEIN" THEN 900
880 PRINT "WAS SOLL DAS BEDEUTEN?"
890 GOTO 840
900 END