CLEAR=JMS I 43
SET=JMS I 44
REFRSH=JMS I 45

RF=2
CL=40
TG=100
RW=20
TR=1000
MUX=4
WE=10
FQ=200
CS=400
DI=1
FE=2000

*40
RAMLIC,	0
RABIC,	0
RAMFEP,	0
SRCLR
SRSET
SRFRSH


*1000


RAMSTR,	LINE
	TDC		/OLD OR NEW(O OR N)
	4317
	4314
	4304
	4240
	4317
	4322
	4240
	4316
	4305
	327
	LINE

	RTCHAR
	CHECK
	317
	JMP RAMALT






/EINLESEN VON SETBACK M UND N (ZEILEN U. SPALTEN)
/EINLESEN VON DELAY (LOW A. HIGH)
/EINLESEN VOM BITMUSTER UND AUSDRUCK

RAMNEU,	CLA
	TAD SETBN
	CIA
	IAC
	DCA RAMTRN
	TAD SETBM
	CIA
	IAC
	DCA RAMTRM

RAMBIT,	LINE		/BITMUSTER:
	TDC
	4302
	4311
	4324
	4315
	4325
	4323
	4324
	4305
	322
	LINE

RAMIN,	CLA		/EINLESEN DES BITMUSTERS
	TAD RABIP
	DCA RABIC
	TAD RAMMN4
	DCA RAMCTN
	TAD RAMMN4
	DCA RAMCTM

RAMRED,	RCHAR
	TAD RMN260
	DCA I RABIC
	TAD I RABIC
	TAD RN260
	TCHAR
	ISZ RABIC
	ISZ RAMCTN
	JMP RAMRED

	LINE
	TAD RAMMN4
	DCA RAMCTN
	ISZ RAMCTM
	JMP RAMRED

	LINE
	LINE






/INITALISIERUNG UND UEBERSCHRIFT

RAMALT,	TLS
	CLA IAC
	DCA RAMFLG
	TAD RABIP
	DCA RABIC
	TAD RAMN16
	DCA RAMCTR
	TAD RAMLIP
	DCA RAMLIC
	DCA I RAMLIC
	ISZ RAMLIC
	ISZ RAMCTR
	JMP .-3

	TAD RAMFEL
	DCA RAMFEP
	TAD RAMN16
	DCA LPCNT
	DCA RAMFEC
	DCA RAMST1


	LINE		/UEBERSCHRIFT
	TDC
	4322
	4301
	4315
	4240
	4316
	4322
	4272
	240

	RTCHAR		/WRITE COMMENT
	CHECK
	212		/END OF COMMENT
	SKP
	JMP .-4

	LINE
	JMS SURE

	RCHAR
	CHECK
	331
	JMP RAMAIN
	JMP RAMSTR


RMN260,	-260
RN260,	260
RAMN16,	-20
RAMCTR,	0
SETBN,	0
SETBM,	0



PAGE






/INITIALISIERUNG DES CLOCK ENABLE REGISTERS




RAMAIN,	CLA CMA
	CLZE	
	CLA
	TAD BUFFER
	CIA
	CLAB
	CLA
	TAD ENABLE		/ENABLE REAL TIME CLOCK
	CLOE



/INITAIALISIERUNG DER STEUERSIGNALE



	JMS RAMINI

	CLA IAC RAL
	CIA
	DCA DURFLG


/ADRESSEN BERECHNEN



	JMS RAMCOR
RAMST1,	0



/ZWISCHENSPEICHER EINSCHREIBEN




DURCH1,	JMS SENZSP




/EINSCHREIBEN IN DAS 4KRAM




	JMS RAMINP





/AUSLESEN AUS DEM 4KRAM



	JMS RAMOUT
	JMP I .+1
	NEXTPA


PAGE






/FEHLERERKENNUNG: VERGLEICH ZWISCHEN EINGELESENEM UND
/AUSGELESENEM BITMUSTER


NEXTPA,	SET
	TG

RAMFIN,	6504			/F EINLESEN
	AND M2000
	SNA CLA
	JMP RAMOKY		/KEIN FEHLER

	NOP

	6514
	CMA
	DCA I RAMFEP
	ISZ RAMFEP

	NOP

	6524
	CMA
	DCA I RAMFEP
	ISZ RAMFEP

	ISZ RAMFEC
	TAD RAMFEC
	DCA FELZAL
	TAD FELZAL
	TAD MN200

	NOP

	SNA CLA
	JMP RAMDEF

	6504
	SPA CLA
	JMP TSTEND

	SET
	FQ
	CLEAR
	FQ
	JMP RAMFIN

RAMOKY,	NOP

	6504
	SMA CLA
	JMP RAMFIN





/4KRAM GETESTET

TSTEND,	SET
	FQ

	CLEAR
	FQ

	CLEAR
	FE

	ISZ DURFLG
	JMP DURCH1

	CLA
	TAD RAMST1
	IAC

	NOP

	SZA CLA
	JMP RAMAIN
	JMP I .+1
	FEHLIS

DURFLG,	0
PAGE




/AUSDRUCK DER FEHLER UND FEHLERHAFTEN ADRESSEN


FEHLIS,	LINE

	TDC		/FEHLERANZAHL
	4306
	4305
	4310
	4314
	4305
	4322
	4301
	4316
	4332
	4301
	4310
	4314
	240
	CIF 20

	JMS DEZOUT	/AUSDRUCK DEZIMAL FEHLERANZAHL
	RAMFEC
	STELE4

	LINE

	TAD RAMFEC
	SNA
	JMP RAMSTR


	TDC		/AUSDRUCK???
	4301
	4325
	4323
	4304
	4322
	4325
	4303
	4313
	4277
	4277
	277

	CLA
	RTCHAR
	CHECK
	331		/YES
	SKP
	JMP RAMSTR


	LINE
	CLA
	TAD RAMFEC
	CIA
	DCA RAMFEC
	TAD RAMFEL
	DCA RAMFEP

FELPRT,	TDC
	4323
	4320
	4301
	4314
	4324
	4305
	4240
	4240
	4332
	4305
	4311
	4314
	4305
	4240
	4322
	4301
	315

	LINE

FELLP,	TAD I RAMFEP

	JMS GETZS
	SPALTE
	ZEILE

	CIF 20

	JMS DEZOUT	/AUSDRUCK DEZIMAL SPALTE
	SPALTE
	STELE1

	CIF 20

	JMS DEZOUT	/AUSDRUCK DEZIMAL ZEILE
	ZEILE
	STELE2

NRPRT,	ISZ RAMFEP

	CLA
	TAD MN12
	DCA RAMC12
	DCA RAMNR
RAM12,	TAD I RAMFEP
	RAL
	DCA I RAMFEP
	ISZ RAMNR
	SNL
	JMP RAMNOT

	CIF 20
	JMS DEZOUT	/AUSDRUCK DEZIMAL RAM NR
	RAMNR
	STELE3


RAMNOT,	ISZ RAMC12
	JMP RAM12

	LINE
	ISZ RAMFEP
	ISZ RAMFEC
	JMP FELLP

	JMP RAMSTR






MN200,	-200
M2000,	2000
RAMFEC,	0;0
STELE1,	7	/STELLENANZAHL ZEILE
STELE2,	10	/    "     SPALTE
STELE3,	5	/    "      RAM NR
STELE4,	7	/    "         FEHLERCOUNTER
RAMNR,	0;0
RAMC12,	0
MN12,	-14
SPALTE,	0;0
ZEILE,	0;0


PAGE


/RAM DEFEKT

RAMDEF,	LINE
	TDC		/MEHR ALS 177 FEHLER
	4322
	4301
	4315
	4240
	4304
	4305
	306
	LINE
	CLA
	TAD RAMFEL
	DCA RAMFEP

	CMA
	DCA RAMFEC
	JMP NRPRT


PAGE



/CALL  RAMINI
/INITIALISIERUNG DER STEUERSIGNALE UND COUNTER


RAMINI,	0
	SET	
	CS FQ CL RW WE MUX RF 
	CLEAR
	CL TG FQ FE TR
	SET
	CL

	SWAB
	CLA
	TAD RAMMN4
	DCA RAMCTN
	TAD RAMMN4
	DCA RAMCTM
	TAD RAMLIP
	DCA RAMLIC
	TAD RAMN16
	DCA LPCNT
	TAD RABIP
	DCA RABIC
	JMP I RAMINI

/CALL RAMZSP
/ZWISCHENSPEICHER EINSCHREIBEN

RAMZSP,	0
RAMLOP,	CLEAR
	TR
	CLA
	TAD I RAMLIC		/ADRESSEN EINSCHREIBEN
	6516
	CMA
	6515

	CLEAR
	DI

	CLA
	TAD I RABIC
	6505
	ISZ RAMLIC
	ISZ RABIC


	CLEAR
	CS
	CLEAR
	WE
	SET
	CS
	SET
	WE
	SET
	TR
	ISZ LPCNT
	JMP RAMLOP

/HARDWARE TEST

	6504
	SMA			/ZWISCHENSPEICER VOLL
	MOSTGO
	CLA

	NOP

	JMP I RAMZSP




/CALL SENZSP
/ZWISCHENSPEICHER EINSCHREIBEN ADRESSE 0;ADRESSE O NICT


SENZSP,	0
SENLOP,	CLA
	TAD SENMN2
	DCA SEDGCT
	CLEAR
	TR
	CLA
	TAD I RAMLIC
ADRQER,	6516
	CMA
	6515

	CLEAR
	DI
	CLA
	TAD I RABIC
	6505
	ISZ RABIC

	CLEAR 
	CS
	CLEAR
	WE
	SET
	CS
	SET
	WE
	SET
	TR
	ISZ LPCNT
	SKP
	JMP HADWAR
	CLEAR
	TR
	CLA
	TAD I RAMLIC
	CMA
	ISZ RAMLIC
	ISZ SEDGCT
	JMP ADRQER
	JMP SENLOP

/HARDWARE TEST

HADWAR,	6504
	SMA			/ZWISCHENSPEICHER VOLL
	MOSTGO
	CLA
	JMP I SENZSP
SEDGCT,	0
SENMN2,	-2

PAGE





/CALL RAMINP
/EINSCHREIBEN IN DAS 4KRAM MIT PROGRAMMIERBAREM DELAY

RAMIND,	0
	SWAB
	CAM DAD
	RAMDLY
	DCM
	DST
	RAMDLC
RAMLP,	CLEAR	
	CL RW MUX
	CLEAR
	CS
	SET
	CL
	SET
	TG

	NOP

	6504
	SMA			/16 BIT INS 4KRAM EINGELESEN?
	JMP .-2

	ISZ RAMDLC
	SKP
	ISZ RAMDLC+1
	JMP RAMLP

	JMP I RAMIND




/CALL RAMINP
/EINSCHREIBEN IN DAS 4KRAM


RAMINP,	0
	CLEAR
	CL RW MUX
	CLEAR
	CS
	SET
	CL
	SET
	TG

	6504
	SMA
	JMP .-2		/16 BIT INS 4KRAM EINGELESEN
	JMP I RAMINP





/CALL RAMOUT
/AUSLESEN AUS DEM 4KRAM

RAMOUT,	0
	CLEAR
	TG CL
	SET
	RW CL
	SET
	FQ
	CLEAR
	FQ
	SET
	FE
	JMP I RAMOUT

LPCNT,	0
ENABLE,	5600
BUFFER,	3720
RAMDLY,	0;0
RAMDLC,	0;0



PAGE



			/SUBROUTINE ZUR BERECHNUNG DER ADRESSEN
			/1.ARG: STAND DER LETZTEN BERECHNETEN ADRESSE




RAMCOR,	0	
	CAM
	TAD I RAMCOR
	DCA RAMOLD
	TAD RAMFLG
	SZA CLA		/FALL1: WENN AC=/0;DANN 1.DURCHGANG
	JMP RAMIAC

	NOP

	TAD RAMOLD
	AND RM77
	TAD RAMN77	/FALL2:WENN AC=0;DANN 63 ZEILEN
	SNA CLA
	JMP RAMNEW

	NOP

	TAD RAMOLD
	BSW
	TAD RAMMN3	/ALTES M-4 BEIBEHALTEN
	BSW
	TAD RAMTRN	/VERSCHIEBUNG VON N
	JMP RAMIAC

RAMNEW,	NOP

	TAD RAMOLD
	BSW
	TAD RAMTRM	/VERSCHIEBUNG VON M
	BSW
	AND RM7700	/N=0

RAMIAC,	NOP

	MQL
	TAD RAMLIP
	DCA RAMLIC
RAMHGN,	MQA

RAMHG,	NOP

	DCA I RAMLIC
	TAD I RAMLIC
	IAC
	ISZ RAMLIC
	ISZ RAMCTN
	JMP RAMHG

	NOP

	CLA
	TAD RAMMN4
	DCA RAMCTN
	DCA RAMFLG
	MQA
	BSW
	IAC
	BSW
	MQL
	ISZ RAMCTM
	JMP RAMHGN

	NOP

	CLA
	TAD RAMMN4
	DCA RAMCTM
	CMA
	TAD RAMLIC
	DCA RAMLIC

	NOP

	TAD I RAMLIC
	DCA I RAMCOR
	ISZ RAMCOR

	TAD RAMLIP
	DCA RAMLIC
	JMP I RAMCOR
RAMOLD,	0
RAMFLG,	0
RM77,	77
RAMN77,	-77
RAMMN3,	-3
RAMMN4,	-4
RAMTRN,	0
RAMTRM,	0
RM7700,	7700
RAMLIP,	RAMLIS
RAMLIS,	ZBLOCK 20
RAMCTN,	0
RAMCTM,	0
RABIP,	RABILI
RABILI,	ZBLOCK 20
FELZAL,	0

PAGE






				/SUBROUTINE REFRESH
SRFRSH,	0
	DCA SAVEAC
	MQA
	DCA SAVEMQ
	CLSA
	CLA
	TAD Z40
	DCA RECTR
	CMA
	AND N2
	6506
	ISZ RECTR
	JMP .-1
	6505
	CLA
	TAD SAVEMQ
	MQL
	TAD SAVEAC
	JMP I SRFRSH

				/SUBROUTINE LOESCHEN D. CONTROLSIGNALS

SRCLR,	0
	CLA
	TAD I SRCLR
	6506
	ISZ SRCLR

	CLA

	JMP I SRCLR




				/SUBROUTINE SETZEN D. CONTROLSIGNALS

SRSET,	0
	CLA
	TAD I SRSET
	6505
	ISZ SRSET

	CLA

	JMP I SRSET

SURE,	0		/ARE YOU SURE
	TDC
	4301
	4322
	4305
	4240
	4331
	4317
	4325
	4240
	4323
	4325
	4322
	305
	JMP I SURE


/GET NUMBER IN AC
/JMS GETZS
/ZEILENADRESS
/SPALTENADRESS

GETZS,	0
	DCA GETTEM
	TAD I GETZS
	DCA GETP1
	ISZ GETZS

	TAD I GETZS
	DCA GETP2
	ISZ GETZS

	SWAB
	TAD GETTEM
	LSR
	6
	DCA I GETP1
	ACL
	BSW
	DCA I GETP2
	JMP I GETZS

GETTEM,	0
GETP1,	0
GETP2,	0



SAVEAC,	0
SAVEMQ,	0
Z40,	-15
RECTR,	0
N2,	2


PAGE

RAMFEL,	RAMFEA
RAMFEA,	ZBLOCK 376








FIELD 2
*1000

ENTF=JMS I 7

/CIF 20
/JMS DEZOUT
/ADR. DER DOPPELGENAUEN ZAHL IN FELD 0
/ANZAHL ALLER STELLEN


DEZOUT,	0
	SWAB
	CLA

	RDF
	TAD CHFIED
	DCA EXIT1

	IAC
	DCA 56
	DCA 55
	TAD I DEZOUT
	DCA DEZP1
	ISZ DEZOUT

	TAD I DEZOUT
	DCA DEZTEM
	TAD I DEZTEM
	DCA 57
	ISZ DEZOUT
	DCA 60

	CAM DAD
DEZP1,	0
	CDF 20
	SWP
	DST
	45
	CLA
	TAD (27
	DCA 44

	ENTF
	FNOR
	FOUT
	FEXT

EXIT1,	0
	JMP I DEZOUT


DEZTEM,	0
CHFIED,	CDF CIF 0