Directory of image this file is from
This file as a plain text file

/	SIG11


FIELD 1
*2000


BUFBOT=1000
AUTO=10





START,	CLA CMA		/CLEAR FLAGS
	6516
	CAM
	SWAB

	JMS I (7700	/DECODE
	5
	5200

	TLS

	TAD I (7611
	JMS STAR
	TAD I (7604
	JMS STAR

	TAD I (7601
	SZA CLA
	JMP FROM11
	TAD I (7606
	SZA CLA
	JMP TO11
	JMP ERROR3



TO11,	CLA
	TAD (6001
	DCA RFARG1
	TAD I (7605
	JMS I (7700	/FETCH
	1
RFARG1,	0
	JMP ERROR1


	TAD (7606
	DCA LARG1
	TAD I (7605
	JMS I (7700	/LOOK UP
	2
LARG1,	0
LARG2,	0
	JMP ERROR2

	JMS SWTEST

	TAD LARG2
	DCA DSKCNT
	TAD LARG1
	DCA RADR
RLOOP,	CLA
	TAD RADR
	DCA HARG3
	CIF 0
	JMS I RFARG1
	200
	BUFBOT
HARG3,	0
	TYDER		/INPUT ERROR

	CDF 10
	TAD (7400
	DCA RSAMCT
	TAD (BUFBOT-1
	DCA AUTO

RSAMLP,	JMS PTSMSR
	ISZ RSAMCT
	JMP RSAMLP

	ISZ RADR
	SKP 
	HLT		/CATASTROPHIC HALT
	ISZ DSKCNT
	JMP RLOOP

	CLA
	TAD (4001
	6515
	CLA
	6514
	SPA
	JMP .-3
	JMP START



DSKCNT,	0
RADR,	0
RSAMCT,	0

SWTEST,	0
	CLA
	LAS
	RAR
	SNL CLA
	JMP CHCKUP
	MOSTSR
	JMP SWTEST+1
CHCKUP,	LAS
	RAR
	SZL CLA
	JMP I SWTEST
	MOSTSR
	JMP CHCKUP




PAGE



STAR,	0
	AND (7700
	CHECK
	5200
	JMP ERROR3
	SHL
	6
	AND (7700
	CHECK
	5200
	JMP ERROR3
	JMP I STAR



ERROR1,	TDC
	"D
	TDC
	"E
	TDC
	"V
ERROR3,	TDC
	"?
	JMP START

ERROR2,	TDC
	"I
	TDC
	"P
	TDC
	"T
	JMP ERROR3




PTSMSR, 0
	CLA
	CDF 0
	TAD I AUTO
	CDF 10
	6505			/LOAD DATA
	CLA CLL CML RAR
	6515			/SET DATA READY FLAG
	CLA 
	6514			/READ QUITTUNG
	SPA CLA
	JMP .-2
	CLA CMA
	6516
	6506			/LOESCHE DATEN +READY FLAG
	CLA
	TAD WNUM
	CIA
	DCA WCOUNT
	ISZ WCOUNT
	JMP .-1			/VERZOEGERUNG
	
        JMP I PTSMSR


WNUM,	100
WCOUNT,	0

        PAGE


FROM11, CLA
        TAD (6001
        DCA WFARG1
        TAD I (7600
        JMS I (7700             /FETCH 
        1
WFARG1, 0
        JMP ERROR1

        TAD (7601
        DCA EARG1
        TAD I (7600
        JMS I (7700             /ENTER
        3
EARG1,  0
EARG2,  0
        JMP ERROR4

	JMS SWTEST

        TAD EARG1
        DCA WADR
        DCA WBLKCT

WLOOP,  CLA
        TAD (7400
        DCA WSMCNT
        TAD (BUFBOT-1
        DCA AUTO

WSAMLP, JMS GTSMSR
        ISZ WSMCNT
        JMP WSAMLP

	CLA
	TAD WADR
	DCA WARG3
        CIF 0
        JMS I WFARG1    /CALL DEV. HANDLER
        4200            /WRITE
        BUFBOT
WARG3,  0
        JMP ERROR4

        CDF 10
        ISZ WADR
        SKP
        HLT
        ISZ WBLKCT
        SKP
        HLT
        CLA CLL CML
        TAD WBLKCT
        TAD EARG2
        SNL
        JMP ERROR5              /DEVICE FULL
        JMP WLOOP


DONE,   CLA CLL CML RAR
	6515
	CLA
        TAD WBLKCT
        DCA LENGTH
        TAD I (7600
        JMS I (7700             /CLOSE
        4
        7601
LENGTH, 0
        TYDER
        JMP START

WADR,   0
WBLKCT, 0
WSMCNT,0


GTSMSR, 0
        CLA
        6514            /READ FLAGS
        SPA
        JMP .-3
        AND (1
        SNA CLA
        JMP DONE                /END OF FILE FLAG
        6504            /READ DATA
        CMA
	CDF 0
        DCA I AUTO
	CDF 10
        CLA CLL CML RAR         /SET QUITTUNG
        6515
        CLA
        TAD DELAY
        CIA
        DCA DCNT
        ISZ DCNT
        JMP .-1
        CLA CLL CML RAR
        6516            /LOESCHE QUITTUNG
        CLA CLL
        JMP I GTSMSR

DELAY,  40
DCNT,   0

ERROR4, TDC
        "O
        TDC
        "P
        TDC
        "T
        JMP ERROR3

ERROR5, TDC
        "F
        TDC
        "U
        TDC
        "L
        TDC
        "L

        CLA CMA         /PDP8 GIBT AUF
        6515
        CIF 0
        JMP I .+1
        7600


$$$$$$$$$$$$$