/SIGPIP     JG 8.6.72

PAGE1=1000

*PAGE1

SIGPIP,	SWAB
	CAM

	TAD (INTAB+1
	DCA IARG1
	TAD (OUTTAB+1
	DCA OARG1

	TAD (6601
	DCA FIARG1
	TAD (7201
	DCA FOARG1

	CIF 10
	JMS I (7700	/DECODE
	5
	5200		/SPECIAL MODE
	TLS
	JMP LSTPGE



FSTPGE,	CIF 10
	JMS I (7700	/USRIN
	10

	TAD I (INTAB	/INPUT DEC NR
	CIF 10
	JMS I (200	/FETCH
	1
FIARG1,	0
	JMP ERROR1

	TAD I (INTAB
	CIF 10
	JMS I (200	/LOOK UP INPUT DEV
	2
IARG1,	0
IARG2,	0
	JMP ERROR4

	TAD I (OUTTAB
	CIF 10
	JMS I (200	/FETCH
	1
FOARG1,	0
	JMP ERROR1

	CDF 10
	TAD I (7643
	RTL
	RTL
	CDF 0
	SNL CLA 	/CHECK D-OPTION
	JMP NDELET
	TAD I (OUTTAB
	CIF 10
	JMS I (200	/DELETE FILE
	4
	OUTTAB+1
	0
	NOP

NDELET,	TAD I (OUTTAB
	CIF 10
	JMS I (200	/ENTER
	3
OARG1,	0
OARG2,	0
	JMP ERROR3

	TAD FIARG1
	DCA DEVHN1
	TAD FOARG1
	DCA DEVHN2
	TAD IARG1
	DCA INAD
	TAD OARG1
	DCA OUTAD


	TAD IARG2	/CHECK OUTPUT FILE LENGTH
	CMA CLL
	TAD OARG2
	SZL CLA
	JMP TOLONG

        TAD IARG2       /CLOSE OUTPUT FILE
        CIA
        DCA LENGTH
        TAD I (OUTTAB
        CIF 10
        JMS I (7700     /CLOSE
        4
	OUTTAB+1
LENGTH, 0
        JMP ERROR1

	TAD IARG2
	CIA
	DCA RESTCT	/SET RESTCT TO FULL BLOCK NUMBER
	DCA DONECT	/NOTHING DONE YET
	TAD MC400
	DCA SMCNT2
	DCA STORCT


	JMS USROUT
	JMP MLOOP

MC400,	-400


*PAGE1+200

MLOOP,	TAD SIMFLD
	CHBLOK
	0
	2
	SKP
	HLT
	RAL CLL
	RTL
	TAD (CIF
	DCA CIFIN
	TAD SIMADR
	DCA SIMINP

	CAM
	TAD NRBLKS
	SHL
	10
	CIA
	DCA MSAMNR
	JMP NXTPGE


OLDPGE,	TAD BUFBOT
	DCA INBOT
	TAD BUFBOT
	DCA OUTBOT

	TAD IARG2
	DCA TFCNT

AGAIN,	TAD MSAMNR
	DCA SAMCNT

	TAD BUFBOT
	DCA SAMP

	CLL
	TAD NRBLKS
	TAD TFCNT
	SZL CLA
	JMP FINISH	/REST OF FILE SMALLER THAN BUFFER

	TAD NRBLKS
	JMS XFER

	TAD INAD
	TAD NRBLKS
	DCA INAD
	TAD OUTAD
	TAD NRBLKS
	DCA OUTAD

	TAD TFCNT
	TAD NRBLKS
	DCA TFCNT
	JMP AGAIN

FINISH,	TAD TFCNT
	CIA
	JMS XFER	/LAST TRANSFER

	TDC		/TYPE DONE
	4304
	4317
	4316
	305

ENDINS,	CLA		/OR SKP CLA IF DISK TURNED OFF
	TOOLGO
	HLT

NRBLKS,	10
TFCNT,	0
ALPHAP,	1000
BUFBOT,	2000
SIMADR,	NULINT		/ADDRESS OF CODEC INIT
SIMFLD,	0



XFER,	0
	SHL
	7
	AND (3700
	DCA LNGTH
	TAD INPAR
	TAD LNGTH
	DCA  INCWD
	JMS I DEVHN1
INCWD,	0
INBOT,	0
INAD,	0
	HLT


NXTSAM,	CLA		/OR SKP CLA  TO TURN DISPLAY OFF
	JMP DPLY
	JMS RUNSIM


BACK,	ISZ SAMP
	ISZ SAMCNT
	JMP NXTSAM

	TAD LNGTH
	TAD OUTPAR
	DCA OUTCWD
	JMS I DEVHN2
OUTCWD,	0
OUTBOT,	0
OUTAD,	0
	HLT

	TAD STORCT	/UPDATE STORE COUNT
	TAD NRBLKS
	DCA STORCT

	JMP I XFER

LNGTH,	0
INPAR,	0		/BUFFER INFIELD 0
OUTPAR,	4000
DEVHN1,	0
DEVHN2,	0
SAMCNT,	0


TOLONG, TDC
        4311            /I
        "=
        TAD IARG2
        CIA
        TOCT
        TDC
        4240            /SPACE
        4317            /O
        "=
        TAD OARG2
        CIA
        TOCT

        TOOLGO


*PAGE1+400

NXTPGE,	TAD CIFIN
	DCA .+1
	0		/CDF
	IAC
	TAD CIFIN	/CDF CIF INSTRUCTION
	DCA CFIN

	DCA MDAFLG
	JMS I SIMINP	/INIT SIMULATION PROG
SIMLOC,	0
	CDF 0
	CAM		/SKP IF MODE B
	DPSZ
	ISZ MDAFLG
	SWAB

	JMS BACKP	/INIT DISPLAY ROUTINE
	TAD (BACK
	DCA BACKP

	CMA
	TAD PNTCNT	/SYNC PLOTS
	DCA PNTCNT

	JMP OLDPGE


SIMINP,	0
MSAMNR,	0
CIFIN,	0
SAMP,	0



DPLY,	CAM
	TAD I SAMP
	ASR
	6
	TAD SHIFT
	TAD IOSEP
	DCA YI

	TAD TBASE
	DCA XI

	JMS DPLPNT	/DISPLAY INPUT
XI,	0
YI,	0

	JMS RUNSIM	/DRIVE SIM

	TAD I SAMP
	ASR
	6
	DCA TEM
	TAD IOSEP
	CIA
	TAD SHIFT
	TAD TEM
	DCA YO

	TAD TBASE
	DCA XO

	JMS DPLPNT	/DISPLU OUTPUT
XO,	0
YO,	0

	ISZ PNTCNT
	JMP SAMBEM

	ISZ BEMCNT
	JMP SAMPLT
	SKP
BACKP,	0
	CLA
	TAD MBEMNR	/NEWPLOT
	DCA BEMCNT

	TAD MAXY
	DCA SHIFT

	TAD ERASE
	LDF
	EXC		/ERASE THE SCREEN
	CLA

SAMPLT,	TAD MPNTNR
	DCA PNTCNT

	TAD SHIFT
	TAD BEMSEP
	DCA SHIFT
	TAD MINX
	DCA TBASE

SAMBEM,	TAD XINCR
	TAD TBASE
	DCA TBASE
	JMP I BACKP

MPNTNR,	-1000
ERASE,	4
BEMCNT,	0
PNTCNT,	0
MBEMNR,	-4
MAXY,	640
BEMSEP,	-240
IOSEP,	40
MINX,	-400
XINCR,	1
SHIFT,	0
TBASE,	0
TEM,	0
MDAFLG,	0

RUNSIM,	0
	CLA
	TAD MDAFLG
	SZA CLA
	SWBA

        TAD I SAMP
CFIN,	HLT
        JMS I SIMLOC
        CDF 0
	DCA I SAMP
	SWAB

	ISZ SMCNT2	/UPDATE BLOCK COUNTS
	JMP OVER
	ISZ DONECT
	NOP
	TAD MN400
	DCA SMCNT2
	CMA
	TAD RESTCT
	DCA RESTCT

OVER,	MOSTSR

	CAM
	JMP I RUNSIM

SMCNT2,	0
DONECT,	0
RESTCT,	0
STORCT,	0
MN400,	-400


*PAGE1+600

DPLPNT,	0		/DISPLAY A POINT
	CLA
	SRF
	JMP .-1
	TAD FORMAT
	LDF
	CLA
	TAD I DPLPNT	/GET X
	LDX
	SRF
	JMP .-1
	ISZ DPLPNT
	CLA
	TAD I DPLPNT
	ISZ DPLPNT
	LDY
	SRF
	JMP .-1
	CLA
	TAD FORMAT
	EXC
	CLA
	SRF
	JMP .-1
	JMP I DPLPNT

FORMAT,	1001


NULINT,	0
	JMS I NULINT
NULCOD,	0
	JMP I NULCOD



/ENTRY POINTS TO SET CODEC ADDRESS




ENTRYT,	CLA
	TAD NULCDP
	DCA SIMADR
	TAD NULCDP+1
	DCA SIMFLD
	JMP SIGPIP

ENTRYS,	CLA
	TAD SIMP
	DCA SIMADR
	TAD SIMP+1
	DCA SIMFLD
	JMP SIGPIP

SIMP,	NULINT	/CODEC ADDRES
	0
NULCDP,	NULINT
	0




LSTPGE, CLA
        TAD MTBSZ       /TFANSFER COMMAND DECODER TABLE
        DCA TBCNT
        TAD BOTF1
        DCA ADF1
        TAD BOTF0
        DCA ADF0
NXTWRD, CDF 10
        TAD I ADF1
        CDF 0
        DCA I ADF0
        ISZ ADF1
        ISZ ADF0
        ISZ TBCNT
        JMP NXTWRD

        TAD I (OUTTAB+4
        AND (7700
        CHECK
        5200            /CHECK FOR * EXTENSION
        JMP STAR
        SHL
        6
        AND (7700
        CHECK
        5200
        JMP STAR
	JMP FSTPGE


BOTF1,  7600
BOTF0,  OUTTAB
MTBSZ,  -12
TBCNT,  0
ADF0,   0
ADF1,   0


ERROR3, JMS USROUT
        TDC
        "O
        JMP .+4
ERROR4, JMS USROUT
        TDC
        "I
        TDC
        "P
        TDC
        "T
        TDC
        "?
        TOOLGO


ERROR1, JMS USROUT
        TDC
        "D
        TDC
        "V
        TDC
        "C
STAR,   TDC
        "?
        JMP SIGPIP

USROUT, 0
        CIF 10
        JMS I (200
        11
        TLS
        JMP I USROUT


OUTTAB,	0
	0
	0
	0
	0
INTAB,	0
	0
	0
	0
	0

$$$$$$$$$$$$$$$$$$$$$$