Directory of image this file is from
This file as a plain text file

/RANWAK/
BSW=7002
MQL=7421
MQA=7501
DLINE=0200
GXBUF=1400
GXDF=10
PGDF=00
*0050
TMP, 0
CTR, 0
PTR, 0
CHAR, 0
*0600
RANWAK, CLA CLL
RWLOOP, KSF
 JMP NOINT1
 KRS
 TAD (-203)
 SZA CLA
 JMP .+4
 6152
 CIF CDF 00
 JMP I (7600)
 KCC
NOINT1, JMS SEED
 DCA RAND1
 TAD RAND1
 DCA RAND2
GXCLR, TAD (GXBUF-1)
 DCA 12
 TAD (-6200)
 DCA CTR
 CDF GXDF
 DCA I 12
 ISZ CTR
 JMP .-2
 CDF PGDF
GXDIS, 6156
 JMP .-1
 TAD (GXBUF)
 6150
 NOP
 NOP
 TAD (GXDF+0002)
 6151
 DECIMAL
 TAD (94)
 DCA OLDX1
 TAD OLDX1
 DCA OLDX2
 TAD (100)
 DCA OLDY1
 TAD OLDY1
 DCA OLDY2
 DCA NUMBEH
 OCTAL
STLOOP, KSF
 JMP NOINT2
 KRS
 TAD (-203)
 SNA CLA
 JMP RWLOOP
 KRB
 TAD (-217)
 SNA 
 JMP RWLOOP
 IAC
 SNA CLA
 JMP I (NXPROG)
NOINT2, TAD (PARM1-1)
 JMS STEP
 TAD NUMBEH
 IAC
 DCA NUMBEH
ERASEL, LAS
 AND (0077)
 SNA
 JMP DELAY
 STL CIA
 TAD NUMBEH
 SNA SZL CLA
 JMP DELAY
 TAD (PARM2-1)
 JMS STEP
 CLA CLL CMA CML
 TAD NUMBEH
 DCA NUMBEH
 JMP ERASEL
DELAY, DCA CTR
DELAYL, KSF
 JMP NOINT3
 JMP STLOOP
NOINT3, LAS
 BSW
 AND (0077)
 STL CIA
 TAD CTR
 SNL CLA
 JMP STLOOP
 ISZ CTR
 6156
 JMP .-1
 JMP DELAYL
PARM1,
OLDX1, 0
OLDY1, 0
NEWX1, 0
NEWY1, 0
      +1
RAND1, 0
PARM2,
OLDX2, 0
OLDY2, 0
NEWX2, 0
NEWY2, 0
      -1
RAND2, 0

NUMBEH, 0
 PAGE
 EJECT
STEP, 0
 DCA APARMS
 TAD APARMS
 DCA 10
 TAD (SPARMS-1)
 DCA 11
 TAD (-6)
 DCA CTR
 TAD I 10
 DCA I 11
 ISZ CTR
 JMP .-3
 TAD RNUM
 JMS RAND
 DCA RNUM
 TAD RNUM
 AND (0030)
 CLL RTR
 RAR
 DCA DIS
 TAD RNUM
 AND (0007)
 TAD (DIRTAB)
 DCA TMP
 TAD I TMP
 DCA XYDIR
 TAD SOX
 DCA XYOLD
 TAD (-274)
 DCA XYMAX
 JMS XYCHNG
 TAD XYOLD
 DCA SNX
 TAD XYDIR
 BSW
 DCA XYDIR
 TAD SOY
 DCA XYOLD
 TAD (-307)
 DCA XYMAX
 JMS XYCHNG
 TAD XYOLD
 DCA SNY
 TAD (SPARMS-1)
 JMS DLINE
 TAD SNX
 DCA SOX
 TAD SNY
 DCA SOY
 TAD APARMS
 DCA 10
 TAD (SPARMS-1)
 DCA 11
 TAD (-6)
 DCA CTR
 TAD I 11
 DCA I 10
 ISZ CTR
 JMP .-3
 JMP I STEP
XYCHNG, 0
 TAD XYDIR
 RAL
 SNL CLA
 JMP I XYCHNG
 TAD XYDIR
 RTL
 DCA TMP
 SZL
 TAD (4)
 TAD (DTAB1)
 TAD DIS
 DCA PTR
 TAD TMP
 RAL
 CLA
 TAD I PTR
 SZL
 CIA
 TAD XYOLD
 SMA
 JMP NOTNEG
 CLA
 DCA XYOLD
 JMP I XYCHNG
NOTNEG, DCA XYOLD
 TAD XYOLD
 TAD XYMAX
 SPA SNA CLA
 JMP I XYCHNG
 TAD XYMAX
 CIA
 DCA XYOLD
 JMP I XYCHNG
APARMS, 0
SPARMS,
SOX, 0
SOY, 0
SNX, 0
SNY, 0
DUD, 0
RNUM, 0
DIS, 0
DIRTAB, 0040
        6060
        4000
        6070
        0050
        7070
        5000
        7060
XYDIR, 0
XYOLD, 0
XYMAX, 0
 PAGE
DTAB1, 03
       06
       11
       14
DTAB2, 02
       04
       06
       11

SEED, 0
 TAD ("?)
 TLS
 CLA CLL
GPARM, DCA TMP
GCHAR, KSF
 JMP .-1
 KRB
 TSF
 JMP .-1
 TLS
 DCA CHAR
 TAD CHAR
 TAD (-215)
 SZA CLA
 JMP GCHARX
 TAD (212)
 TSF
 JMP .-1
 TLS
 CLA CLL
GCHARX, TAD CHAR
 TAD (-272)
 SMA
 JMP DELIM
 TAD (12)
 SPA
 JMP DELIM
 DCA CHAR
 TAD TMP
 CLL RTL
 TAD TMP
 CLL RAL
 TAD CHAR
 JMP GPARM
DELIM, CLA CLL
 TSF
 JMP .-1
 TAD TMP
 JMP I SEED

 DECIMAL
RAND, 0
 RAL
 TAD (-1031)
 SPA
 TAD (1031)
 JMP I RAND
 OCTAL
NXPROG, 6152
 CLA IAC
 MQL
 TAD I (7746)
 MQA
 DCA I (7746)
 CIF 10
 JMS I (7700)
 10
 CIF 10
 JMS I (200)
 1
DEVNUM, DEVICE DTA0
 DEVHND+1
 JMP CHERR1
 TAD DEVNUM+1
 CIF 10
 JMS I (200)
 2
BLKNUM, CHNAME
 0
 JMP CHERR2
 TAD BLKNUM
 DCA BLKN2
 CIF 10
 JMS I (200)
 6
BLKN2, 0
CHNAME, FILENAME FULCRC.SV
CHERR1, CIF 10
 JMS I (200)
 7
 3
CHERR2, CIF 10
 JMS I (200)
 7
 4
 PAGE
DEVHND, 0 /DEV HNDLR/
$