Directory of image this file is from
This file as a plain text file

/RAM16K TEST FUER BESTRAHLUNG MIT ALPHA-TEILCHEN
/EINSCHREIBEN, VERIFIZIEREN, AUSLESEN
/WENN FEHLER AUFTRETEN NEU EINSCHREIBEN

*50
ERRADR,	0
RDZYL,	0

*1200

WE=10
TRIG=40
DOUT=4000
DI=20



INIT,	CLA
	DCA ERRADR
	DCA RDZYL
	CAM DST
	FELCTR

INIT1,	CAM DST
	ADRCTR
	CLA
	DCA NULLFG
	DCA ERRFLG
	CLEAR
	TRIG
	SET
	WE
	CLEAR
	WE

/****** EINSCHREIBEN INS DEVICE ********

RAMIN,	CAM DAD		/BERECHNEN DER ADRESSE 
	ADRCTR
	JMS ADRMOD
	CLA
	TAD ADRLOW
	AND MASK7	/BIT 7 BESTIMMT AUSGABE VON 0 ODER 1
	SZA CLA
	JMP ONEIN
	JMP ZEROIN
RAMINS,	NOP
OUTDA,	0		/AUSGEBEN DER NULL ODER EINS
	DI

	JMS ADRPUT	/ANLEGEN DER ADRESSEN LOW UND HIGH

	JMS ADRLOP		/EINLESEN BEENDET?
	CLA
	TAD NULLFG		/EINLESEN BEENDET FLAG=0
	SZA CLA
	JMP RAMOUT
	JMP RAMIN

/******** AUSLESEN AUS DEVICE ********


RAMOUT,	SET
	WE
	DCA NULLFG
	CAM DST
	ADRCTR


RMOUT,	CAM DAD
	ADRCTR
	JMS ADRMOD	/BERECHNEN DER ADRESSEN LOW UND HIGH

	CLA
	TAD ADRLOW
	AND MASK7
	SZA CLA
	JMP ONEOUT
	JMP ZEROUT

RMOUTS,	JMP ADRPUT	/ANLEGEN DER ADRESSEN

	INPUT		/AUSLESEN DER DATEN AUS DEM RAM
	AND DOMASK
ERRSKP,	0		/SKIP WIRD VOM PROGRAMM AUSGETAUSCHT
	JMS INERR

	CLA		/NEU EINSCHREIBEN NACH FEHLER
	TAD ERRFLG
	SZA CLA
	JMP INIT1

	JMS ADRLOP
	CLA
	TAD NULLFG		/AUSLESEN BEENDET FLAG=0
	SNA CLA
	JMP RMOUT
	ISZ ZYLCTL
	SKP
	ISZ ZYLCTH
	JMP RAMOUT




ADRCTR,	0;0
DOMASK,	DOUT
NULLFG,	0
MASK7,	100
ZYLCTL,	0
ZYLCTH,	0
ERRFLG,	0


PAGE



ZEROIN,	CLA		/INPUT 0
	TAD CLEARP
	DCA OUTDA
	JMP RAMINS

ZEROUT,	CLA		/OUTPUT 0
	TAD SKP1
	DCA ERRSKP
	JMP RMOUTS

ONEIN,	CLA		/INPUT 1
	TAD SETP
	DCA OUTDA
	JMP RAMINS

ONEOUT,	CLA		/OUTPUT 1
	TAD SKP0
	DCA ERRSKP
	JMP RMOUTS



ADRMOD,	0		/BERECHNEN DER ADRESSEN
	SHL		/ADRESSE HIGH IN MQ, ADRESSE LOW IN ACC
	5
	DCA ADRHGH
	LSR
	5
	SWP
	DCA ADRLOW
	JMP I ADRMOD

ADRPUT,	0
	CLA
	TAD ADRLOW		/OUTPUT VON LOW ADDRESS
	OUTPUT
	NPULSE
	TRIG
	TAD ADRHGH
	OUTPUT			/OUTPUT VON HIGH ADDRESS
	JMP I ADRPUT


ADRLOP,	0		/ALLE ADRESSEN ABGEARBEITET?
	CAM DAD
	ADRCTR
	DPIC
	DST
	ADRCTR
	DCM
	DAD
	RMSIZE
	DPSZ
	JMP READAG
	DCA NULLFG
	JMP I ADRLOP

READAG,	CLA IAC
	DCA NULLFG
	JMP I ADRLOP


ADRHGH,	0
ADRLOW,	0
FELCTR,	0;0
SKP0,	7440
SKP1,	7450
CLEARP,	CLEAR
SETP,	SET

PAGE


INERR,	0		/ZAEHLEN DER FEHLER
	ISZ FELCTR
	CLA
	TAD FELCTR
	SNA CLA
	ISZ FELCTR+1
	CLA IAC
	DCA ERRFLG

	TAD ADRHGH	/ABSPEICHERN DER FEHLERHAFTEN ADRESSE
	CDF 10
	DCA I ERRADR
	CDF 0
	ISZ ERRADR
	TAD ADRLOW
	CDF 10
	DCA I ERRADR
	CDF 0
	ISZ ERRADR

	TAD ZYLCTH	/ABSPEICHERN DES LESEDURCHGANGS
	CDF 20
	DCA I RDZYL
	CDF 0
	ISZ RDZYL
	TAD ZYLCTL
	CDF 20
	DCA I RDZYL
	CDF 0
	ISZ RDZYL

	JMP I INERR

PAGE


FELPRT,	TDC
	4306
	4305
	4310
	4314
	4305
	4322
	240
	CLA
	DCA ERRADR
	DCA RDZYL

	CAM DAD
	FELCTR
	TOCT
	SWP
	TOCT
ERRPRT,	MOSTSR
	CDF 10
	TAD I ERRADR
	CDF 0
	TOCT
	ISZ ERRADR
	CDF 10
	TAD I ERRADR
	CDF 0
	TOCT
	ISZ ERRADR

	TDC
	240
	CDF 20
	TAD I RDZYL
	CDF 0
	TOCT
	ISZ RDZYL
	CDF 20
	TAD I RDZYL
	CDF 0
	TOCT
	ISZ RDZYL
	JMP ERRPRT
	MOSTGO

RMSIZE,	0;4	/RAMSIZE 3 7777;HIGH ADRESS 177,LOW ADRESS 177