DCLA=6751
	DLDR=6733
	DLDC=6732
	DRDS=6741
	DRWC=6752
	DCLS=6742
	DSKC=6745
	DLWC=6753
	DSKE=6747
	DLCA=6755



	RDCC=6402
	RDSF=6401
	RDRS=6404
	RDRB=6406
	WTSF=6411
	WTLS=6416



*4000
NOPUNCH
*7607
ENPUNCH



SHNDLR,	0
	CLA CLL CMA RTL
	DCA SYSCNT	/NO. ERROR TRIES
	TAD I SHNDLR
	DCA SFUN	/FUNCTION WORD
	ISZ SHNDLR
	CLA CMA
	TAD I SHNDLR
	DCA SLOC	/BUFFER ADDRESS-1
	ISZ SHNDLR
STRY,	TAD I SHNDLR
	DCA SREC
	TAD SFUN
	RAL
	AND S7600
	DCA SBLKCT	/WORD COUNT
	RTL
	TAD SDLDR
	DCA SINST	/SINST=6733 (READ) OR 6735 WRITE
SLOOP,	TAD SLOC
	DLCA		/LOAD CURRENT ADDRESS
	TAD SBLKCT
	TAD S7600	/FULL OR HALF RECORD READ?
	SZA CLA
	TAD S7600	/FULL..2 PAGES
	TAD S7600	/HALF..1 PAGE
	DLWC		/WORD COUNT
	DCLS		/CLEAR ALL FLAGS
	TAD SFUN
	AND S70
	DLDC		/LOAD DATA FIELD OF BUFFER
	TAD SREC
SAVE,
SINST,	0		/READ OR WRITE IOT
	DSKC
	JMP .-1
SNEXT,	DSKE		/DONE..IS ERROR FLAG UP?
	JMP NOERR

SERROR,	ISZ SYSCNT
	JMP SLOOP	/TRY AGAIN
	CLA CLL CML RAR	/DON'T BOTHER..YOU LOSE
	JMP SRTRN+1

NOERR,	ISZ SREC	/NO..BUMP RECORD NO.
S70,	70
	DRCA
	DCA SLOC
	TAD S7600
	CLL RAL
	TAD SBLKCT
	SZL SNA		/WORD COUNT EXHAUSTED?
	JMP .+3		/YES
	DCA SBLKCT
	JMP SLOOP
S7600,	7600
SRTRN,	ISZ SHNDLR
	ISZ SHNDLR
	JMS FELDSR
	JMP I SHNDLR





KRBSR,	0
	CLA RAL
	DCA LINK
	RDF
	TAD SCIF
	DCA RETFLD
ROUND,
INS1,	KSF
	JMP .-1
INS5,	KRS
	TAD S7600
	CIF 10
	SNA CLA
	JMP 7705
	TAD LINK
	CLL RAR
INS2,	KRB
RETFLD,	0
	JMP I KRBSR



SYSCNT,
FELDSR,	0
	DCA SAVE
	RDF
	TAD SCIF
	DCA RTFLD2
SCIF,	CIF CDF 0
	TAD I FELDSR
	DCA .+3
	TAD SAVE
SBLKCT,
RTFLD2,	0
SLOC,	0



SREC,	0
LINK,
EAEMOD,	0
MQSAV,	0
	HLT
	HLT
	HLT
	HLT

NOPUNCH
*.+3
ENPUNCH

SDLDR,	DLDR

SFUN,
KSFSR,	0
INS6,	KSF
	SKP
	ISZ KSFSR
	JMS FELDSR
	JMP I KSFSR
FIELD 1

*0



TCHAR=JMS SRTCH
TOCT=JMS SRTOCT
RCHAR=JMS SRRCH
RTCHAR=JMS SRRTCH
TDC=JMS SRTDC
CHECK=JMS SRCH
CHBLOK=JMS SRCHBK
CHOCT=JMS SRCHOC
ROCT=JMS SRROCT
CHKCHN=JMS SRCKCN




SRCHBK, 0               /SKIP IF NOT IN BLOCK
        DCA TEMP        /SAVE AC
        TAD I SRCHBK
        ISZ SRCHBK
        CIA
        TAD TEMP
        SPA
        JMP NO
        CMA
        TAD I SRCHBK
        SPA
NO,     ISZ SRCHBK
        ISZ SRCHBK
	CLA
        TAD TEMP        /RESTORE AC
        JMP I SRCHBK



	JMP START	/DO NOT MOVE. ENTRY FROM USR AREA


TEM,
SRTOCT, 0       /TYPE OCTAL
	RAL
	DCA TEMPB
	TAD M4
        DCA TEMP
NEXTO,	TAD TEMPB
	RAL
	RTL
	DCA TEMPB
	TAD TEMPB
	AND MASK
        TAD P260
        TCHAR
	CLA
        ISZ TEMP
        JMP NEXTO
        JMP I SRTOCT


DESTIN,
SRRCH,  0               /READ A CHARACTER
INS7,	KSF
        JMP .-1
INS8,	KRB
        JMP I SRRCH

CKCNCT,
SRTCH,  0               /TYPE A CHARACTER
INS9,	TSF
        JMP .-1
INS10,	TLS
        JMP I SRTCH

TEMPB,
SRRTCH, 0               /READ AND TYPE A CHARACTER
        RCHAR
        TCHAR
        JMP I SRRTCH

ORIGIN,
TEMPA,
SRTDC,  0               /TYPE DIAGNOSTIC SYMBOL
	CLA
TDCLP,	TAD I SRTDC
        ISZ SRTDC
        TCHAR
	SPA CLA
	JMP TDCLP
        JMP I SRTDC





SRCH,   0       /CHECK AND SKIP IF WRONG
        DCA TEMP        /SAVE AC
        TAD I SRCH
        ISZ SRCH
        CIA
        TAD TEMP
        SZA CLA
        ISZ SRCH
        TAD TEMP        /RESTORE AC
        JMP I SRCH


TEMPC,
SRCHOC, 0               /SKIP IF OCTAL DIGIT
        CHBLOK
P260,	260
        10
        ISZ SRCHOC
        JMP I SRCHOC

SRROCT, 0               /READ AND TYPE OCTAL NUM
        CHOCT           /1ST. CHAR. IN AC. ON ENTRY
NOWHER,	HLT
        AND MASK	/% USED WITH NOWHERE TO GO
        DCA TEMP
        TAD M4
        DCA TEMPA
        DCA OCNUM
ROCTA,  TAD OCNUM
        RAL CLL
        RTL
        TAD TEMP
        DCA OCNUM
        RTCOMD
        CHOCT
        JMP I SRROCT    /EXIT ON NON-OCT CHAR.
	ISZ TEMPA
	SKP
	JMP I SRROCT
	AND MASK
	DCA TEMP
	JMP ROCTA

M4,     -4
MASK,   0007
OCNUM,	0


TEMP,
SRCKCN, 0       /CHECK CHAIN OF TAGS
        DCA TEM
        TAD I SRCKCN
        CIA
        DCA CKCNCT
CHCNLP, ISZ SRCKCN
        TAD I SRCKCN
        CIA
        TAD TEM
        ISZ SRCKCN
        SNA CLA
        JMP CHKADD
        ISZ CKCNCT
        JMP CHCNLP
        TAD TEM
	ISZ SRCKCN
        JMP I SRCKCN
CHKADD, TAD I SRCKCN
        DCA CKCNCT
        JMP I CKCNCT

*200


START,	KCC
	RDCC
	TLS
	LDY
	CDF 0
	CLA SWP
	DCA I MQSAVI
	DPSZ
	CLA CLL CML RAR
	TAD I EAEMDI
	DCA I EAEMDI
	CDF 10
CART,	TDC
	4215
	4212
	272
	RTCHAR
	CHKCHN
	4
	215
	CART
	"R
	RETURN
	"X
	SWAP
	203	/CONTROL C
	CONTRC
	TDC
	"?
	JMP CART

CONTRC,	TAD N7600
	JMP CNCRET

RETURN,	TAD ROUNDI
CNCRET,	DCA 7700
	TAD N6203
	DCA I N7736
	TDC
	4215
	212
	SWBA
	CDF 0
	TAD I EAEMDI
	RAR CLL
	SNA CLA
	SWAB
	RAL
	DCA I EAEMDI
	TAD I MQSAVI
	CDF 10
	MQL
	JMP 7730


ROUNDI,	ROUND
N7736,	7736

SWAP,	CIF 0
	JMS I SYSHN3
	4210
	1600
	65
	HLT


	CIF 0
	JMS I SYSHN3
	110
	2000
	64
	HLT

	JMP I USRCLI

SYSHN3,	SHNDLR
USRCLI,	USRCAL
N6203,	CDF CIF 0
EAEMDI,	EAEMOD
MQSAVI,	MQSAV

PAGE


AREPLA,	0
	CIF 0
	JMS I SYSHNI
	210
	1600
	65
	HLT

	JMP I AREPLA


SYSHNI,	SHNDLR



USRRET,	TAD ARG11
	DCA TEMBLK

	JMS AREPLA


	JMS TRNSFR
	0	/INCLUDE TOP PAGES
	JMP CART


N7600,
MAKSWP,	7600
	TAD ARG41
	DCA TEMBLK
	JMS AREPLA

	JMS TRNSFR
	1	/EXCLUDE TOP PAGES
	TAD N7600
	CDF 0
	DCA I KRBSRA
	TAD C6203
	DCA I RTFLDA
	CDF 10

	JMP CART


KRBSRA,	KRBSR
C6203,	6203
RTFLDA,	RETFLD



KTRANS,	0
	CIF 0
	JMS SYS
	410
N1000A,	1000
SWPBK3,	0
	HLT

	TAD SWPBK3
	DCA SWPBK4

	CIF 0
	JMS SYS
TR1,	4410
CORAD1,	2000
SWPBK4,	0
	HLT

	TAD CORAD1
	DCA COPYAD
	TAD N1000A
	TAD CORAD1
	DCA CORAD1
	CLA CLL IAC RAL
	TAD SWPBK3
	DCA SWPBK3
	ISZ COUNT
	SKP
	JMP I KTRANS

	JMS MOVE
	1000
	CDF 10
COPYAD,	0
TR2,	CDF 10
	1000

	ISZ COUNT
	JMP KTRANS+1
	JMP I KTRANS

NOSWAP, TDC
        4240
        4316
        317
        JMS AREPLA
        JMP CART


MOVE,	0
	CLA
	TAD NDCADS
	DCA MINST
	TAD I MOVE
	DCA ORIGIN
	ISZ MOVE
	TAD I MOVE
	DCA FLDIN
	ISZ MOVE
	TAD I MOVE
	DCA DESTIN
	ISZ MOVE
	TAD I MOVE
	DCA FLDOUT
	ISZ MOVE
	TAD I MOVE
	CIA
	DCA COUNTM
	ISZ MOVE

MOVELP,	TAD I DESTIN
	DCA TEM
FLDIN,	CDF 10
	TAD I ORIGIN
FLDOUT,	CDF 10
MINST,	DCA I DESTIN
	CDF 10
	ISZ ORIGIN
	ISZ DESTIN
	ISZ COUNTM
	JMP MOVELP
	JMP I MOVE

INSMV,	0
	CLA
	TAD NDCATM
	DCA MINST
	TAD INSMV
	DCA MOVE
	JMP MOVE+4

COUNTM,	0
NDCADS,	DCA I DESTIN
NDCATM,	DCA I TEM



OUTER,

PAGE
*1000

NOPUNCH
*2000
ENPUNCH

BREPLA,	0
	CIF 0
	JMS I SYSHN2
	1010
	0
	66
	HLT
	JMP I BREPLA

T3WYIN,	0
	TAD ARG51
	TAD N12
	DCA I SWBLKI
	TAD I SWBLKI
	DCA I SWBK2I
	TAD I T3WYIN
	DCA BREPLA
	TAD I BREPLA
	ISZ T3WYIN
	TAD N40
	DCA I SCRC1I
	ISZ NOMOST
	SKP CLA
	JMP I T3WYIN
	TAD I SCRC1I
	DCA I SCRC2I
	TAD NM22
	DCA I COUNTI
	JMS I T3WAYI
	JMP I T3WYIN

USRCAL,	TAD I N7760	/CHECK IF FILE OPEN ON SYS
	AND N7
	SZA CLA
	JMP I NOSWPI
	TAD I N7761	/CHECK DEV DISK
	AND N7
	SZA CLA
	JMP I NOSWPI


	CIF 0
	JMS I SYSHN2
	1010
	0
	27
	HLT

	CLA CLL CMA RAL
	DCA NOMOST
	CLA IAC
	JMS I N7700
	2		/LOOK UP
ARG51,	NAME2
	0
	ISZ NOMOST

	CLA IAC
	JMS I N7700
	2	/LOOKUP
ARG11,	NAME1
	0
	JMP NOTFND


	JMS BREPLA
	JMS T3WYIN
	ARG11
	JMP I USRETI

NOTFND,	TAD VAL4
	JMS I N7700
	3	/ENTER SWAP.X
ARG41,	NAME1
	0
	JMP NOSWOT

	CLA IAC
	JMS I N7700
	4	/CLOSE SWAP.X
	NAME1
	62
	HLT

	JMS BREPLA
	JMS T3WYIN
	ARG41
	JMP I MKSWPI

NOSWOT,	JMS BREPLA
	JMP I NOSWPI


NAME1,	FILENAME SWAP.X
NAME2,	FILENAME MOSTOV.SV



SYSHN2,	SHNDLR
N7,	7
N7760,	7760
N7761,	7761
N7700,	7700
VAL4,	1441
USRETI,	USRRET
MKSWPI,	MAKSWP
NOSWPI,	NOSWAP
N40,	40
N12,	12
NM22,	-22
NOMOST,	0
SWBLKI,	SWPBLK
SWBK2I,	SWPBK2
SCRC1I,	SCRTC1
SCRC2I,	SCRTC2
T3WAYI,	T3WAY
COUNTI,	COUNT



*OUTER

PAGE


TRNSFR,	0
	TAD N27
	DCA SCRTC1
	TAD N27
	DCA SCRTC2
	TAD SWPBLK
	DCA SWPBK2
	TAD NM4
	DCA COUNT
	TAD TEMBLK
	DCA SWPBLK
	JMS T3WAY

	TAD SWPBLK
	DCA SWPBK3
	TAD N4410
	DCA TR1
	TAD NCDF10
	DCA TR2
	CLA CLL CML RTR
	DCA CORAD1
	TAD NM14
	TAD I TRNSFR
	DCA COUNT
	JMS KTRANS

	JMS MOVE
	1000
	CDF 10
	7000
	CDF 10
	600	/FIELD 1 DONE

	TAD N4400
	DCA TR1
	TAD NCDF0
	DCA TR2
	DCA CORAD1
	TAD NM17
	DCA COUNT
	JMS KTRANS

	JMS MOVE
N1000,	1000
NCDF10,	CDF 10
	7000
NCDF0,	CDF 0
	600

	TAD I TRNSFR
	ISZ TRNSFR
	SZA CLA
	JMP I TRNSFR

	JMS MOVE
	1700
	CDF 10
	7700
	CDF 0
	100
	JMP I TRNSFR

T3WAY,	0
FRSTLP,	CIF 0
	JMS SYS
	210
	1000
SCRTC1,	27
	HLT
	CIF 0
	JMS SYS
	210
	1400
SWPBLK,	0
	HLT

	CIF 0
	JMS SYS
	4210
	1000
SWPBK2,	0
	HLT
	CIF 0
	JMS SYS
	4210
	1400
SCRTC2,	27
	HLT


	ISZ SCRTC1
	ISZ SCRTC2
	ISZ SWPBLK
	ISZ SWPBK2
	ISZ COUNT
	JMP FRSTLP
	JMP I T3WAY



N27,	27
SYS=7607
NM4,	-4
N4410,	4410
NM14,	-14
N4400,	4400
NM17,	-17
COUNT,	0
TEMBLK,	0