9 DIM V$(150,25)
10 DIM W$(20),T$(20)
11 PRINT"BEI DIESEM SPIEL DUERFEN SIE"
12 PRINT"DIE BUCHSTABEN EINES WORTES ERRATEN"
13 PRINT"DAS WORT HAT EBENSOVIELE BUCHSTABEN"
14 PRINT"WIE PUNKTE AUSGEDRUCKT WERDEN"
15 FILE#1:"SYS:RATE1.BA"
16 FOR I=1 TO 100\INPUT#1:V$(I)\NEXT I
17 CLOSE#1
19 RANDOMIZE
20 H=INT(1+100*RND(1))
30 W$=V$(H)\L=LEN(W$)
31 Z=3+INT(SQR(L))\X=Z
32 PRINT"SIE DUERFEN ";Z;" MAL FALSCH RATEN"\T$="."
40 FOR I=1 TOL-1\T$=T$&"."\NEXT I\PRINTT$;
50 PRINTTAB(25);"BITTE RATEN SIE",\INPUTR$\IF LEN(R$)=1 THEN70
60 PRINT"UNZULAESSIG"\GOTO 50
70 FOR I=1TOL
80 IF SEG$(W$,I,I)=SEG$(T$,I,I) THEN 120
90 IF SEG$(W$,I,I)=R$ THEN 110
100 B=1\GOTO 120
110 T$=SEG$(T$,1,I-1)&R$&SEG$(T$,I+1,L)\A=1
120 NEXT I
130 PRINT T$,
140 IF B=0 THEN200
150 IF A=1 THEN 170
160 Z=Z-1
170 IF Z>0 THEN 190
180PRINT"NICHTS GEHT MEHR, LOESUNG IST:"\PRINTW$\GOTO270
190 A=0\B=0\GOTO 50
200 IF Z<X THEN 220
210 PRINT"SIND SIE HELLSEHER?"\GOTO 270
220 IF Z<X-1 THEN 240
230 PRINT"ARBEITEN SIE BEIM GEHEIMDIENST?"\GOTO 270
240 IF Z<X-2 THEN 260
250 PRINT"RESPEKTABLE LEISTUNG"\GOTO 270
260 PRINT"NA JA , GANZ GUT"
270 PRINT\PRINT"NOCH EIN VERSUCH?(JA ODER NEIN)"\INPUT A$
280 IF A$="JA"THEN19\IF A$<>"NEIN"THEN 270
290 END