Directory of image this file is from
This file as a plain text file

/ RT01 DATA DECODE TASK				17-MAY-90
/
/
/EDIT HISTORY:
/
/09-NOV-78	(LHN)
/	1)  FIXED DATE DECODING
/20-NOV-78	(LHN)
/	1)  FIXED START OF ROLL SAMPLING LENGTH.
/24-APR-90	(LHN)
/	1) REMOVED ENTRY OF SAMPLING FREQUENCY
/	2) CHANGED ENTRY OF SAMPLING CODE FOR BOX SAMPLES






	FIELD ROLDTFLD%10
	*ROLLPGZ

RTD0A,  0		/LOCAL TEMPORARIES
RTD0B,	0
RTD0C,	0
RTD0D,	0
RTD0E,	0
RTD0F,	0

RT01MSG, ZBLOCK 3	/RT01 MESSAGE AREA
RTSIND,	0		/INDICATOR STATUS
RTFUNC,	0		/FUNCTION CODE
RTDECF,	0		/CHARACTER COUNT IN MESSAGE
RTDBUF,	ZBLOCK 14	/CHARACTER BUFFER





	TASK=	ROLLDT
	INIWT=  0
	CUR=	ROLDTFLD
	VERS=	3






	*ROLDTLOC
/
/
/%RT	RT01 DATA TERMINAL OPERATION
/
/
/%TW	THE RT01 DATA TERMINAL IN THE INPUT DEVICE FOR
/	ALL OPERATOR INFORMATION. THE NUMERIC AND CONTROL
/	KEYS ON THE RT01 PERMIT THE ENTRY AND MODIFICATION
/	OF THE ROLL DATA AND HEADING INFORMATION.
/
/%TW	THE RT01 KEYBOARD HAS 4 STATUS LIGHTS CONTROLLED
/	FROM THE MAST SYSTEM. THESE STATUS LIGHTS AND THE 
/	CONTROL KEYS DETERMINE WHAT TYPE OF INFORMATION
/	IS BEING ENTERED ON THE NUMERIC KEYS. THE DATA
/	IS CLASSED AS FOLLOWS:
/
/
/%TN	STATUS	CONTROL		DATA TYPE
/%TN	LIGHT	  KEY
/%TN
/%TN	  1	   B	NEXT ROLL NUMBER
/%TN	  1	   C	NEXT ROLL PUT-UP AND SHEAR CUT
/%TN	  1	   D	NEXT ROLL SAMPLING CODE
/%TN	  1	   E	NEXT ROLL SLIT WIDTH (MM)
/%TN	  1	   F	NEXT ROLL CHOP LENGTH (MM)
/%TN
/%TN	  2	   B	SISTER ROLL CUT NUMBER
/%TN
/%TN	  3	   B	CURRENT ROLL NUMBER
/%TN	  3	   C	CURRENT ROLL PUT-UP AND SHEAR CUT
/%TN	  3	   D	CURRENT ROLL SAMPLING CODE
/%TN	  3	   E	CURRENT ROLL SLIT WIDTH (MM)
/%TN
/%TN	  4	   B	DATE
/%TN	  4	   C	SHIFT CODE
/%TN	  4	   D	OPERATOR CODE
/%TN
/
/%TW	THE "A" CONTROL KEY HAS TWO FUNCTIONS, CLEAR THE 
/	CURRENT DISPLAY AND MOVE THE STATUS LIGHT TO THE
/	NEXT POSITION. IF A NUMBER HAS BEEN ENTERED ON
/	THE RT01 THE "A" KEY WILL CLEAR THE DISPLAY AND
/	TELL MAST TO IGNORE THE ENTERED NUMBER. IF THE
/	"A" KEY IS STRUCK WHEN THERE IS NO DATA BEING
/	DISPLAYED, THE STATUS LIGHT WILL ADVANCE TO THE
/	THE NEXT POSITION.
/
/
/%R	RT01 DATA DECODE ROUTINE
/
/%TW	DECODE AND PROCESS DATA ENTERED BY THE MACHINE
/	OPERATOR ON THE RT01 DATA TERMINAL.
/
/
START,  CLB
	CAL
	SENDW		/GO TO SLEEP 'TIL NEXT TIME
	RT01
	RT01MSG

	CLB
	TAD (RTDBUF-1)	/SET UP AN AUTO-INDEX FOR THE RT01
	DCA XR10	/DATA BUFFER AREA.
	TAD RTSIND	/IS THE STATUS INDICATOR CODE = 1 ?
	CLL RAR
	SZA
	JMP RTD05	/NO, KEEP LOOKING
/
/
/	DECODE NEW ROLL DATA
/
/
	CLB CMA RAL	/YES, IS THE FUNCTION CODE = B ?
	TAD RTFUNC
	SZA 
	JMP RTD01	/NO, KEEP LOOKING
	JMS RTMOVR	/YES, GO MOVE THE NEXT ROLL NUMBER
	CRTX01		/TO THE TEXT AREA.
	ISZ NEWRNF	/SET THE ROLL NUMBER ENTERED FLAG
	AC4000
	JMS CRTMGA	/GO REMOVE THE "ENTER NEXT ROLL
	MOPM08		/DATA" MESSAGE FROM THE DISPLAY.
	JMP RTD21	/GO TO THE ROUTINE EXIT

RTD01,	TAD (-1)	/IS THE FUNCTION CODE = C ?
	SZA
	JMP RTD02	/NO, KEEP LOOKING
	JMS RTMOVP	/YES, GO MOVE THE NEXT ROLL PUT-UP
	CRTX02		/TO THE TEXT AREA
	DCA NSHEAR	/SAVE THE NEW SHEAR CUT DIGIT.
	TAD RTD0B
	CIA
	DCA NPUTPF	/SET THE PUT-UP ENTERED FLAG
	JMP RTD21	/GO TO THE ROUTINE EXIT

/
RTD02,	TAD (-1)	/IS THE FUNCTION CODE = D ?
	SZA
	JMP RTD03	/NO, KEEP LOOKING
	JMS RTMOVS	/YES, GO MOVE THE NEXT ROLL SAMPLING 
	CRTX03		/CODE TO THE TEXT AREA.
	DCA NSAMCD	/SAVE THE NEW SAMPLING CODE .
	JMP RTD21	/GO TO THE ROUTINE EXIT
RTD03,	TAD (-1)	/IS THE FUNCTION CODE = E ?
	SZA
	JMP RTD04	/NO, KEEP LOOKING
	JMS RTMOVW	/YES, GO PROCESS THE NEXT ROLL SLIT
	CRTX04		/ WIDTH.
	NSLITC		/PUT THE NEXT ROLL WIDTH HERE.
	JMP RTD21	/GO TO THE ROUTINE EXIT

RTD04,	TAD (-1)	/IS THE FUNCTION CODE = F ?
	SZA
	JMP RTD20	/NO, GO DISPLAY THE DATA ERROR MSG
	JMS RTMOVC	/YES, GO MOVE THE NEW CHOP LENGTH
	CRTX05		/TO THE TEXT AREA AND SET UP THE
			/CHOP LENGTH DATA FOR END-OF-ROLL
			/SUMMARY TIME.
/
/
/	DECODE THE SISTER ROLL NUMBER
/
/
RTD05,	CLL RAR		/IS THE STATUS INDICATOR CODE = 2 ?
	SZA
	JMP RTD10	/NO, KEEP LOOKING
	CLB CMA RAL	/YES, IS THE FUNCTION CODE = B ?
	TAD RTFUNC
	SZA
	JMP RTD20	/NO, GO DISPLAY THE DATA ERROR MSG

	CLB CMA		/YES, GO CHECK THAT ONLY 1 DIGIT WAS
	JMS RTDCHK	/ENTERED
	TAD (CRTX06+5)	/YES, GO MOVE THE SISTER ROLL CUT
	DCA XR11	/NUMBER TO THE CURRENT ROLL TEXT
	TAD (700)	/AREA
	JMS RTMOV1
	TAD (CRTX06+6)	/GET THE SISTER ROLL CUT NUMBER IN
			/ASCII AND GIVE TO THE SAMPLE
	DCA SRCUTN	/ROUTINES
	ISZ SISRLF	/SET THE SISTER ROLL FLAG
	TAD (CRTX06)	/GO CUE THE CURRENT ROLL NUMBER TEXT
	JMS RTSHOW	/FOR DISPLAY
	JMP RTD21	/GO TO THE ROUTINE EXIT

	PAGE
/
/
/	DECODE CURRENT ROLL DATA CHANGES
/
/
RTD10,	CLL RAR		/IS THE STATUS INDICATOR CODE = 3 ?
	SZA
	JMP RTD14	/NO, KEEP LOOKING
	CLB CMA RAL	/YES, IS THE FUNCTION CODE = B ?
	TAD RTFUNC
	SZA
	JMP RTD11	/NO, KEEP LOOKING
	JMS RTMOVR	/YES, GO MOVE THE CURRENT ROLL
	CRTX06		/NUMBER TO THE TEXT AREA.
	CDF 20
	ISZ I (MROLLF)	/SET THE MOVE ROLL NUMBER FLG
	JMP RTD21	/GO TO THE ROUTINE EXIT

RTD11,	TAD (-1)	/IS THE FUNCTION CODE = C ?
	SZA
	JMP RTD12	/NO, KEEP LOOKING
	JMS RTMOVP	/YES, GO MOVE THE CURRENT ROLL
	CRTX07		/PUT-UP TO THE TEXT AREA.
	DCA SHEARC
	CDF 20
	ISZ I (NPCODE)	/SET THE NEW PUT-UP CODE FLAG.
	CDF 10
	TAD RTD0B	/RESET THE CURRENT PUT UP IN F1.
	CIA
	DCA I (PUTUP1)
	JMP RTD21	/GO TO THE ROUTINE EXIT.

RTD12,	TAD (-1)	/IS THE FUNCTION CODE = D ?
	SZA
	JMP RTD13	/NO, KEEP LOOKING
	JMS RTMOVS	/YES, GO MOVE THE CURRENT ROLL
	CRTX08		/SAMPLING CODE TO THE TEXT AREA.
	CDF 20
	DCA I (PATCON)	/UPDATE THE CURRENT SAMPLING
			/PATTERN INTERVAL.
	ISZ I (NSCODE)	/SET THE NEW SAMPLING CODE FLAG FOR
	JMP RTD21	/GO TO THE ROUTINE EXIT
RTD13,	TAD (-1)	/IS THE FUNCTION CODE = E ?
	SZA
	JMP RTD14	/NO, KEEP LOOKING
	JMS RTMOVW	/YES, GO PROCESS THE CURRENT ROLL
	CRTX09		/ SLIT WIDTH DATA.
	SLITC		/PUT CURRENT WIDTH HERE.
	JMP RTD21	/GO TO THE ROUTINE EXIT
/
/
/	DECODE NEW HEADING INFORMATION
/
/
RTD14,	CLL RAR		/IS THE STATUS INDICATOR CODE = 4 ?
	SZA
	JMP RTD20	/NO, GO DISPLAY THE DATA ERROR MSG
	CLB CMA RAL	/YES, IS THE FUNCTION CODE = B ?
	TAD RTFUNC
	SZA
	JMP RTD16	/NO, KEEP LOOKING
	TAD (-6)	/YES, GO CHECK THAT ONLY 6 DIGITS
	JMS RTDCHK	/WERE ENTERED ?
	TAD (CRTH01+2)	/SET UP AN AUTO-INDEX FOR THE TEXT
	DCA XR11		/AREA
	JMS RTMOV2	/GO MOVE THE MONTH
	ISZ XR11
	JMS RTMOV2	/GO MOVE THE DAY
	ISZ XR11
	JMS RTMOV2	/GO MOVE THE YEAR

	JMS RTDATE	/GO PROCESS THE SYSTEM FOR RTS/8.
	JMS RTDTTY	/GO OUTPUT AND DISPLAY THE NEW DATE
	CRTH01

RTD16,	TAD (-1)	/IS THE FUNCTION CODE = C ?
	SZA
	JMP RTD17	/NO, KEEP LOOKING
	CLB CMA		/YES, GO CHECK THAT ONLY 1 DIGIT WAS
	JMS RTDCHK	/ENTERED
	TAD (CRTH02+3)	/SET UP AN AUTO-INDEX FOR THE TEXT
	DCA XR11		/AREA
	JMS RTMOV1	/GO MOVE THE SHIFT CODE TO THE TEXT
	CLB IAC
	DCA SHFTRL	/RESET THE SHIFT ROLL NUMBER FOR THE
			/SAMPLING ROUTINES.
	JMS RTDTTY	/GO OUTPUT AND DISPLAY THE NEW SHIFT
	CRTH02		/CODE.
RTD17,	TAD (-1)	/IS THE FUNCTION CODE = D ?
	SZA
	JMP RTD20	/NO, GO DISPLAY THE DATA ERROR MSG
	CLB CMA RAL	/YES, GO CHECK THAT ONLY 2 DIGITS
	JMS RTDCHK	/WERE ENTERED.
	TAD (CRTH03+4)	/SET UP AN AUTO-INDEX FOR THE TEXT
	DCA XR11		/AREA
	JMS RTMOV2	/GO MOVE THE NEW OPERATOR CODE TO
			/THE TEXT AREA
	JMS RTDTTY	/GO OUTPUT AND DISPLAY THE NEW
	CRTH03		/OPERATOR CODE.

	PAGE
/
/
/	DISPLAY THE "DATA ENTRY ERROR" MESSAGE
/
/
RTD20,	CLB
	JMS CRTMGA	/GO CUE THE "DATA ENTRY ERROR" MSG
	MOPM02		/FOR DISPLAY.
	CAL
	SENDW		/DELAY FOR 5 SECONDS
	CLOCK
	DLYMSG
	
	AC4000
	JMS CRTMGA	/GO CLEAR THE MESSAGE FROM DISPLAY
	MOPM02
/
/
/	NORMAL ROUTINE EXIT
/
/
RTD21,	CDF CUR
	JMP START	/GO BACK TO SLEEP 

DLYMSG,	ZBLOCK 3	/DELAY MESSAGE
	0		/SET EVENT FLAG AFTER INTERVAL
	0;400		/5 SECOND DELAY
/
/
/	CHECK THAT ONLY THE RIGHT NUMBER OF
/	DIGITS WERE ENTERED ON THE RT01.
/
/	COME HERE WITH MINUS THE NUMBER OF VALID
/	DIGITS FOR THIS DATA ENTRY.
/
/
RTDCHK,	0
	TAD RTDECF
	SNA
	JMP I RTDCHK	/YES, RETURN
	JMP RTD20	/NO, GO DISPLAY THE DATA ERROR MSG
/
/
/%RP	PROCESS A ROLL NUMBER
/
/
RTMOVR,	0
	TAD (-12)	/GO CHECK THAT ONLY 10 DIGITS WERE
	JMS RTDCHK	/ENTERED
	CLB CMA		/SET UP AN AUTO-INDEX FOR THE TEXT
	TAD I RTMOVR	/AREA
	DCA XR11
	JMS RTMOV3	/GO MOVE THE NEW PRODUCT TYPE
	TAD (700)
	JMS RTMOV3	/GO MOVE THE NEW EMULSION TYPE
	TAD (700)
	JMS RTMOV3	/GO MOVE THE NEW EMULSION RUN
	TAD (700)
	JMS RTMOV1	/GO MOVE THE NEW SLIT CUT DIGIT
	TAD I RTMOVR
	JMS RTSHOW	/GO CUE THE NEW TEXT FOR DISPLAY
	ISZ RTMOVR
	JMP I RTMOVR	/RETURN
/
/
/%RP	PROCESS THE PUT-UP CODE
/
/
RTMOVP,	0
	TAD (-4)	/GO CHECK THAT ONLY 4 DIGITS WERE
	JMS RTDCHK	/ENTERED.
	CLB CMA		/SET UP AN AUTO-INDEX FOR THE TEXT
	TAD I RTMOVP	/AREA
	DCA XR11
	JMS RTMOV3	/GO MOVE THE NEW PUT-UP
	TAD (700)
	JMS RTMOV1	/GO MOVE THE NEW SHEAR CUT DIGIT
	CLB CMA RTL
	JMS RTABIN	/GO CONVERT THE NEW PUT-UP TO BINARY
	JMS RTVALD	/GO TEST FOR A VALID PUT-UP CODE
	RTPTBL
	RTPTBL-RTPEND
	TAD I XR10	/GET THE NEW SHEAR CUT DIGIT.
	AND (7)
	JMS RTVALD	/GO TEST FOR A VALID SHEAR CUT
	RTUTBL		/NUMBER
	RTUTBL-RTUEND
	TAD I RTMOVP
	ISZ RTMOVP
	JMS RTSHOW	/GO CUE THE NEW TEXT FOR DISPLAY
	TAD RTD0E	/RETURN THE NEW SHEAR CUT DIGIT TO
	CIA		/THE CALLING ROUTINE.
	AND (3)
	JMP I RTMOVP	/RETURN
/
/
/%RP	PROCESS A SAMPLING CODE
/
/
RTMOVS,	0
	CLB CMA		/GO CHECK THAT ONLY 1 DIGIT WAS
	JMS RTDCHK	/ENTERED
	CLB CMA		/SET UP AN AUTO-INDEX FOR THE TEXT
	TAD I RTMOVS	/AREA
	DCA XR11
	JMS RTMOV1	/GO MOVE THE NEW SAMPLING CODE
	CLB CMA
	JMS RTABIN	/GO CONVERT THE NEW SAMPLING CODE TO 
			/ BINARY

	SNA 		/ENTERED SAMPLING CODE = 0 ?
	JMP RTD20	/YES, SHOW ERROR
	
	CLB
/	TAD (-12)	/TEST FOR A VALID SAMPLING CODE
/	SMA SZA CLA
/	JMP RTD20	/TOO BIG, DISPLAY DATA ERROR

	TAD I RTMOVS
	JMS RTSHOW	/GO CUE THE NEW TEXT FOR DISPLAY
	TAD RTD0B	/RETURN THE SAMPLING INVERVAL TO THE
	ISZ RTMOVS	/CALLING ROUTINE.
	JMP I RTMOVS	/RETURN

	PAGE
/
/
/%RP	PROCESS THE NEW ROLL CHOP LENGTH
/
/
RTMOVC,	0
	CLB CMA RTL	/GO CHECK THAT ONLY 3 DIGITS WERE
	JMS RTDCHK	/ENTERED
	CLB		/SET UP AN AUTO-INDEX FOR THE TEXT
	TAD I RTMOVC	/AREA
	DCA XR11
	JMS RTMOV3	/GO MOVE THE CHOP LENGTH
	CLB CMA RTL
	JMS RTABIN	/GO CONVERT THE NEW CHOP LENGTH TO 
			/BINARY.
	JMS RTVALD	/GO TEST FOR A VALID CHOP LENGTH
	RTCTBL
	RTCTBL-RTCEND
	CLB CMA RAL	/COMPUTE THE CODE FOR THIS CHOP
	TAD .-2		/LENGTH (1-8).
	CIA
	TAD RTD0F
	DCA NCHOPC
	TAD I RTMOVC
	JMS RTSHOW	/GO CUE THE NEW TEXT FOR DISPLAY
	JMP RTD21	/GO TO THE ROUTINE EXIT
/
/
/%RP	PROCESS THE SLIT WIDTH
/
/
RTMOVW,	0
	CLB CMA RTL	/GO CHECK THAT ONLY 3 DIGITS WERE
	JMS RTDCHK	/ENTERED
	CLB CMA		/SET UP AN AUTO-INDEX FOR THE TEXT
	TAD I RTMOVW	/AREA
	DCA XR11
	JMS RTMOV3	/GO MOVE THE NEW SLIT WIDTH
	TAD I RTMOVW
	JMS RTSHOW	/GO CUE THE NEW TEXT FOR DISPLAY
	ISZ RTMOVW
	TAD I RTMOVW	/GET THE ADDRESS OF WHERE TO PUT
	ISZ RTMOVW	/ THE NEW SLIT WIDTH.
	DCA RTD0C	/SAVE ADDRESS FOR INDIRECT.
	CLB CMA RTL	/GO CONVERT THE NEW SLIT WIDTH
	JMS RTABIN	/ TO BINARY AND SAVE IT FOR THE
	DCA I RTD0C	/ ROLL SLIT WIDTH.
	JMP I RTMOVW	/NOW RETURN.

	PAGE
/
/
/%RTP	RTO1 DATA MOVING SUBROUTINES
/
/%TW	MOVE 3 DIGITS FROM THE RT01 DATA BUFFER TO A
/	CRT TEXT AREA.
/
/
RTMOV3,	0
	JMS RTMOV1	/GO FORM AND MOVE 1 DIGIT
	JMS RTMOV2	/GO FORM AND MOVE 2 DIGITS
	JMP I RTMOV3
/
/
/%TW	MOVE 2 DIGITS FROM THE RT01 DATA BUFFER TO A
/	CRT TEXT AREA.
/
/
RTMOV2,	0
	TAD I XR10	/GET THE FIRST NEW DIGIT, SHIFT IT
	BSW		/AND PACK IN THE SECOND NEW DIGIT
	TAD I XR10
	DCA I XR11	/ADD THE NEW WORD TO THE TEXT AREA
	JMP I RTMOV2	/RETURN
/
/
/%TW	MOVE 1 DIGIT FROM THE RT01 DATA BUFFER TO A
/	CRT TEXT AREA.
/
/
RTMOV1,	0
	TAD I XR10	/GET THE NEW DIGIT AND ADD IN THE
	TAD (4600)	/NULL CHARACTER
	DCA I XR11	/ADD THE NEW WORD TO THE TEXT AREA
	JMP I RTMOV1	/RETURN

/
/
/%RP	ASCII TO BINARY CONVERTER
/
/%TW	COME HERE TO CONVERT ASCII CHARACTERS IN THE RT01
/	DATA BUFFER TO A BINARY NUMBER. ENTER WITH THE
/	NUMBER OF DIGITS TO CONVERT IN THE ACCUMULATOR. ON
/	EXIT, THE BINARY NUMBER IS STORED IN 'RTD0B' AND IS
/	IN THE ACCUMULATOR.
/
/
RTABIN,	0
	DCA RTD0A	/SAVE THE LOOP COUNTER
	TAD (RTDBUF-1)	/RESET THE AUTO-INDEX TO THE START
	DCA XR10		/OF THE RT01 DATA BUFFER.
	CLL RAL		/MULTIPLY THE CURRENT NUMBER BY 10
	DCA RTD0B
	TAD RTD0B
	CLL RTL
	TAD RTD0B
	DCA RTD0B	/SAVE THE CURRENT NUMBER
	TAD I XR10	/ADD IN THE NEW DIGIT
	AND (17)
	TAD RTD0B
	ISZ RTD0A	/IS THE NUMBER CONVERSION FINISHED ?
	JMP RTABIN+4	/NO, KEEP GOING
	DCA RTD0B
	TAD RTD0B
	JMP I RTABIN	/YES, RETURN
/
/
/%RP	CUE A TEXT AREA FOR DISPLAY ON THE CRT.
/
/	THE ADDRESS OF THE TEXT AREA IS IN THE ACCUMULATOR.
/
/
RTSHOW,	0
	DCA RTSHWA	/SAVE MESSAGE NUMBER
	CAL
	SENDW		/ISSUE THE MESSAGE REQUIRED
	CRT
	RTSHWM
	JMP I RTSHOW	/RETURN
/
/
/	CUE A TEXT AREA TO PRINT ON THE TELETYPE AND
/	DISPLAY THE TEXT AREA ON THE CRT.
/
/	THE ADDRESS OF THE TEXT AREA FOLLOWS THE CALL.
/
/
RTDTTY,	0
	TAD I RTDTTY	/GET THE TEXT ADDRESS TO PRINT
	DCA RTSHTA
	TAD RTSHTA
	JMS RTSHOW	/GO CUE THE TEXT FOR DISPLAY
	CAL
	SENDW		/ISSUE THE MESSAGE TO TTY
	TTYST
	RTSHTY
	CLB
	JMP RTD21	/GO TO THE ROUTINE EXIT
/
/
/	ADD OR DELETE A CRT MESSAGE
/
/
CRTMGA,	0
	TAD I CRTMGA	/FETCH MESSAGE NUMBER
	ISZ CRTMGA	/INC FOR PROPER RETURN
	DCA CRTMGC	/SET UP FOR CRT MESSAGE CALL

	CAL
	SENDW
	CRTMSG		/SEND MESSAGE TO MESSAGE HANDLER
	CRTMGB

	JMP I CRTMGA	/RETURN

CRTMGB,	ZBLOCK 3
CRTMGC,	0
/
/
/%RP	TEST FOR A VALID CODE TYPE
/
/	COME HERE TO LOOK FOR A BINARY NUMBER IN
/	THE SPECIFIED TABLE.
/
/
/	THE CALLING SEQUENCE IS:
/
/	(AC) = THE BINARY NUMBER TO LOOK FOR
/	JMS RTVALD
/	ADDRESS OF THE TABLE TO LOOK IN
/	-(LENGTH OF THE TABLE)
/
/
RTVALD,	0
	CIA
	DCA RTD0E
	CLB CMA
	TAD I RTVALD
	ISZ RTVALD
	DCA XR12
	CLB CMA
	TAD I RTVALD
	ISZ RTVALD
	DCA RTD0F
RTV1,	TAD I XR12
	TAD RTD0E
	SNA CLA
	JMP I RTVALD
	ISZ RTD0F
	JMP RTV1	/NO, KEEP LOOKING
	JMP RTD20	/YES, GO DISPLAY THE "DATA ENTRY
			/ERROR" AND QUIT.


RTSHWM, ZBLOCK 3	/CRT MESSAGE HANDLER MESSAGE
RTSHWA,	0

RTSHTY,	ZBLOCK 3
	1000
	0
RTSHTA,	0

	PAGE
/
/
/%RP	SET UP THE SYSTEM DATE FOR USE BY RTS/8
/
/
RTDATE,	0
	CLB
	TAD (RTDBUF-1)	/RESET THE AUTO-INDEX TO THE START
	DCA XR10	/ OT THE RT01 DATA BUFFER.
	JMS RTDA1	/GO GET THE 'DAY' DIGITS.
	AND (0037)
	CLL RTL
	RAL
	DCA RTD0A	/SAVE FOR A MOMENT.

	JMS RTDA1	/GO GET THE 'MONTH' DIGITS.
	AND (0017)
	BSW
	CLL RTL
	TAD RTD0A	/ADD 'MONTH' TO 'DAY'.
	DCA RTD0A

	JMS RTDA1	/NOW GET THE 'YEAR' DIGITS.
	TAD (-106)	/FORCE BASE YEAR OF 1970.
	CDF 0
	DCA I (YEAR)	/SAVE YEAR IN THE EXEC'S YEAR WORD.
	TAD I (YEAR)
	SPA
	TAD (4)
	AND (0007)
	TAD RTD0A	/ADD 'YEAR' INTO THE NEW DATE WORD,
	DCA I (DATE)	/ AND PUT IT IN THE EXEC'S DATE 
	CDF CUR		/ WORD.
	JMP I RTDATE	/ALL DONE, RETURN HOME.

RTDA1,	0
	TAD I XR10	/GET THE HIGH ORDER DIGIT OF THE
	AND (0017)	/ PAIR, AND MULTIPLY BY 10(10)
	CLL RAL
	DCA RTD0B
	TAD RTD0B
	RTL
	TAD RTD0B
	DCA RTD0B
	TAD I XR10	/NOW THE LOW ORDER DIGIT
	AND (0017)
	TAD RTD0B	/COMBINE THE TWO DIGITS.
	JMP I RTDA1	/BACK TO CALLER.
/
/
/%RTP	TABLES OF VALID OPERATOR DATA
/
/	TABLE OF VALID CHOP LENGTHS (IN BINARY)
/
/
RTCTBL,	262		/178 MM CHOP LENGTH
	306		/198
	356		/238
/	450		/296
	452		/298
	542		/354
RTCEND,	616		/398
/	656		/430
/
/
/	TABLE OF VALID PUT-UP CODES
/
/
RTPTBL,	31		/25 SHEETS PER PRODUCT TRAY
	62		/50
	113		/75
	144		/100
RTPEND,	175		/125
/
/
/	TABLE OF VALID SHEAR CUT DIGITS
/
/
RTUTBL,	0
	1
RTUEND,	2

	PAGE

	NOPUNCH		/CRT TEXT FILE FOLLOWS
	XLIST 1