Directory of image this file is from
This file as a plain text file

/PLOT7.SB, PAGE 1 OF 4.		(9/16/71 - C.M.MOORE, RICE U., HOUSTON)
/
/PDP-12 SCOPE DISPLAY PACKAGE 7.
/
/CONTAINS ENTRY POINT DSP12.
/SEE LISTING OF FILE 'XPLAIN.PL' FOR AN EXPLANATION OF HOW TO
/USE THIS ROUTINE.
/
	LAP /THIS ROUTINE OCCUPIES 2 CORE PAGES.
/
ABSYM PT0   4
ABSYM LENTH 5
ABSYM Y     6
ABSYM TEM2 10 /AUTO-INDEX REGISTER
ABSYM TEM3 11 /AUTO-INDEX REGISTER
OPDEF TADI 1400
OPDEF JMPI 5400
/
/ADDRES LOADS NEXT ARG ADDRESS POINTED TO BY DSP12.
SAVE1,
ADDRES,	0
	TAD I DSP12 /USE LINKAGE ROUTINES TO SAVE 1 LOC.
	INC DSP12#
	DCA CDFARG
	CLA CMA
	TADI DSP12#
	INC DSP12#
	DCA TEM3 /AUTO-INDEX
	JMPI ADDRES
/
/GETARG FETCHES NEXT ARG POINTED TO BY DSP12.
PT1,
GETARG,	0
CDFARG,	0 /CHANGE TO DF OF ARG
	TADI TEM3 /AUTO-INDEX
	JMP I GETARG /CHANGE TO CURRENT DF
/
/DSCHAR DISPLAYS PATTERN POINTED TO BY TEM2.
DSCHAR,	0
	TADI TEM2 /AUTO-INDEX
	DCA PAT
	TAD Y
P6141,	6141 /LINC
P1760,	1760 /DSC I
PAT,	0000 /DISPLAY PATTERN
	0002 /PDP
	CLA
	JMPI DSCHAR
/
PATTRN,	P77
P770,	770
P23,	23
M366,	-366
/
/PLOT7.SB, PAGE 2 OF 4.
/
/CHPLOT DISPLAYS 8-BIT ASCII CHARACTERS 240-377.
/ALL OTHER CHARS EXCEPT TAB AND C-R ARE IGNORED
CHPLOT,	0
	AND P377
	TAD M240
	SMA
	JMP CPLOT /DISPLAY CHAR
	TAD P23
	SNA
	JMP CR
	TAD P4
	SZA CLA
	JMPI CHPLOT /IGNORE CHAR
/TAB CHARACTER: SET L1=(L1/80)*80+80, WHERE L1 =DISPLAY X-COORD.
	6141 /LINC
	1020 /LDA I
	3147 /INVERSE OF 120 OCTAL, SHIFTED 6 BITS LEFT
	1240 /MUL
	4001 /FRACTIONAL MULT WITH I.F. LOC 1
P346,	0346 /SCR 6
	1260 /MUL I
P120,	0120
	0002 /PDP
	TAD M650
	JMP M240
OVER,	CLA /LINE OVERFLOW
	TAD P346
CR,	JMS STC1 /CARRIAGE-RETURN CHARACTER
	TAD Y
	TAD P346
	SPA
	JMP JBACK /TOO MANY LINES
	TAD M366
	DCA Y
	JMPI CHPLOT
/DISPLAY THE CHARACTER IN BITS 6-11 OF THE AC
CPLOT,	TAD M240
P377,	0377 /AND P77
	CLL RAL
	TAD PATTRN
	DCA TEM2 /AUTO-INDEX
	JMS DSCHAR /DISPLAY 1ST HALF OF CHARACTER PATTERN
	JMS DSCHAR /DISPLAY 2ND HALF
	JMS ADD1
	TAD M766
M240,	SMA SZA
	JMP OVER /LINE OVERFLOW
	TAD P770
CHBAC,	JMS STC1
	JMPI CHPLOT
/
/ADD1 GETS LINC MODE INSTRUCTION FIELD LOC 1.
ADD1,	0
	6141 /LINC
	2001 /ADD 1
	0002 /PDP
	JMPI ADD1
/
/PLOT7.SB, PAGE 3 OF 4.
/
/STC1 STORES LINC MODE I.F. LOC 1.
STC1,	0
	6141 /LINC
	4001 /STC 1
P4,	0004 /ESF (SET UP HALF-SIZED CHARS)
	0002 /PDP
	JMPI STC1
/
/SUBROUTINE DSP12(LY,LENTH,STRNG)
	ENTRY DSP12
DSP12,	BLOCK 2
	JMS ADDRES
	JMS GETARG /GET LY
	DCA Y
	JMS ADDRES
	JMS GETARG /GET LENTH
	CIA
M650,	CLL CML RAR
	DCA LENTH
	JMS ADDRES /LOAD ADDRESS OF STRNG INTO TEM3
	JMS ADD1
	DCA SAVE1 /SAVE I.F. LOC 1
	JMS STC1 /ZERO LOC 1
/CHARACTER DISPLAY LOOP.
ALUP9,	JMS GETARG
	DCA PT0
	TAD PT0
	JMS CHPLOT /DISPLAY 1ST CHAR
	JMS GETARG
	DCA PT1
	TAD PT1
	JMS CHPLOT /DISPLAY 2ND CHAR
	TAD PT0
M766,	RTR
	RTR
	AND P1760
	DCA PT0
	TAD PT1
	RTL
	AND P6141
	RTL
	RAL
	TAD PT0
	JMS CHPLOT /DISPLAY 3RD CHAR
	ISZ LENTH
	JMP ALUP9
/EXIT SECTION
JBACK,	TAD SAVE1
	JMS STC1 /RESTORE I.F. LOC 1
AADISP,	RETRN DSP12
P77,	77 /MUST BE LAST LOC ON PAGE
/END OF FIRST CORE PAGE
/
/PLOT7.SB, PAGE 4 OF 4.
CHRPAT,	5146;3645 /@   DISPLAY PATTERNS FOR 6-BIT STRIPPED ASCII CHARS.
	4477;7744 /A
	5177;2651 /B
	4136;2241 /C
	4177;3641 /D
	4577;4145 /E
	4477;4044 /F
	4136;2645 /G
	1077;7710 /H
	7741;0041 /I
	4142;4076 /J
	1077;4324 /K
	0177;0301 /L
	3077;7730 /M
	3077;7706 /N
	4177;7741 /O
	4477;3044 /P
	4276;0376 /Q
	4477;3146 /R
	5121;4651 /S
	4040;4077 /T
	0177;7701 /U
	0176;7402 /V
	0677;7701 /W
	1463;6314 /X
	0770;7007 /Y
	4543;6151 /Z
	4177;0000 /[ (SHIFT K)
	3040;0106 /\ (SHIFT L)
	0000;7741 /] (SHIFT M)
	3710;1037 /^
	3410;1052 /_
	0000;0000 /  (SPACE)
	7500;0000 /!
	0070;0070 /"
	7624;0024 /#
	4731;4275 /$
	1446;6130 /%
	5166;0526 /&
	7000;0000 /'
	3600;0041 /(
	4100;0036 /)
	2050;0050 /*
	0404;0437 /+
	0500;0006 /,
	0404;0404 /-
	0001;0000 /.
	0601;4030 //
	4536;3651 /0
	2101;0177 /1
	4523;2151 /2
	4122;2651 /3
	2414;0477 /4
	5172;0651 /5
	1506;4225 /6
	4443;6050 /7
	5126;2651 /8
	5122;3651 /9
	2200;0000; 4601;0000; 2410;0042; 1212;1212; 4200;1024 /:;<=>
AAAEND,	4020;2055 /?
	END