*40

ERRMPT,	0

*1000


RAMSTR,	TLS	/INITIALISIERUNG
	CLA
	DCA ERRMPT
	DCA RAMFEL
	DCA RAMFEL+1
	DCA RAMADR
	TAD MN32
	DCA CTR32
	CDF 20
	TAD NM256
	DCA I ERRMPT
	CDF 0
	ISZ ERRMPT
	ISZ CTR32
	JMP .-6
	CLA
	DCA ERRMPT

	RCHAR	/	UEBERSCHRIFT
	CHECK
	304
	JMP RAMIN
	JMP RAMCOM

MN32,	-1777
CTR32,	0
NM256,	256

PAGE


RAMCOM,	LINE
	LINE
	TDC
	4322
	4301
	4315
	4240
	4316
	4322
	4272
	240
RAMSPE,	RTCHAR
	CHECK
	212	/END OF COMMENT
	JMP RAMIN
	JMP RAMSPE

RAMIN,	LINE
	TDC
	4304
	4301
	4324
	4301
	240


	JMP INTRPT

	LINE

INONE,	RTCHAR
	CLA
	TAD RAMSZL	/TEST FUER EINZULESENDES BIT
	DCA RAMVGL
	TAD BITIN1
	MQL
	JMP BITINI


INZERO,	RTCHAR
	CLA
	TAD RAMSNL	/TEST FUER EINZULSESENDES BIT
	DCA RAMVGL
	TAD BITIN0
	MQL

BITINI,	CMA	/CLEAR SELECT. OUTPUT REG. OUTPUT=HIGH
	6515
	CLA

RAMWR,	TAD RAMADR
	CMA
	6506	/CLEAR SELECT. OUTPUT REG. 0
	CMA
	6505

	SWP
	6516	/SET RESPECTIVE OUTPUT REG.  OUTPUT=0
	BSW
	6515
	BSW
	MQL
	TAD RAMADR
	CIA
	TAD RMSIZE
	SNA CLA
	JMP .+3

	ISZ RAMADR
	JMP RAMWR

	TAD BITOUT
	MQL
RAMRDN,	DCA RAMADR

RAMRD,	TAD RAMADR
	CMA
	6506
	CMA
	6505
	MQA CLA
	6516	/SET SELECTIVE OUTPUT REG (MQ V ACC)
	6514	/EINLESEN;DIE VERSCHIEDENEN AUSGANGSSIGN.
	RAL CLL	/KOMMEN ALS HIHG AN
	MQA CLA
	6515	/CLEAR SELECTIVE OUTPUT REG.

RAMVGL,	SZL	/WIRD GEAENDERT JE NACH EINLESEN VON 0 ODER 1
	JMP RAMOKY
	ISZ RAMFEL
	CDF 20
	TAD NUM253
	DCA I ERRMPT
	CDF 0

RAMOKY,	CLA
	TAD RAMADR
	CIA
	TAD RMSIZE
	SNA CLA
	JMP RMEND

	ISZ ERRMPT
	ISZ RAMADR
	JMP RAMRD

RMEND,	JMP I .+1
	RAMERR



RAMFEL,	0;0
RAMSNL,	7420
RAMSZL,	7430
BITIN0,	5474
BITIN1,	7454
BITOUT,	44
RAMADR,	0
NUM253,	253
RMSIZE,	1777


PAGE



RAMERR,	LINE
	TDC
	4306
	4305
	4310
	4314
	4305
	4322
	240
	JMS DEZOUT
	RAMFEL
	STELE1
	LINE
	JMS FELPLO
	LINE
	LINE
	JMP RAMSTR






INTRPT,	KSF
	JMP .-1
	KRS
	CHECK
	260
	JMP INZERO
	CHECK
	261
	JMP INONE
	MOSTSR
	CLA
	JMP RAMSTR

STELE1,	7

PAGE



FELPLO,	0
	CLA
	TAD MN32
	DCA CTR32
	DCA ERRMPT
	DCA SETFOR
	LINE
	JMS SPACE8
	TDC		/COLUMN
	4303
	4317
	4314
	4325
	4315
	316
	LINE

	JMS SPACE8
	TDC
	261
	JMS SPACE8
	TDC
	4261
	260
	JMS SPACE8
	TDC
	4262
	260
	JMS SPACE8
	TDC
	4263
	260
	LINE

	JMS SPACE8
	TDC
	336
	TAD MNUM6
	DCA ARRCTR
ARROW,	JMS PRTARR
	CLA
	TAD MNUM1
	DCA SETFOR
	ISZ ARRCTR
	JMP ARROW

	LINE
	TDC
	4322
	4317
	4327
	240

	CLA
	DCA ERRMPT
ROWNEW,	TAD MNUM64
	DCA CTR64
	LINE
	CIF 10
	JMS DEZOUT
	SPALTE
	STELLE
	TDC
	4240
	240
ROWAG,	CDF 20
	TAD I ERRMPT
	CDF 0
	DCA PRTDOT
	TDC
PRTDOT,	0
	MOSTSR
	ISZ ERRMPT
	ISZ CTR32
	SKP
	JMP END

	ISZ CTR64
	JMP ROWAG
	ISZ SPALTE
	JMP ROWNEW
END,	JMP I FELPLO


SPACE8,	0
	CLA
	TAD MNUM8
	TAD SETFOR
	DCA SPCCTR
	TDC
	240
	ISZ SPCCTR
	JMP .-3
	JMP I SPACE8


PRTARR,	0
	JMS SPACE8
	TDC
	336
	JMP I PRTARR


MNUM8,	-10
MNUM6,	-3
SPCCTR,	0
ARRCTR,	0
SETFOR,	0
MNUM1,	-1
SPALTE,	0;0
STELLE,	7
MNUM64,	-40
CTR64,	0

FIELD 1
*1000


ENTF=JMS I 7

DEZOUT,	0
	SWAB
	CLA

	RDF
	TAD CHFIED
	DCA EXIT1
	IAC
	DCA 56
	DCA 55
	TAD I DEZOUT
	DCA DEZP1
	ISZ DEZOUT

	TAD I DEZOUT
	DCA DEZTEM
	TAD I DEZTEM
	DCA 57
	ISZ DEZOUT
	DCA 60

	CAM DAD
DEZP1,	0
	CDF 10
	SWP
	DST
	45
	CLA
	TAD (27
	DCA 44

	ENTF
	FNOR
	FOUT
	FEXT

EXIT1,	0
	JMP I DEZOUT

DEZTEM,	0
CHFIED,	CDF CIF 0