Directory of image this file is from
This file as a plain text file

	DCLA=6751
	DLDR=6733
	DLDC=6732
	DRDS=6741
	DRWC=6752
	DCLS=6742
	DSKC=6745
	DLWC=6753
	DSKE=6747
	DLCA=6755

*4000
NOPUNCH
*7607
ENPUNCH



SHNDLR,	0
	CLA CLL CMA RTL
	DCA SYSCNT	/NO. ERROR TRIES
	RDF
	TAD SCIF
	DCA SFIELD	/CALLING FIELD..FOR RETURN
	TAD I SHNDLR
	DCA SFUN	/FUNCTION WORD
	ISZ SHNDLR
	CLA CMA
	TAD I SHNDLR
	DCA SLOC	/BUFFER ADDRESS-1
	ISZ SHNDLR
STRY,	TAD I SHNDLR
	DCA SREC
	TAD SFUN
	RAL
	AND S7600
	DCA SBLKCT	/WORD COUNT
	RTL
	TAD SDLDR
	DCA SINST	/SINST=6733 (READ) OR 6735 WRITE
SLOOP,	TAD SLOC
	DLCA		/LOAD CURRENT ADDRESS
	TAD SBLKCT
	TAD S7600	/FULL OR HALF RECORD READ?
	SZA CLA
	TAD S7600	/FULL..2 PAGES
	TAD S7600	/HALF..1 PAGE
	DLWC		/WORD COUNT
	DCLS		/CLEAR ALL FLAGS
	TAD SFUN
	AND S70
	DLDC		/LOAD DATA FILED OF BUFFER
	TAD SREC
SINST,	0		/READ OR WRITE IOT
	DSKC
	JMP .-1
SNEXT,	DSKE		/DONE..IS ERROR FLAG UP?
	SKP
	JMP SERROR	/YEAH?!
	ISZ SREC	/NO..BUMP RECORD NO.
S70,	70
	TAD SLOC
	TAD S400
	DCA SLOC
	TAD S400
	CLL CIA CML
	TAD SBLKCT
	SZL SNA		/WORD COUNT EXHAUSTED?
	JMP .+3		/YES
	DCA SBLKCT
	JMP SLOOP
S7600,	7600
SRTRN,	ISZ SHNDLR
	ISZ SHNDLR
SFIELD,	HLT
	JMP I SHNDLR


SERROR,	ISZ SYSCNT
	JMP .+3		/TRY AGAIN!
	CLA CLL CML RAR	/DON'T BOTHER..YOU LOSE
	JMP SRTRN+1
	DCLA		/SEEK TRACK 0
	DSKC
	JMP .-1
	JMP SLOOP	/AND RETRY

SLOC,	0
SBLKCT,	0
SYSCNT,	0
SDLDR,	DLDR
SFUN,	0
SCIF,	CIF CDF 0
SREC,	0
S400,	400

	HLT
	HLT
	HLT
	HLT
	HLT
	HLT
	HLT
	HLT
	HLT
	HLT
	HLT
	HLT
	HLT
	HLT
	HLT
	HLT
	HLT
	HLT
	HLT