Directory of image this file is from
This file as a plain text file

/*************************************************
/
/  ENDPRUEFSYSTEM - BHS-STUTTGART
/
/  INPUT/OUTPUT-ROUTINEN FUER ENDPRUEFAUTOMATEN
/
/*************************************************


/	SPECIAL AUTOMATION
/	WALDSTRASSE 9
/	8504 STEIN
/	TEL. 0911/678727
/
/	25. MAI 1977
/	F. WESSELY

*3000

/DEFINITIONEN

PATEST=1	/DEF. STAND-ALONE TESTPROGR.
VESPA=1		/AKTIVIERT SPA-VERS. VON STP1.PA
PAPNT=155	/POINTER IN PAGE 0

IFDEF PATEST <

BSW=7002
PASF=6141	/SKIP ON PA-FLAG
PFCL=6142	/CLEAR PA-FLAG
RD0=6143	/READ PA-NUMMER U. KONTAKTTYP
RD1=6144	/READ ANZUGSWERT
RD2=6145	/READ ABFALLWERT
RD3=6146	/READ WIDERSTAND U. WEICHENSTELLUNG
WR0=6140	/KONTAKTAUSWURF
WR1=6147	/WEICHENEINSTELLUNG
/PA-TESTPROGRAMM

PATST,	CLA CLL
	TLS
	PASF
	JMP .-1
	JMP PAINT	/PA-INPUT

/DUMP PA-TABELLE BEI PA-EXIT

PROTOK,	CLA CLL
	PFCL
	TAD PAXTAB
	DCA PAPNT
	TAD (-7
	DCA PACNT1
	TAD (215	/CR-LF
	JMS TYPE
	TAD (212
	JMS TYPE
	TAD I PAPNT	/WERT AUS TABELLE
	JMS PRNT	/AUSGEBEN
	TAD (240	/SPACE
	JMS TYPE
	ISZ PAPNT
	ISZ PACNT1	/FERTIG ?
	JMP .-6	/NEIN
	JMP PATST+2	/JA- NEXT INPUT
PACNT1,	0		/ZAEHLER

/PRINT OKTALZAHL

	0		/SCHLEIFENZAEHLER
	0		/ZW. SPEICHER
PRNT,	0
	DCA PRNT-1
	TAD (-4
	DCA PRNT-2
PLOP,	TAD PRNT-1	/ZIFFER FREISTELLEN
	RAR
	RTR
	BSW
	AND (7
	TAD (260	/UND DRUCKEN
	JMS TYPE
	TAD PRNT-1
	RAL		/NAECHSTE ZIFFER
	RTL
	DCA PRNT-1
	ISZ PRNT-2	/FERTIG ?
	JMP PLOP
	JMP I PRNT	/JA- RETURN

/TYPE CHARACTER

TYPE,	0
	TSF
	JMP .-1
	TLS
	CLA CLL
	JMP I TYPE

/DUMMY AUSWERTEPROGRAMM

INP0,	0		/SOLLKL. ZAEHLER
	NOP		/EINGANG IST INP0+2
	ISZ PAPNT	/AUF SOLLKLASSE
	ISZ INP0
	NOP		/SOLLKLASSE ERZEUGEN
	TAD INP0	/KLASSE 1-13 (OKT)
	TAD	(-14	/HOECHSTE KLASSE ?
	SPA CLA		/JA-UEBERSCHRITTEN,SKIP
	JMP .+3
	DCA INP0	/RESET KLASSE
	JMP .-7
	TAD INP0	/O.K.-
	DCA I PAPNT	/ABSPEICHERN
	JMP PAOX	/PA- OUTPUT EXIT
	>
	PAGE
/EINGANG NACH PA-INTERRUPT

PAINT,	CLA CLL
	RD0		/INP. AUTOMATENNR.
	AND	(17	/IGNORE KONTAKTTYP ETC.
	SNA		/PA-NR.=0 ?
	JMP	PAIX	/JA- ERROR
	RAL		/PA-NR*10
	RTL
	TAD	(PATAB-10
	DCA	PAXTAB	/TAB. ADR. PA-NR. X
	TAD	PAXTAB
	DCA	PAPNT	/POINTER AUF PA-STATUS
	TAD I	PAPNT	/STATUS IN AC
	SZA CLA		/IN- ODER OUTPUT ?
	JMP	PAWEKO	/OUTPUT

/MESSWERTINPUT UND VERGLEICH MIT LETZTEM TRANSFER

	ISZ	PAPNT	/ZEIGT AUF INP. ZAEHLER
	ISZ I	PAPNT	/INPUTS ZAEHLEN
	NOP
	JMS	PACHK	/INPUT PRUEFEN
	JMP 	INP0+2	/O.K. -AUSWERTEN
PAIX,	TAD	PAXTAB	/POINTER AUF SOLL-
	TAD	(6	/WEICHENSTELLUNG
	DCA	PAPNT	/STELLEN
	JMP	PAIXX	/INPUT WIEDERHOLEN

/WEICHENKONTROLLE NACH LEZTER EINSTELLUNG

PAWEKO,	TAD	PAXTAB	/POINTER AUF
	TAD	(6	/SOLL-WEICHENSTELLUNG
	DCA	PAPNT
	RD3		/READ WEICHENSTELLUNG
	RAL
	BSW
	AND	(17	/SONSTIGES IGNORIEREN
	CMA IAC		/VERGLEICH MIT SOLL
	TAD I	PAPNT
	SNA CLA	
	JMP	PAAUS	/GLEICH- AUSWURF


/AUSGANG AUS PA-BEARBEITUNG

PAOX,	ISZ I	PAXTAB	/WEICHENEINSTELLUNGEN
	NOP		/ZAEHLEN
PAIXX,	TAD I	PAPNT	/WEICHE AUF SOLLWERT
	WR1		/EINSTELLEN
PAX,	CLA CLL		/EXIT
IFDEF PATEST <
	JMP	PROTOK >
IFNDEF PATEST <
	IOF
	PFCL
	DCA	MPA	/INTERRUPTS FREIGEBEN
	JMS	3
	1		/PROGRAMM-ENDE
	>




/KONTAKTAUSWURF

PAAUS,	WR0		/KONTAKTAUSWURF
	TAD	(-6	/PA-TABELLE CLEAREN
	DCA	PACNT
	TAD	PAXTAB
	DCA	PAPNT
	DCA I	PAPNT
	ISZ	PAPNT
	ISZ	PACNT
	JMP .-3
	JMP	PAX	/EXIT

/INPUT PRUEFEN UND ABSPEICHERN

PACHK,	0
	TAD	(-4	/SCHLEIFENZAEHLER
	DCA	PACNT	/LADEN
	TAD	(RD0	/READ IOT LADEN
	DCA	PALOP+1
PALOP,	ISZ	PAPNT
	RD0		/READ REGISTER X
	CMA IAC		/VERGLEICH MIT
	TAD I	PAPNT	/LETZTEM INPUT
	SZA CLA		/GLEICH ?
	JMP	PASTOR	/NEIN !
	ISZ	PALOP+1
	ISZ	PACNT	/FERTIG ?
	JMP	PALOP	/NEIN,
	JMP I	PACHK	/JA, ALLES O.K. -EXIT

PASTOR,	TAD	PAXTAB	/POINTER ZUM ABSPEICHERN
	TAD	(2	/EINSTELLEN
	DCA	PAPNT
	TAD	(-4	/SCHLEIFENZAEHLER
	DCA	PACNT
	TAD	(RD0	/READ IOT
	DCA	PALOP2
PALOP2,	RD0
	DCA I	PAPNT	/ABSPEICHERN
	ISZ	PAPNT
	ISZ	PALOP2	/NEXT IOT
	ISZ	PACNT	/FERTIG ?
	JMP	PALOP2	/NEIN, WEITER
	ISZ	PACHK	/RETURN
	JMP I	PACHK

PAXTAB,	0	/ANFANGSADR, DER AKT. PA-TABELLE
PACNT,	0	/SCHLEIFENZAEHLER

	PAGE

/INPUT-OUTPUT-TABELLEN PRO AUTOMAT

PATAB,	0	/PA-STATUS
		/ =0 -INPUT-MODE
		/ GR.0 -OUTPUT-MODE
		/U. ANZAHL WEICHENEINSTELLUNGEN
	0	/ANZAHL INPUT-TRANSFERS
	0	/REGISTER 0, LETZTER INPUT
	0	/REGISTER 1	...
	0	/REGISTER 2	...
	0	/REGISTER 3	...
	11	/SOLL-WEICHENSTELLUNG
	0	/RESERVE
ZBLOCK 6	/PA 2
	11
ZBLOCK 7	/PA 3
	11
ZBLOCK 7	/PA4
	11
ZBLOCK 7	/PA5
	11
ZBLOCK 7	/PA6
	11
ZBLOCK 7	/PA7
	11
ZBLOCK 7	/PA8
	11
ZBLOCK 7	/PA9
	11
ZBLOCK 7	/PA10
	11
ZBLOCK 7	/PA11
	11
ZBLOCK 7	/PA12
	11
ZBLOCK 7	/PA13
	11
ZBLOCK 7	/PA14
	11
ZBLOCK 7	/PA15
	11
ZBLOCK 7	/PA 16
	11
	0
$$$$$$$$$$