File PLOT.SB (8k SABR macro assembler source file)

Directory of image this file is from
This file as a plain text file

/	GENERAL PLOT PROGRAMM FUER LA36, TTY UND CENTRONICS DRUCKER
/	13.JANUAR 1976					W. HOUBEN
/
/	CALL PLOT (DEV,U,ARG1,.....,ARG8)
/
/	MAX. 8 ARGUMENTE
/

	ENTRY	PLOT
	DUMMY	ARG1
	OPDEF BSW 7002
	LAP
ARG1,	BLOCK	2
PNTR,	0
CNTR,	0
POS,	0
IG,	0
N,	0
CHAR,	0
CTAB,	52	/ *
	53	/ +
	43	/ #
	44	/ $
	00	/ @
	46	/ &
	45	/ %
	77	/ ?
PNTR1,	0
XLINE,	LINE
XCTAB,	CTAB
XMESS,	MESS
LINE,	BLOCK	77
	EAP
PLER,	6014;1724		/ PLOT ERROR
PLOT,	BLOCK	2
	CLA CMA
	TAD	PLOT#
	DCA	PLOT#
	TAD I	PLOT
	BSW
	AND	(77
	TAD	(-2
	CIA
	DCA	N		/ NUMBER OF ARGUMENTS
	INC	PLOT#
	TAD I	PLOT
	DCA	ARG1
	INC	PLOT#
	TAD I	PLOT
	DCA	ARG1#
	INC	PLOT#
	TAD I	ARG1
	DCA	IG		/ GERAETENUMMER
	TAD I	PLOT
	DCA	ARG1
	INC	PLOT#
	TAD I	PLOT
	DCA	ARG1#
	INC	PLOT#
	TAD	XCTAB
	DCA	PNTR
	TAD I	ARG1
	SZA CLA			/MODE !
	JMP	WLINE
	TAD	XLINE
	DCA	PNTR1
	TAD	(-77
	DCA	CNTR
LOOP,	TAD	(4040		/ CLEAR LINE !
	DCA I	PNTR1
	ISZ	PNTR1
	ISZ	CNTR
	JMP	LOOP
FILL,
	TAD I	PLOT
	DCA	ARG1
	INC	PLOT#
	TAD I	PLOT
	DCA 	ARG1#
	INC	PLOT#
	TAD I	PNTR
	DCA	CHAR
	INC	PNTR
	TAD I	ARG1
	SNA
	IAC
	DCA	POS		/ POSITION
	TAD	POS
	TAD	(-177		/ ZEILENLAENGE
	SMA CLA
	JMS	ERR1		/ POS > LINE
	CALL 3,	LSET
	ARG	LINE
	ARG	POS
	ARG	CHAR
	ISZ	N
	JMP	FILL
	CALL 2,	WRITE
	ARG	IG
	ARG	FORMAT		/ (22A6)
	CMA
	CALL 2,	IOH
	ARG	4025
	ARG	LINE
	CALL 1,	IOH
	ARG	0
	RETRN	PLOT
FORMAT,	TEXT	$(1H ,21A6)$
WLINE,	TAD	XLINE
	DCA	PNTR1
	TAD	(-77
	DCA	CNTR
	TAD	XMESS
	DCA	CHAR
WLOP,	TAD I	CHAR
	DCA I	PNTR1
	ISZ	CHAR
	ISZ	PNTR1
	ISZ	CNTR
	JMP	WLOP
	JMP	FILL
ERR1,	0
	CALL 1,	ERROR
	ARG	PLER
	JMP I ERR1
	CPAGE	77
MESS,	1155;5555;5355;5555;5511;5555;5555;5355;5555;5511
	5555;5555;5355;5555;5511;5555;5555;5355;5555;5511
	5555;5555;5355;5555;5511;5555;5555;5355;5555;5511
	5555;5555;5355;5555;5511;5555;5555;5355;5555;5511
	5555;5555;5355;5555;5511;5555;5555;5355;5555;5511
	5555;5555;5355;5555;5511;5555;5555;5355;5555;5511
	5555;5555;5355;0
	END



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search