/ROM TYPE OUT ROUTINE USING MODIFIED MOST SUBROUTINES




/SET PAGE 0 POINTERS

        *20

FIRST,	SRRCH
        SRTCH
        SRRTCH
        SRTDC
        SRLINE
        SRCH
        7577
	7577
	SRRTCM
	7577
        SRCHOC
        SRROCT
        SRTOCT
        7600
LAST,	7577




                *200

SRTOCT, 0       /TYPE OCTAL
	RTL
	RTL
	DCA TEMPB
	TAD M3
        DCA TEMP
NEXTO,	TAD TEMPB
	RAL
	RTL
	DCA TEMPB
	TAD TEMPB
	AND MASK
        TAD P260
        TCHAR
PS8I,	7600	/CLA AND PS8 ADDR.
        ISZ TEMP
        JMP NEXTO
        JMP I SRTOCT



SRRTCM,	0	/READ AND TYPE A COMMAND
	RTCHAR
	CHECK
	203	/CONTR/C  JMP TO PS/8
	JMP I PS8I
	CHECK
	250	/IGNORE COMMENTS
	JMP COMMNT
CMNRET,	JMP I SRRTCM

COMMNT,	RTCHAR
	CHECK
	203	/CONTR/C.   JMP TO PS8
	JMP I PS8I
	CHECK
	215	/END OF COMMENT
	JMP CMNRET
	CHECK
	212	/END OF COMMENT
	JMP CMNRET
	CHECK
	251	/END OF COMMENT
	JMP SRRTCM+1
	JMP COMMNT
SRRCH,	0		/READ A CHARACTER
	KSF
	JMP .-1
	KRB
	JMP I SRRCH

SRTCH,  0               /TYPE A CHARACTER
	TSF
        JMP .-1
	TLS
        JMP I SRTCH

TEMPB,
SRRTCH, 0               /READ AND TYPE A CHARACTER
        RCHAR
        TCHAR
        JMP I SRRTCH

TEMPA,
SRTDC,  0               /TYPE DIAGNOSTIC SYMBOL
	CLA
TDCLP,	TAD I SRTDC
        ISZ SRTDC
        TCHAR
	SPA CLA
	JMP TDCLP
        JMP I SRTDC



TEMP,
SRLINE, 0       /TYPE "CR LF"
        TDC
	4215
	212
        JMP I SRLINE


SRCH,   0       /CHECK AND SKIP IF WRONG
        DCA TEMP        /SAVE AC
        TAD I SRCH
        ISZ SRCH
        CIA
        TAD TEMP
        SZA CLA
        ISZ SRCH
        TAD TEMP        /RESTORE AC
        JMP I SRCH

SRCHBK, 0               /SKIP IF NOT IN BLOCK
        DCA TEMP        /SAVE AC
        TAD I SRCHBK
        ISZ SRCHBK
        CIA
        TAD TEMP
        SPA
        JMP NO
        CMA
        TAD I SRCHBK
        SPA
NO,     ISZ SRCHBK
        ISZ SRCHBK
	CLA
        TAD TEMP        /RESTORE AC
        JMP I SRCHBK


TEMPC,
SRCHOC, 0               /SKIP IF OCTAL DIGIT
        CHBLOK
P260,	260
        10
        ISZ SRCHOC
        JMP I SRCHOC

SRROCT, 0               /READ AND TYPE OCTAL NUMBER
        CHOCT           /1ST. CHAR. IN AC. ON ENTRY
	TYDER		/ENTERED WITH NON-OCTAL CHAR
        AND MASK
        DCA TEMP
        TAD M4
        DCA TEMPA
        DCA OCNUM
ROCTA,  TAD OCNUM
        RAL CLL
        RTL
        TAD TEMP
        DCA OCNUM
        RTCOMD
        CHOCT
        JMP I SRROCT    /EXIT ON NON-OCT CHAR.
	ISZ TEMPA
	SKP
	JMP I SRROCT
	AND MASK
	DCA TEMP
	JMP ROCTA

M3,	-3
M4,     -4
MASK,   0007
OCNUM,	0


PAGE


RAMSTR,	CLA
	TAD RAM10
	CIA
	DCA RAMRDC
	DCA RAMERL
	DCA RAMERH
	DCA RAMADR

	KSF
	KRB
	TLS
	JMS INTRPT
	JMP .-1

INONE,	CLA
	TAD RAMSMA	/SMA CLA
	DCA RAMVGL
	TAD BITIN1
	JMP BITINI


INZERO,	CLA
	TAD RAMSPA	/SPA CLA
	DCA RAMVGL
	TAD BITIN0

BITINI,	BSW
	CMA
	6505
	CMA
	6505
	BSW
	MQL

RAMWR,	CMA
	6505	/CLEAR SELECT. OUTPUT REG. 0
	CMA
	6506

	SWP
	CMA
	6515	/CLEAR SELECT. OUTPUT REG. 1
	CMA
	6516
	BSW
	CMA
	6515
	CMA
	6516
	BSW
	SWP
	IAC
	SZA
	JMP RAMWR


	TAD BITOUT
	MQL

RAMRD,	CMA
	65 3	/INIT. VON INPUT REG.
	CLA
	TAD RAMADR
	CMA
	6505
	CMA
	6506
	MQA
	CMA
	6515
	CMA
	6516
	BSW
	CMA
	6515
	CMA
	6516

	65 4	/INPUT DATA TO ACC IN BIT 11

RAMVGL,	SMA CLA	/WIRD GEAENDERT JE NACH EINLESEN VON 0 ODER 1
	JMP .+3
	ISZ RAMERL
	ISZ RAMERH

	ISZ RAMADR
	JMP RAMRD

	ISZ RAMRDC
	JMP RAMRD


RAMERR,	LINE
	TDC
	4306
	4305
	4310
	4314
	4305
	322
	LINE
	TAD RAMERH
	TOCT
	LINE
	TAD RAMERL
	TOCT

	JMS INTRPT
	JMP .-1



INTRPT,	0
	KSF
	JMP I INTRPT
	RCHAR
	CHECK
	203
	JMP I PS8II
	CHECK
	260
	JMP INZERO
	CHECK
	261
	JMP INONE
	CLA
	JMP I INTRPT

RAM10,	10
RAMRDC,	0
RAMERL,	0
RAMERH,	0
RAMSPA,	7710
RAMSMA,	7700
BITIN0,	0316
BITIN1,	0116
BITOUT,	0521
RAMADR,	0
PS8II,	7600