4 REMARKABLY TRANSLATED TO OS8 BASIC BY KAY R. FISHER ...DEC
5 RANDOMIZE
10 PRINT "SOMEWHERE ABOVE YOUR PLANET IS A ROMULAN SHIP."
15 PRINT
20 PRINT "THIS SHIP IS IN A CONSTANT POLAR ORBIT. IT'S"
25 PRINT "DISTANCE FROM THE CENTER OF YOUR PLANET IS FROM"
30 PRINT "10,000 TO 30,000 MILES AND AT IT'S PRESENT VELOCITY CAN"
31 PRINT "CIRCLE YOUR PLANET ONCE EVERY 12 TO 36 HOURS."
35 PRINT
40 PRINT "UNFORTUNATELY THEY ARE USING A CLOAKING DEVICE SO"
45 PRINT "YOU ARE UNABLE TO SEE THEM, BUT WITH A SPECIAL "
50 PRINT "INSTRUMENT YOU CAN TELL HOW NEAR THEIR SHIP YOUR"
55 PRINT "PHOTON BOMB EXPLODED. YOU HAVE SEVEN HOURS UNTIL THEY"
60 PRINT "HAVE BUILT UP SUFFICIENT POWER IN ORDER TO ESCAPE "
65 PRINT "YOUR PLANET'S GRAVITY."
70 PRINT
75 PRINT "YOUR PLANET HAS ENOUGH POWER TO FIRE ONE BOMB AN HOUR."
80 PRINT
85 PRINT "AT THE BEGINNING OF EACH HOUR YOU WILL BE ASKED TO GIVE AN"
90 PRINT "ANGLE (BETWEEN 0 AND 360) AND A DISTANCE IN UNITS OF"
95 PRINT "100 MILES (BETWEEN 100 AND 300), AFTERWHICH YOUR BOMB'S"
100 PRINT "DISTANCE FROM THE ENEMY SHIP WILL BE GIVEN."
105 PRINT
110 PRINT "AN EXPLOSION WITHIN 5,000 MILES OF THE ROMULAN SHIP"
111 PRINT "WILL DESTROY IT."
114 PRINT 
115 PRINT "BELOW IS A DIAGRAM TO HELP YOU VISUALIZE YOUR PLIGHT."
116 PRINT
117 PRINT
168 PRINT "                          90"
169 PRINT "                          ^"
170 PRINT "                    OOOOOOOOOOOOO"
171 PRINT "                 OOOOOOOOOOOOOOOOOOO"
172 PRINT "               OOOOOO           OOOOOO"
173 PRINT "             OOOOO                 OOOOO"
174 PRINT "            OOOOO     XXXXXXXXXXX    OOOOO"
175 PRINT "           OOOOO    XXXXXXXXXXXXXXX    OOOO"
176 PRINT "          OOOO     XXXXXXXXXXXXXXXXX    OOOO"
177 PRINT "         OOOO     XXXXXXXXXXXXXXXXXXX    OOOO"
178 PRINT "        OOOO     XXXXXXXXXXXXXXXXXXXXX    OOOO"
179 PRINT "180<== OOOOO     XXXXXXXXXXXXXXXXXXXXX    OOOOO ==>0"
180 PRINT "        OOOO     XXXXXXXXXXXXXXXXXXXXX    OOOO"
181 PRINT "         OOOO     XXXXXXXXXXXXXXXXXXX    OOOO"
182 PRINT "          OOOO     XXXXXXXXXXXXXXXXX    OOOO"
183 PRINT "           OOOOO    XXXXXXXXXXXXXXX   OOOOO"
184 PRINT "            OOOOO    XXXXXXXXXXXXX   OOOOO"
185 PRINT "             OOOOO                  OOOOO"
186 PRINT "               OOOOOO             OOOOOO"
187 PRINT "                 OOOOOOOOOOOOOOOOOOOO"
188 PRINT "                    OOOOOOOOOOOOOOO"
189 PRINT "                           !"
190 PRINT "                          270"
191 PRINT
192 PRINT
195 PRINT "X - YOUR PLANET"
196 PRINT "O - THE ORBIT OF THE ROMULAN SHIP"
197 PRINT
198 PRINT "ON THE ABOVE DIAGRAM, THE ROMULAN SHIP IS CIRCLING"
199 PRINT "COUNTERCLOCKWISE AROUND YOUR PLANET. DON'T FORGET"
200 PRINT "WITHOUT SUFFICIENT POWER THE ROMULAN SHIP'S ALTITUDE"
201 PRINT "AND ORBITAL RATE WILL REMAIN CONSTANT."
203 PRINT 
204 PRINT "GOOD LUCK. THE FEDERATION IS COUNTING ON YOU."
270 LET A=INT(RND(0)*360)
280 D=INT(RND(0)*200)+100
290 R=INT(RND(0)*20)+10
300 H=0
310 IF H=7 GOTO 490
320 H=H+1
325 PRINT
326 PRINT
330 PRINT "HOUR";H;", AT WHAT ANGLE DO YOU WISH TO SEND"
335 PRINT "YOUR PHOTON BOMB";
340 INPUT A1
350 PRINT "HOW FAR OUT DO YOU WISH TO DETONATE IT";
360 INPUT D1
365 PRINT
366 PRINT
370 A=A+R
380 IF A<360 GOTO 400
390 A=A-360
400 T=ABS(A-A1)
410 IF T<180 GOTO 430
420 T=360-T
430 C=SQR(D*D+D1*D1-2*D*D1*COS(T*3.14159/180))
440 PRINT "YOUR PHOTON BOMB EXPLODED";C;"*10^2 MILES FROM THE"
445 PRINT "THE ROMULAN SHIP"
450 IF C<=50 GOTO 470 
460 GOTO 310
470 PRINT "YOU HAVE SUCCESSFULLY COMPLETED YOUR MISSION."
480 GOTO 500
490 PRINT "YOU HAVE ALLOWED THE ROMULAN TO ESCAPE."
500 PRINT "ANOTHER ROMULAN SHIP HAS GONE INTO ORBIT."
510 PRINT "DO YOU WISH TO TRY TO DESTROY IT";
520 INPUT C$
530 IF C$="YES" GOTO 270
999 END