/TEST VON STATISCHEN 1K SPEICHERN
/BACKGROUND 0


*1000


		/HAUPTPROGRAMM

RAMSTR,	JMS RAMTIT	/UEBERSCHRIFT

	JMS WLKPAT	/PRUEFEN VON AUSGANG 1
	5077
	7057
	1

	JMS WLKPAT	/PRUEFEN VON AUSGANG 2
	5077
	5473
	2

	JMS WLKPAT	/PRUEFEN VON AUSGANG 3
	5077
	5275
	3

	JMS WLKPAT	/PRUEFEN VON AUSGANG 4
	5077
	5176
	4

	JMS RAMPR		/AUSDRUCKEN DER FEHLER

	JMP RAMSTR

PAGE



		/SUBROUTINE UEBERSCHRIFT DES URUEFPROGRAMMS
RAMTIT,	0
	TLS
	LINE
	LINE
	TDC
	4322
	4301
	4315
	4240
	240

RAMSPE,	RTCHAR		/READ COMMENT
	CHECK
	212
	SKP		/END OF COMMENT
	JMP RAMSPE
	LINE

	CLA
	DCA FLSUM1
	DCA FLSUM2
	DCA FLSUM3
	DCA FLSUM4
	JMP I RAMTIT



			/SUBROUTINE WALKPAT 
			/1. ARGUMENT BITMUSTER 0 
			/2. ARGUMENT BITMUSTER 1
			/3. ARGUMENT ZU TESTENDER AUSGANG
			/VIER AUSGAENGE KOENNEN GETESTET WERDEN

WLKPAT,	0	
	CLA
	TAD I WLKPAT
	DCA BITIN0
	ISZ WLKPAT

	TAD I WLKPAT
	DCA BITIN1
	ISZ WLKPAT

	TAD I WLKPAT
	DCA ERRAUS
	ISZ WLKPAT

	TAD BITIN0
	MQL
	CMA
	6515		/STEUERLTGEN. AUF EINS GESETZT
	CLA


	DCA RAMLIN
	DCA RAMADR
	DCA FLCNT1
	DCA FLCNT2
	DCA FLCNT3
	DCA FLCNT4
	DCA DEFFLG
	JMP I .+1
	RAMWR

WLKPTI,	JMP I WLKPAT



FLSUM1,	0
FLSUM2,	0
FLSUM3,	0
FLSUM4,	0
FLCNT1,	0
FLCNT2,	0
FLCNT3,	0
FLCNT4,	0
DEFFLG,	0
ERRAUS,	0
BITIN0,	0
BITIN1,	0


PAGE



/LADEN DES SPEICHERS MIT NULLEN

RAMWR,	TAD RAMADR
	6505
	CMA
	6506
	CMA

	SWP
	6516	
	BSW
	6515
	BSW
	MQL
	TAD RAMADR
	CIA
	TAD RMSIZE
	SNA CLA
	JMP .+3

	ISZ RAMADR
	JMP RAMWR


	TAD BITOUT              /INITIALISIERUNG DER LESEROUTINE
	MQL
	DCA RAMADR



/AUSLESEN DES GESAMTEN SPEICHERS UND PRUEFUNG AUF NULLEN

RAMRD,	TAD RAMADR
	6505
	CMA
	6506
	MQA CLA
	6516
	6514
	DCA RMOUTP
	JMS RAMERR	/PRUEFEN DES SPEICHERZELLENINHALTS, ALLE AUSGAENGE
	MQA CLA
	6515

	CLA
	TAD RAMADR
	CIA
	TAD RMSIZE
	SZA CLA
	JMP .+6
	JMS DEFECT		/RAM DEFECT ?
	TAD DEFFLG
	SZA
	JMP RAMSTR
	JMP RAMWR1

	ISZ RAMADR
	JMP RAMRD


RAMADR,	0
BITOUT,	44
RMSIZE,	377		/GROESSE DES RAMS
RMOUTP,	0

PAGE


/EINLESEN EINER EINS IN DEN SPEICHER


RAMWR1,	CMA CLA
	6515

	CLA
	DCA FLCNT1
	DCA FLCNT2
	DCA FLCNT3
	DCA FLCNT4
	TAD BITIN1
	MQL

	TAD RAMLIN	
	6505
	CMA
	6506

	MQA CLA
	6516
	BSW
	6515
	CLA

	TAD BITOUT		/INIT. DER LESEROUTINE
	MQL
	DCA RAMADR




/PRUEFUNG DES SPEICHERINHALTS 

RAMRD1,	TAD RAMADR	
	6505
	CMA
	6506

	MQA CLA	
	6516
	6514
	DCA RMOUTP
	JMS RAMERR	/PRUEFEN DES SPEICHERZELLENINHALTS, ALLE AUSGAENGE
	MQA CLA
	6515


	CLA
	TAD RAMADR
	CIA
	TAD RMSIZE
	SZA CLA
	JMP .+7
	JMS DEFSUM		/ADDITION DER FEHLER
	JMS DEFECT		/RAM DEFECT
	TAD DEFFLG
	SZA CLA
	JMP RAMSTR
	JMP RAMWR0


	ISZ RAMADR
	JMP RAMRD1




PAGE


/RUECKSCHREIBEN EINER NULL AN DIE STELLE DER EINS

RAMWR0,	CLA
	TAD BITIN0
	MQL
	TAD RAMLIN	
	6505
	CMA
	6506

	MQA CLA
	6516
	BSW
	6515

	CLA
	TAD RAMLIN
	CIA
	TAD RMSIZE
	SNA CLA
	JMP WLKPTI

	ISZ RAMLIN
	JMP RAMWR1



RAMLIN,	0

PAGE




		/SUBROUTINE FFEHLERERKENNUNG

RAMERR,	0
	CLA
	TAD RMOUTP
	AND M7400
	SNA
	JMP I RAMERR

	RAL 
	SZL
	ISZ FLCNT1		/AUSGANG1
	RAL
	SZL
	ISZ FLCNT2		/AUSGANG2
	RAL
	SZL
	ISZ FLCNT3		/AUSGANG3
	RAL
	SZL CLA
	ISZ FLCNT4		/AUSGANG4
	JMP I RAMERR




			/SUBROUTINE SUMMATION DER FEHLER

DEFSUM,	0
	CLA IAC
	CIA
	TAD ERRAUS		/MODIFIKATION DER FEHLERZAEHLERADRESSE
	TAD FECTPI		/JE NACH AUSGANG
	DCA FECTR
	TAD I FECTR
	SNA
	JMP FELONE		/WENN NULL DANN 1 FEHLER
	TAD MNUM1
	SZA
	DCA I FECTR		/ANZAHL DER FEHLER -1
	JMP I DEFSUM

FELONE,	CLA IAC
	DCA I FECTR
	JMP I DEFSUM




			/SUBROUTINE RAM DEFECT ?


DEFECT,	0
	CLA
	TAD FLSUM1
	TAD FLCNT1
	DCA FLSUM1

	TAD FLSUM2
	TAD FLCNT2
	DCA FLSUM2

	TAD FLSUM3
	TAD FLCNT3
	DCA FLSUM3

	TAD FLSUM4
	TAD FLCNT4
	DCA FLSUM4

	TAD MNDEF
	TAD FLCNT1
	SNA CLA
	JMS RAMDEF

	TAD MNDEF
	TAD FLCNT2
	SNA CLA
	JMS RAMDEF

	TAD MNDEF
	TAD FLCNT3
	SNA CLA
	JMS RAMDEF

	TAD MNDEF
	TAD FLCNT4
	SNA CLA
	JMS RAMDEF
	JMP I DEFECT

MNUM1,	-1
MNDEF,	-400		/MAXIMALE ANZAHL D. FEHLER/DURCHGANG
FECTPI,	FLCNT1
FECTR,	0
M7400,	7400


PAGE



		/SUBROUTINE AUSDRUCK DER FEHLERANZAHL
RAMPR,	0
	LINE
	LINE
	TDC
	4302
	4301
	4303
	4313
	4307
	4322
	4317
	4325
	4316
	4304
	4240
	4240
	260


	CLA
	TAD NUM1
	DCA AUSCTR
	TAD FLSUMP
	DCA FLSUMC
OUTPR,	LINE
	TDC
	4301
	4325
	4323
	4307
	4301
	4316
	4307
	4272
	240
	CLA
	TAD AUSCTR
	TOCT

	TDC
	4240
	4240
	4240
	4240
	4306
	4305
	4310
	4314
	4305
	4322
	4272
	240
	CLA
	TAD I FLSUMC
	TOCT

	ISZ FLSUMC
	ISZ AUSCTR
	CLA
	TAD AUSCTR
	TAD MN4
	SPA SNA CLA
	JMP OUTPR
	JMP I RAMPR


FLSUMP,	FLSUM1
FLSUMC,	0
NUM1,	1
MN4,	-4		/ANZAHL DER AUSGAENGE



PAGE



			/SUBROUTINE AUSDRUCK WENN RAM DEFECT
RAMDEF,	0
	CLA
	TAD DEFFLG
	SZA CLA
	JMP I RAMDEF

	LINE
	TAD RAMLIN
	TOCT		/DURCHGANG
	LINE
	LINE

	TDC
	4301
	4325
	4323
	4307
	4301
	4316
	4307
	4207
	240
	CLA
	TAD ERRAUS
	TOCT
	LINE

	TDC
	4322
	4301
	4315
	4240
	4240
	4304
	4305
	4306
	4303
	4240
	241
	TAD NUM1
	DCA AUSCTR
	TAD FECTPI
	DCA FECTP
	LINE
DEFPR,	TDC
	4301
	4325
	4323
	4307
	4301
	4316
	4307
	4272
	240
	CLA
	TAD AUSCTR
	TOCT

	TDC
	4240
	4240
	4240
	4240
	4306
	4305
	4310
	4314
	4305
	4322
	4272
	240
	CLA
	TAD I FECTP
	TOCT

	LINE
	ISZ FECTP
	ISZ AUSCTR
	CLA
	TAD AUSCTR
	TAD MN4
	SPA SNA CLA
	JMP DEFPR
	IAC
	DCA DEFFLG
	JMP I RAMDEF



AUSCTR,	0
FECTP,	0